P_CostCtrChangeDocItem

@AbapCatalog.sqlViewName: 'PCOSTCTRCHGDOCIT'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM.private: true
@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_CostCtrChangeDocItem as select from I_ChangeDocumentItem

  association [0..1] to P_CostCenterChangeDocument as _CostCenterChangeDocument on  $projection.ChangeDocObjectClass = _CostCenterChangeDocument.ChangeDocObjectClass
                                                                                and $projection.ChangeDocObject      = _CostCenterChangeDocument.ChangeDocObject
                                                                                and $projection.ChangeDocument       = _CostCenterChangeDocument.ChangeDocument

 association [0..1] to I_ChgDocItemChangeTypeText   as _ChgDocItemChangeTypeText   on  _ChgDocItemChangeTypeText.ChangeDocItemChangeType = $projection.ChangeDocItemChangeType
                                                                                   and _ChgDocItemChangeTypeText.Language                = $session.system_language                                                                                

{
  key I_ChangeDocumentItem.ChangeDocObject,
  key I_ChangeDocumentItem.ChangeDocObjectClass,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.DatabaseTable,
  key I_ChangeDocumentItem.ChangeDocTableKey,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key cast ( I_ChangeDocumentItem.ChangeDocItemChangeType  as changedocumentchangetype preserving type ) as ChangeDocItemChangeType,
      _ChgDocItemChangeTypeText.ChangeDocItemChangeTypeText,
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      I_ChangeDocumentItem.ChangeDocNewUnit,
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      cast ( I_ChangeDocumentItem.ChangeDocPreviousFieldValue as fis_cc_old_fieldval preserving type ) as ChangeDocPreviousFieldValue,
      cast ( I_ChangeDocumentItem.ChangeDocNewFieldValue as fis_cc_new_fieldval preserving type ) as ChangeDocNewFieldValue,

      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 1, 3) as mandt ) as ChangeDocumentSAPClient,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 4, 4) as kokrs ) as ChangeDocumentControllingArea,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 8, 10) as kostl ) as ChangeDocumentCostCenter,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 18, 8) as fis_cc_datbis ) as ChangeDocumentValidityEndDate,
      cast ( substring(I_ChangeDocumentItem.ChangeDocTableKey, 26, 8) as fis_cc_datab )  as ChangeDocValidityStartDate,

      case
        when I_ChangeDocumentItem.DatabaseTable = 'CSKSB' and
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'LAND1' then 'COUNTRY'
        when I_ChangeDocumentItem.DatabaseTable = 'CSKSB' and
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'TELF1' then 'PHONENUMBER1'
        when I_ChangeDocumentItem.DatabaseTable = 'CSKSB' and
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'DRNAM' then 'COSTCENTERPRINTERDESTINATION'
        when I_ChangeDocumentItem.DatabaseTable = 'CSKSB' and
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'NAME1' then 'ADDRESSNAME'
        else I_ChangeDocumentItem.ChangeDocDatabaseTableField
      end                                                       as DatabaseTableFieldName,
      case
        when I_ChangeDocumentItem.DatabaseTable = 'CSKSB' and
           ( I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'LAND1' or
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'TELF1' or
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'DRNAM' or
             I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'NAME1' ) then 'PFICOSTCENTER'
        else I_ChangeDocumentItem.DatabaseTable
      end                                                       as ObjectDatabaseTable,


      _CostCenterChangeDocument,
      _ChgDocItemChangeTypeText 

}
where I_ChangeDocumentItem.ChangeDocObjectClass = 'KOSTL' and 
      I_ChangeDocumentItem.ChangeDocDatabaseTableField <> 'KEY'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENTITEM",
"I_CHGDOCITEMCHANGETYPETEXT"
],
"ASSOCIATED":
[
"I_CHGDOCITEMCHANGETYPETEXT",
"P_COSTCENTERCHANGEDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/