P_BankChangeDocument

@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM.private: true
@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@EndUserText.label: 'Bank Change Document'
define view entity P_BankChangeDocument as select from I_ChangeDocumentItem 
  
  association [0..1] to I_ChangeDocChangeIndT as _ChgDocItemChangeTypeText  
    on  $projection.ChangeDocItemChangeType = _ChgDocItemChangeTypeText.Value
    and _ChgDocItemChangeTypeText.Language = $session.system_language

  association [0..1] to I_ChangeDocFieldNames as _ChangeDocFieldNames
    on $projection.ChangeDocDatabaseTableField = _ChangeDocFieldNames.Value
    and $projection.DatabaseTable = _ChangeDocFieldNames.DatabaseTable
    and _ChangeDocFieldNames.Language = $session.system_language
/*        
  association [0..1] to I_ChangeDocTableNames as _ChangeDocTableNames
    on $projection.DatabaseTable = _ChangeDocTableNames.Value
    and _ChangeDocTableNames.Language = $session.system_language
*/    
{
  key ChangeDocObject,
  key ChangeDocObjectClass,
  key ChangeDocument,
  key ChangeDocTableKey,
  key ChangeDocDatabaseTableField,
  key cast ( ChangeDocItemChangeType  as  bf_bank_change_document_type preserving type ) as ChangeDocItemChangeType,
  //key ChangeDocItemChangeType,

  key DatabaseTable,
 
  key _ChgDocItemChangeTypeText.Text                                                   as ChangeDocItemChangeTypeText,
  key _ChangeDocFieldNames.Text                                                      as DatabaseTableFieldName,
  key _ChangeDocument.ChangeTransactionCode                                          as ChangeDocTransactionCode,
  
  cast ( ChangeDocPreviousFieldValue as bf_bank_old_fieldval preserving type )     as ChangeDocPreviousFieldValue,
  cast ( ChangeDocNewFieldValue as bf_bank_new_fieldval preserving type )          as ChangeDocNewFieldValue,

  cast ( _ChangeDocument.CreatedByUser as bf_bank_changedby preserving type )    as CreatedByUser,
  cast ( _ChangeDocument.CreationDate  as bf_bank_changedon preserving type )    as CreationDate,
  cast ( _ChangeDocument.CreationTime  as bf_bank_changetime preserving type )   as CreationTime,
  
  _ChangeDocLongTableKey.ChangeDocLongTableKey,
  //_ChangeDocument.ChangeDocLanguage,

  
  cast ( substring(ChangeDocTableKey, 4, 3) as land1 preserving type )  as BankCountry,
    
  cast ( substring(ChangeDocTableKey, 7, 15) as bankk preserving type ) as BankInternalID,
  
  _ChangeDocument.ChangeTransactionCode                                 as TransacionCode,

  /* Associations */
  _ChangeDocLongTableKey,
  _ChangeDocument,
  _ChangeDocumentItemExtension

} where ChangeDocObjectClass = 'BANK'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCCHANGEINDT",
"I_CHANGEDOCFIELDNAMES",
"I_CHANGEDOCLONGTABLEKEY",
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM"
],
"ASSOCIATED":
[
"I_CHANGEDOCLONGTABLEKEY",
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEMEXTENSION"
],
"BASE":
[
"I_CHANGEDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/