I_WorkflowStatusOverview

@AbapCatalog.sqlViewName: 'IWRKFLWSTTSVW'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Workflow'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
define view I_WorkflowStatusOverview
  as select from    I_WorkflowTask           as WorkflowHeader
    inner join      I_WorkflowTaskApplObject as WorkflowTaskApplObject on WorkflowTaskApplObject.WorkflowTaskInternalID = WorkflowHeader.WorkflowTaskInternalID
    left outer join I_WorkflowTaskCount      as Tasks                  on Tasks.WorkflowInternalID = WorkflowHeader.WorkflowTaskInternalID
  association [0..1] to I_WorkflowExternalStatus     as _WorkflowExternalStatus     on $projection.WorkflowExternalStatus = _WorkflowExternalStatus.WorkflowExternalStatus
  association [0..1] to I_WorkflowScenarioDefinition as _WorkflowScenarioDefinition on $projection.WorkflowScenarioDefinition = _WorkflowScenarioDefinition.WorkflowScenarioDefinition
  association [0..*] to I_WorkflowStatusDetails      as _WorkflowStatusDetails      on $projection.WorkflowInternalID = _WorkflowStatusDetails.WorkflowInternalID
  association [0..1] to I_WorkflowResult             as _WorkflowResult             on $projection.WorkflowInternalID = _WorkflowResult.WorkflowInternalID
{
  key WorkflowHeader.WorkflowTaskInternalID                     as WorkflowInternalID,
      WorkflowTaskStatus                                        as WorkflowExternalStatus,
      _WorkflowExternalStatus,
      WorkflowTaskDefinition                                    as WorkflowScenarioDefinition,
      _WorkflowScenarioDefinition,
      WorkflowTaskDefinitionVersion                             as WorkflowScenarioDefinitionVers,
      WrkflwTskCreationUTCDateTime,
      WrkflwTskCompletionUTCDateTime,
      WorkflowTaskApplObject.SAPObjectNodeRepresentation,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey1,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey2,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey3,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey4,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey5,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey6,
      sum(case when  Tasks.WorkflowTaskExternalStatus = 'COMPLETED'
                     or WorkflowTaskExternalStatus    = 'CANCELLED'
                     then Tasks.NumberOfWorkflowDialogTasks
               else 0
          end )                                                 as NmbrOfCmpltdWrkflwDialogTasks,
      sum(case when  Tasks.WorkflowTaskExternalStatus != 'COMPLETED'
                     and WorkflowTaskExternalStatus   != 'CANCELLED'
                     then Tasks.NumberOfWorkflowDialogTasks
               else 0
          end )                                                 as NmbrOfActiveWrkflwDialogTasks,
      _WorkflowStatusDetails,
      _WorkflowResult
}
where
      WorkflowTaskType                                   = 'F'
  and WorkflowTaskDefinitionType                         = 'SCENARIO'
  and WorkflowTaskApplObject.SAPObjectNodeRepresentation is not initial
  and WorkflowTaskApplObject.WorkflowObjectRole          = '01'
group by WorkflowHeader.WorkflowTaskInternalID, WorkflowTaskStatus,
      WorkflowTaskDefinition,
      WorkflowTaskDefinitionVersion,
      WrkflwTskCreationUTCDateTime,
      WrkflwTskCompletionUTCDateTime,
      WorkflowTaskApplObject.SAPObjectNodeRepresentation,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey1,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey2,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey3,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey4,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey5,
      WorkflowTaskApplObject.SAPBusinessObjectNodeKey6
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKFLOWTASK",
"I_WORKFLOWTASKAPPLOBJECT",
"I_WORKFLOWTASKCOUNT"
],
"ASSOCIATED":
[
"I_WORKFLOWEXTERNALSTATUS",
"I_WORKFLOWRESULT",
"I_WORKFLOWSCENARIODEFINITION",
"I_WORKFLOWSTATUSDETAILS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/