P_CANotDisputedDocumentSum

@AbapCatalog.sqlViewName: 'PCANOTDCDOCS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType: {
        sizeCategory: #M,
        serviceQuality: #A,
        dataClass: #TRANSACTIONAL
    }
@VDM.private:true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Not Disputed Document'
define view P_CANotDisputedDocumentSum as select from I_CADocumentBPItemPhysical as _NotDisputedDoc
  inner join I_CADocumentHeader       as _DocumentHeader       on _DocumentHeader.CADocumentNumber = _NotDisputedDoc.CADocumentNumber
  inner join I_CAMainTransaction      as _MainTransaction      on  _NotDisputedDoc.CAApplicationArea = _MainTransaction.CAApplicationArea
                                                                               and _NotDisputedDoc.CAMainTransaction = _MainTransaction.CAMainTransaction
  inner join I_CASubTransaction       as _SubTransaction       on  _NotDisputedDoc.CAApplicationArea = _SubTransaction.CAApplicationArea
                                                                               and _NotDisputedDoc.CAMainTransaction = _SubTransaction.CAMainTransaction
                                                                               and _NotDisputedDoc.CASubTransaction  = _SubTransaction.CASubTransaction
  association [1..1] to I_CAClearingReason          as _ClearingReason       on  $projection.CAClearingReason = _ClearingReason.CAClearingReason
{
  key _NotDisputedDoc.CADocumentNumber,
  key _NotDisputedDoc.BusinessPartner,
  key _NotDisputedDoc.ContractAccount,
  key _NotDisputedDoc.CAMainTransaction,
  key _NotDisputedDoc.CASubTransaction,
  key _NotDisputedDoc.CAClearingReason,
      _NotDisputedDoc.CAContract,
      _NotDisputedDoc.CompanyCode,
      _NotDisputedDoc.CASubApplication,
      _NotDisputedDoc.CANetDueDate,
      _NotDisputedDoc.CADeferralDate,
      _NotDisputedDoc.CAClearingDate,
      _NotDisputedDoc.CAApplicationArea,
      @Semantics.currencyCode
      _NotDisputedDoc.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(_NotDisputedDoc.CAAmountInTransactionCurrency as betrw_kk) as CAAmountInTransactionCurrency,
      cast(_DocumentHeader.CreationDate as erdat) as CreationDate,
      cast(_DocumentHeader.CreationTime as crtime_kk) as CreationTime,
      _DocumentHeader.CAPostingDate,
      _DocumentHeader.CAReferenceDocument,
      _DocumentHeader.ReferenceDocumentType,
      _DocumentHeader._DocType._Text[1:Language = $session.system_language].CADocumentTypeName,
      _DocumentHeader.DocumentDate,
      _DocumentHeader.CAReconciliationKey,
      _DocumentHeader.CADocumentOriginCodeName,
      _DocumentHeader.CreatedByUser,
      _DocumentHeader.CADocumentOriginCode,
      _DocumentHeader.CAReversalDocumentNumber,
      _DocumentHeader.CAReversedDocumentNumber,
      cast(_ClearingReason._Text[1:Language = $session.system_language].CAClearingReasonName as augrd_gfn_kk ) as CAClearingReasonName,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case when _NotDisputedDoc.CAClearingReason = '' then _NotDisputedDoc.CAAmountInTransactionCurrency
           else 0
           end  as OpenAmountInTransCrcy,
      _MainTransaction._Text[1:Language = $session.system_language].CAMainTransactionName,
      _SubTransaction._Text[1:Language = $session.system_language].CASubTransactionName,
      _NotDisputedDoc.CAClearingDocumentNumber,
      _ClearingReason
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CACLEARINGREASON",
"I_CACLEARINGREASONTEXT",
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTHEADER",
"I_CADOCUMENTTYPE",
"I_CADOCUMENTTYPETEXT",
"I_CAMAINTRANSACTION",
"I_CAMAINTRANSACTIONTEXT",
"I_CASUBTRANSACTION",
"I_CASUBTRANSACTIONTEXT"
],
"ASSOCIATED":
[
"I_CACLEARINGREASON"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/