I_CASUBTRANSACTION

CDS View

Document Subtransaction

I_CASUBTRANSACTION is a CDS View in S/4HANA. Document Subtransaction. It contains 2 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 2 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_CASubTransactionValueHelp view from CONSUMPTION Teilvorgang Wertehilfe
P_CANotDisputedDocumentSum view inner COMPOSITE Not Disputed Document

Fields (2)

KeyField CDS FieldsUsed in Views
KEY CAMainTransaction CAMainTransaction 1
KEY CASubTransaction CASubTransaction 1 
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Document Subtransaction'

@Analytics: { dataCategory: #DIMENSION,
              dataExtraction.enabled: true }
              
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { modelingPattern: #ANALYTICAL_DIMENSION,
                representativeKey: 'CASubTransaction',
                sapObjectNodeType.name: 'ContrAcctgSubtransaction',
                supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                         #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #SQL_DATA_SOURCE,
                                         #EXTRACTION_DATA_SOURCE ],
                usageType: { dataClass: #CUSTOMIZING,
                             serviceQuality: #A,
                             sizeCategory: #S } }

@VDM.viewType: #BASIC

define view entity I_CASubTransaction
  as select from tfktvo
    inner join   I_CAApplicationArea as ApplArea on tfktvo.applk = ApplArea.CAApplicationArea

  association [1..1] to I_CAApplicationArea    as _ApplArea           on  $projection.CAApplicationArea = _ApplArea.CAApplicationArea
  association [1..1] to I_CAMainTransaction    as _MainTransaction    on  $projection.CAApplicationArea = _MainTransaction.CAApplicationArea
                                                                      and $projection.CAMainTransaction = _MainTransaction.CAMainTransaction
  association [0..1] to I_CAMainTransaction    as _MainTransactionRev on  $projection.CAApplicationArea            = _MainTransactionRev.CAApplicationArea
                                                                      and $projection.CAMainTransactionForReversal = _MainTransactionRev.CAMainTransaction
  association [0..1] to I_CASubTransaction     as _SubTransactionRev  on  $projection.CAApplicationArea            = _SubTransactionRev.CAApplicationArea
                                                                      and $projection.CAMainTransactionForReversal = _SubTransactionRev.CAMainTransaction
                                                                      and $projection.CASubTransactionForReversal  = _SubTransactionRev.CASubTransaction
  association [0..*] to I_CASubTransactionText as _Text               on  $projection.CAApplicationArea = _Text.CAApplicationArea
                                                                      and $projection.CAMainTransaction = _Text.CAMainTransaction
                                                                      and $projection.CASubTransaction  = _Text.CASubTransaction
{
      @ObjectModel.foreignKey.association: '_ApplArea'
  key tfktvo.applk     as CAApplicationArea,
      @ObjectModel.foreignKey.association: '_MainTransaction'
  key tfktvo.hvorg     as CAMainTransaction,
      @ObjectModel.text.association: '_Text'
  key tfktvo.tvorg     as CASubTransaction,

      @ObjectModel.foreignKey.association: '_MainTransactionRev'
      tfktvo.hvorg_rev as CAMainTransactionForReversal,
      @ObjectModel.foreignKey.association: '_SubTransactionRev'
      tfktvo.tvorg_rev as CASubTransactionForReversal,
      tfktvo.faetp     as CADueDateDeterminationRule,
      tfktvo.qsvtp     as CAWithholdingTaxAmountType,
      tfktvo.rladdr    as CARuleForAddlReceivables,
      tfktvo.xpayt     as CAIsPaymentTransaction,
      /*
            hvorg_spl,
            tvorg_spl,
            xnega,
      */

      /* Associations */
      _ApplArea,
      _MainTransaction,
      _MainTransactionRev,
      _SubTransactionRev,
      _Text
}
where
  ApplArea.CAApplicationAreaIsActive = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CAAPPLICATIONAREA",
"TFKTVO"
],
"ASSOCIATED":
[
"I_CAAPPLICATIONAREA",
"I_CAMAINTRANSACTION",
"I_CASUBTRANSACTION",
"I_CASUBTRANSACTIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More