I_WorkflowStatusDetails

@AbapCatalog.sqlViewName: 'IWRKFLWSTTSDTLS'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'Workflow Task'
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view I_WorkflowStatusDetails
  as select from    I_WorkflowTask
    left outer join I_WorkflowTaskResult as WorkflowTaskResult on  I_WorkflowTask.TopLevelWorkflowTask   = WorkflowTaskResult.WorkflowInternalID
                                                               and I_WorkflowTask.WorkflowTaskInternalID = WorkflowTaskResult.WorkflowTaskInternalID

  association [0..1] to I_WorkflowTaskExternalStatus as _WorkflowTaskExternalStatus on  $projection.WorkflowTaskExternalStatus = _WorkflowTaskExternalStatus.WorkflowTaskExternalStatus

  association [0..1] to I_BusinessUser               as _WorkflowTaskProcessor      on  $projection.WorkflowTaskProcessor = _WorkflowTaskProcessor.UserID
  association [0..1] to I_BusinessUserBasic          as _WorkflowTaskProcessor_2    on  $projection.WorkflowTaskProcessor = _WorkflowTaskProcessor_2.UserID  
  
  association [0..1] to I_WorkflowStepType           as _WorkflowTaskStepType       on  $projection.WorkflowScenarioDefinition     = _WorkflowTaskStepType.WrkflwScen
                                                                                    and $projection.WorkflowScenarioDefinitionVers = _WorkflowTaskStepType.WrkflwScenVers
                                                                                    and $projection.WorkflowTaskStepType           = _WorkflowTaskStepType.WorkflowStepType
  association [0..*] to I_WorkflowRecipients         as _WorkflowRecipients         on  $projection.WorkflowInternalID             = _WorkflowRecipients.WorkflowInternalID
                                                                                    and $projection.WorkflowTaskInternalID         = _WorkflowRecipients.WorkflowTaskInternalID
  association [0..*] to I_WORKFLOWRECIPIENTS_V2       as _WorkflowRecipients_2      on  $projection.WorkflowInternalID             = _WorkflowRecipients_2.WorkflowInternalID
                                                                                    and $projection.WorkflowTaskInternalID         = _WorkflowRecipients_2.WorkflowTaskInternalID
  association [0..1] to I_WorkflowStepResult         as _WorkflowTaskStepResult     on  $projection.WorkflowScenarioDefinition     = _WorkflowTaskStepResult.WorkflowScenarioDefinition
                                                                                    and $projection.WorkflowScenarioDefinitionVers = _WorkflowTaskStepResult.WorkflowScenarioDefinitionVers
                                                                                    and $projection.WorkflowTaskStepType           = _WorkflowTaskStepResult.WorkflowStepType
                                                                                    and $projection.WorkflowTaskResult             = _WorkflowTaskStepResult.WorkflowStepResult

  association [0..1] to I_WorkflowAgentRule          as _WorkflowAgentRule          on  $projection.WorkflowScenarioDefinition     = _WorkflowAgentRule.WorkflowScenarioDefinition
                                                                                    and $projection.WorkflowScenarioDefinitionVers = _WorkflowAgentRule.WorkflowScenarioDefinitionVers
                                                                                    and $projection.WorkflowTaskProcessorRole      = _WorkflowAgentRule.WorkflowAgentRule
{
  key I_WorkflowTask.WorkflowTaskInternalID,
      TopLevelWorkflowTask           as WorkflowInternalID,
      WorkflowTaskStatus             as WorkflowTaskExternalStatus,
      _WorkflowTaskExternalStatus,
      WorkflowTaskDefinition,
      WorkflowTaskCurrentUser        as WorkflowTaskProcessor,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_WorkflowTaskProcessor_2' 
      _WorkflowTaskProcessor,
      _WorkflowTaskProcessor_2,
      WorkflowTaskProcessorRole,
      _WorkflowAgentRule,
      WrkflwTskCreationUTCDateTime,
      WrkflwTskCompletionUTCDateTime,
      WorkflowTaskStepType,
      _WorkflowTaskStepType,
      TopLevelWorkflowTaskDefinition as WorkflowScenarioDefinition,
      WorkflowTaskDefinitionVersion  as WorkflowScenarioDefinitionVers,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_WorkflowRecipients_2'      
      _WorkflowRecipients,
      _WorkflowRecipients_2,
      WorkflowTaskResult.WorkflowTaskResult,
      _WorkflowTaskStepResult
}
where
      WorkflowTaskType           = 'W'
  and WorkflowTaskDefinitionType = 'SCENARIO'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKFLOWTASK",
"I_WORKFLOWTASKRESULT"
],
"ASSOCIATED":
[
"I_BUSINESSUSER",
"I_BUSINESSUSERBASIC",
"I_WORKFLOWAGENTRULE",
"I_WORKFLOWRECIPIENTS",
"I_WORKFLOWRECIPIENTS_V2",
"I_WORKFLOWSTEPRESULT",
"I_WORKFLOWSTEPTYPE",
"I_WORKFLOWTASKEXTERNALSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/