P_BusinessPartnerBank

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'PBUSPARTBANK'
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #S,
   usageType.dataClass: #MIXED
}
define view P_BusinessPartnerBank
  as select from I_BusinessPartnerBank as BusinessPartnerBank

  association [1..1] to I_BusinessPartner as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_Bank_2          as _Bank            on  $projection.BankNumber     = _Bank.BankInternalID
                                                              and $projection.BankCountryKey = _Bank.BankCountry

  association [1..1] to P_IBAN            as _IBAN            on  $projection.BankAccount    = _IBAN.BankAccount
                                                              and $projection.BankNumber     = _IBAN.Bank
                                                              and $projection.BankCountryKey = _IBAN.BankCountry
                                                              and $projection.BankControlKey = _IBAN.BankControlKey

{
  key BusinessPartnerBank.BusinessPartner               as BusinessPartner,
  key BusinessPartnerBank.BankIdentification            as BankIdentification,
      BusinessPartnerBank.BankCountryKey                as BankCountryKey,
      _Bank.BankName                                    as BankName,
      BusinessPartnerBank.BankNumber                    as BankNumber,
      _Bank.SWIFTCode                                   as SWIFTCode,
      BusinessPartnerBank.BankControlKey                as BankControlKey,
      BusinessPartnerBank.BankAccountHolderName         as BankAccountHolderName,
      BusinessPartnerBank.BankAccountName               as BankAccountName,
      BusinessPartnerBank.ValidityStartDate             as ValidityStartDate,
      BusinessPartnerBank.ValidityEndDate               as ValidityEndDate,

      case
        when BusinessPartnerBank.BankAccount <> ''
          then _IBAN.IBAN
        else
          BusinessPartnerBank.IBAN
      end                                               as IBAN,

      _IBAN.IBANValidityStartDate                       as IBANValidityStartDate,
      BusinessPartnerBank.BankAccount                   as BankAccount,
      BusinessPartnerBank.BankAccountReferenceText      as BankAccountReferenceText,
      BusinessPartnerBank.CollectionAuthInd             as CollectionAuthInd,
      BusinessPartnerBank.BusinessPartnerExternalBankID as BusinessPartnerExternalBankID,
      BusinessPartnerBank.BPBankDetailsChangeDate       as BPBankDetailsChangeDate,
      BusinessPartnerBank.BPBankDetailsChangeTargetID   as BPBankDetailsChangeTargetID,
      BusinessPartnerBank.BPBankIsProtected             as BPBankIsProtected,
      _Bank.CityName                                    as CityName,
      _Bank,
      _IBAN,
      _BusinessPartner,
      _BusinessPartner.AuthorizationGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK_2",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERBANK",
"P_IBAN"
],
"ASSOCIATED":
[
"I_BANK_2",
"I_BUSINESSPARTNER",
"P_IBAN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/