N_ChangeRecordObjPgTmplRouting

@AbapCatalog.sqlViewName: 'NCHGRCDOBJPGTER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking:#NOT_REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant','BillOfOperationsVersion']
}
@UI.headerInfo:{
  typeName: 'Shop Floor Routing Template',
  typeNamePlural: 'Shop Floor Routing Templates',
  title:{value:'BillOfOperationsGroup'}
  }
@UI.presentationVariant.requestAtLeast: ['BillOfOperationsGroup','BillOfOperationsType','BillOfOperationsVariant','BillOfOperationsVersion','Plant','ChangeRecordType']
@EndUserText.label: 'Auxillary view for ESH-Change Record Ref. Obj. Tmpl Routing'

@Search.searchable: true

@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChangeRecordObjPgTmplRouting'

define view N_ChangeRecordObjPgTmplRouting
  as select from           I_ChgRecdRefTmplRoutingBsc as reference_template_routing
    left outer to one join I_ProductionRoutingVersion as Routing on  reference_template_routing.ChgRecRefInternalKey1 = Routing.BillOfOperationsType
                                                                 and reference_template_routing.ChgRecRefInternalKey2 = Routing.BillOfOperationsGroup
                                                                 and reference_template_routing.ChgRecRefInternalKey3 = Routing.BillOfOperationsVariant
                                                                 and reference_template_routing.ChgRecRefInternalKey4 = Routing.BillOfOperationsVersion
  association [1..1] to I_BillOfOperationsVersion      as _BillOfOperationsGroupVH on  $projection.BillOfOperationsType    = _BillOfOperationsGroupVH.BillOfOperationsType
                                                                                   and $projection.BillOfOperationsGroup   = _BillOfOperationsGroupVH.BillOfOperationsGroup
                                                                                   and $projection.BillOfOperationsVariant = _BillOfOperationsGroupVH.BillOfOperationsVariant
                                                                                   and $projection.BillOfOperationsVersion = _BillOfOperationsGroupVH.BillOfOperationsVersion
  association [1..1] to C_ChangeRecordItemRelTmplRtgVH as _ChangeRecordItemRelVH   on  $projection.ChangeRecordItemRelevance              = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                   and $projection.changerecordtype                       = _ChangeRecordItemRelVH.ChangeRecordType
                                                                                   and (
                                                                                      $projection.ChangeRecordReferenceType               = _ChangeRecordItemRelVH.ChangeRecordReferenceType
                                                                                      or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
                                                                                    )
  association [1..1] to C_ChangeRecordObjPg            as _ChangeRecordObjPg       on  $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID

{

          @UI.hidden: true
  key     ChangeRecordReferenceUUID,

          @UI: {
                 lineItem:{position:10,importance:#HIGH },
                 identification:{position: 10, importance: #HIGH }
               }
          @Consumption.valueHelpDefinition: [
                                               { entity:  { name:    'C_ChangeRecordTmplRtgVH',
                                                            element: 'BillOfOperationsGroup' },
                                                 additionalBinding:[ { localElement: 'BillOfOperationsVariant',
                                                                       element: 'BillOfOperationsVariant' },
                                                                     { localElement: 'BillOfOperationsVersion',
                                                                       element: 'BillOfOperationsVersion' }]
                                                }
                                            ]
          Routing.BillOfOperationsGroup   as BillOfOperationsGroup,

          @UI.hidden: true
          Routing.BillOfOperationsType,

          @UI: {
                 lineItem:{position:20,importance:#HIGH },
                 identification:{position: 20, importance: #HIGH }
               }
          Routing.BillOfOperationsVariant as BillOfOperationsVariant,

          @UI: {
                lineItem:{position:30,importance:#HIGH },
                identification:{position: 30, importance: #HIGH }
              }
          Routing.BillOfOperationsVersion as BillOfOperationsVersion,

          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ParentChangeRecordRefUUID,
          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          @ObjectModel.readOnly: true
          reference_template_routing.CreatedByUser,

          @UI.hidden: true
          reference_template_routing.CreationDateTime,
          //          @ObjectModel.virtualElement : true

          //          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'

          //          @ObjectModel.readOnly: true

          //          cast( '00000000' as /plmb/created_on ) as CreationDate,


          @Semantics.user.lastChangedBy: true
          @ObjectModel.readOnly: true
          reference_template_routing.LastChangedByUser,

          @UI.hidden: true
          reference_template_routing.LastChangeDateTime,
          //          @ObjectModel.virtualElement : true

          //          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'

          //          @ObjectModel.readOnly: true

          //          cast( '00000000' as /plmb/changed_on ) as LastChangeDate,


          @UI: {
                  lineItem:{position:40,importance:#HIGH },
                  identification:{position: 40, importance: #HIGH }
               }
          @ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
          @Consumption.valueHelp: '_ChangeRecordItemRelVH'
          @ObjectModel.mandatory: true
          ChangeRecordItemRelevance,

          --Routing Status(Processing Status)
          @ObjectModel.readOnly: true
          @UI: {
                  lineItem:{position:50,importance:#HIGH }
                }
          _BillOfOperationsGroupVH._BOOVersionStatus._Text[1: Language=$session.system_language].BOOVersionStatusText,

          @UI.hidden: true
          Routing.Plant,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordType,

          _ChangeRecordObjPg,

          _ChangeRecordItemRelVH,
          _BillOfOperationsGroupVH

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECORDOBJPG",
"I_BILLOFOPERATIONSVERSION",
"I_BOOVERSIONSTATUS",
"I_BOOVERSIONSTATUSTEXT",
"I_CHGRECDREFTMPLROUTINGBSC",
"I_PRODUCTIONROUTINGVERSION"
],
"ASSOCIATED":
[
"C_CHANGERECORDITEMRELTMPLRTGVH",
"C_CHANGERECORDOBJPG",
"I_BILLOFOPERATIONSVERSION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/