N_MaintenanceTaskList

@AbapCatalog.sqlViewName: 'NMAINTTASKLIST'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Auxiliary view for I_MaintenanceTaskList'
@VDM.auxiliaryEntity.for.entity: 'I_MaintenanceTaskList'
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@ObjectModel.representativeKey: 'TaskListGroupCounter'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
define view N_MaintenanceTaskList
  as select from I_BillOfOperationsChangeState
  association [0..1] to I_MaintenanceTaskListType    as _TaskListType              on  _TaskListType.TaskListType = $projection.TaskListType


  association [0..1] to I_TechObjIsEquipOrFuncnlLoc  as _TechObjIsEquipOrFuncnlLoc on  _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc




  association [1..1] to I_BillOfOperationsGroup      as _TaskListGroup             on  _TaskListGroup.BillOfOperationsType   = $projection.TaskListType
                                                                                   and _TaskListGroup.BillOfOperationsGroup  = $projection.TaskListGroup
                                                                                   and (
                                                                                      _TaskListGroup.BillOfOperationsType    = 'A'
                                                                                      or _TaskListGroup.BillOfOperationsType = 'E'
                                                                                      or _TaskListGroup.BillOfOperationsType = 'T'
                                                                                    )

  association [1..1] to I_BillOfOperations           as _TaskListGroupCounter      on  _TaskListGroupCounter.BillOfOperationsType    = $projection.TaskListType
                                                                                   and _TaskListGroupCounter.BillOfOperationsGroup   = $projection.TaskListGroup
                                                                                   and _TaskListGroupCounter.BillOfOperationsVariant = $projection.TaskListGroupCounter
                                                                                   and (
                                                                                      _TaskListGroupCounter.BillOfOperationsType     = 'A'
                                                                                      or _TaskListGroupCounter.BillOfOperationsType  = 'E'
                                                                                      or _TaskListGroupCounter.BillOfOperationsType  = 'T'
                                                                                    )
  association [0..1] to I_TaskListToEquipAlloc       as _TaskListEquip             on  _TaskListEquip.TaskListType         = $projection.TaskListType
                                                                                   and _TaskListEquip.TaskListGroup        = $projection.TaskListGroup
                                                                                   and _TaskListEquip.TaskListGroupCounter = $projection.TaskListGroupCounter

  association [0..1] to I_TaskListToFuncnlLocAlloc   as _TaskListFuncnlLoc         on  _TaskListFuncnlLoc.TaskListType          = $projection.TaskListType
                                                                                   and _TaskListFuncnlLoc.TaskListGroup         = $projection.TaskListGroup
                                                                                   and  _TaskListFuncnlLoc.TaskListGroupCounter =  $projection.TaskListGroupCounter

  association [0..*] to I_TaskListLongText           as _LongText                  on  $projection.TaskListType           = _LongText.TaskListType
                                                                                   and $projection.TaskListGroup          = _LongText.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter   = _LongText.TaskListGroupCounter
                                                                                   and $projection.TaskListVersionCounter = _LongText.TaskListVersionCounter
{
      /* Key fields */
      @ObjectModel.foreignKey.association: '_TaskListType'
  key I_BillOfOperationsChangeState.BillOfOperationsType                      as  TaskListType,
      @ObjectModel.foreignKey.association: '_TaskListGroup'
  key I_BillOfOperationsChangeState.BillOfOperationsGroup                     as  TaskListGroup,
      @ObjectModel.foreignKey.association: '_TaskListGroupCounter'
  key I_BillOfOperationsChangeState.BillOfOperationsVariant                   as  TaskListGroupCounter,
   
  key  I_BillOfOperationsChangeState.BOOInternalVersionCounter                 as  TaskListVersionCounter,

      /* Data fields */
      I_BillOfOperationsChangeState.BillOfOperationsDesc                      as  TaskListDesc,

      I_BillOfOperationsChangeState.MaintenanceStrategy,


      I_BillOfOperationsChangeState.Plant,

      I_BillOfOperationsChangeState.ResponsiblePlannerGroup,

      I_BillOfOperationsChangeState.IsDeleted,
      I_BillOfOperationsChangeState.Assembly,


      @ObjectModel.foreignKey.association: '_TaskListStatus'
      I_BillOfOperationsChangeState.BillOfOperationsStatus                    as  TaskListStatus,

      I_BillOfOperationsChangeState.ValidityStartDate,
      
       case I_BillOfOperationsChangeState.ValidityEndDate
        when '00000000' then cast ('99991231' as datub)
        else I_BillOfOperationsChangeState.ValidityEndDate
      end                                                          as  ValidityEndDate,

      I_BillOfOperationsChangeState.OperationSystemCondition,

      I_BillOfOperationsChangeState.WorkCenterTypeCode,

      I_BillOfOperationsChangeState.WorkCenterInternalID,

      @ObjectModel.foreignKey.association: '_TaskListUsage'
      I_BillOfOperationsChangeState.BillOfOperationsUsage                     as  TaskListUsage,

      @ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
      cast( case I_BillOfOperationsChangeState.BillOfOperationsType
        when 'E' then 'EAMS_EQUI'
        when 'T' then 'EAMS_FL'
        else ''
      end as eams_tec_obj_type_value )                                        as  TechObjIsEquipOrFuncnlLoc,

      I_BillOfOperationsChangeState.ControllingArea, //


      _TaskListEquip.Equipment,
      _TaskListFuncnlLoc.FunctionalLocation,
      _TaskListFuncnlLoc._FunctionalLocation._FunctionalLocationLabel.FuncnlLocPrimaryLabelName,

     
      I_BillOfOperationsChangeState.MaintenancePlanningPlant,
      //Association

      I_BillOfOperationsChangeState._BillOfOperationsStatus                   as  _TaskListStatus,
      I_BillOfOperationsChangeState._WorkCenter,
      I_BillOfOperationsChangeState._MaintenanceStrategy,
      I_BillOfOperationsChangeState._Assembly,
      I_BillOfOperationsChangeState._BillOfOperationsUsage                    as  _TaskListUsage,
      I_BillOfOperationsChangeState._ResponsiblePlannerGroup,
      _LongText.PlainLongText,
      _TaskListType,
      _TaskListGroup,
      _TaskListGroupCounter,
      _TechObjIsEquipOrFuncnlLoc,
      _TaskListEquip._Equipment,
      _TaskListFuncnlLoc._FunctionalLocation
}
where
  (
       I_BillOfOperationsChangeState.BillOfOperationsType = 'A'
    or I_BillOfOperationsChangeState.BillOfOperationsType = 'E'
    or I_BillOfOperationsChangeState.BillOfOperationsType = 'T'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSCHANGESTATE",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONLABEL",
"I_TASKLISTLONGTEXT",
"I_TASKLISTTOEQUIPALLOC",
"I_TASKLISTTOFUNCNLLOCALLOC"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSSTATUS",
"I_BILLOFOPERATIONSUSAGE",
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_MAINTENANCESTRATEGY",
"I_MAINTENANCETASKLISTTYPE",
"I_MATERIAL",
"I_RESPONSIBLEPLANNERGROUP",
"I_TASKLISTLONGTEXT",
"I_TASKLISTTOEQUIPALLOC",
"I_TASKLISTTOFUNCNLLOCALLOC",
"I_TECHOBJISEQUIPORFUNCNLLOC",
"I_WORKCENTER"
],
"BASE":
[
"I_BILLOFOPERATIONSCHANGESTATE",
"I_TASKLISTTOEQUIPALLOC",
"I_TASKLISTTOFUNCNLLOCALLOC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/