I_WasteStreamPtOfGnrtnLoc

@EndUserText.label: 'Waste Stream Pt Of Generation Location'

@AbapCatalog:
{
  sqlViewName: 'IWSTSTPTGENLOC',
  compiler.compareFilter: true,
  preserveKey:true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED
}

@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  },
  representativeKey: 'WasteStreamPtOfGnrtnLocUUID'
}

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_WasteStreamPtOfGnrtnLoc
  as select distinct from  I_EHSLocHierarchyPath          as LocHierarchy

    inner join             I_EHSLocationHierarchyRevision as LocHierarchyRevision      on  LocHierarchy.EHSLocHierarchyRevisionUUID = LocHierarchyRevision.EHSLocHierarchyRevisionUUID
                                                                                       and LocHierarchyRevision.RevisionStartDate   <= $session.system_date
                                                                                       and LocHierarchyRevision.RevisionEndDate     >= $session.system_date

    inner join             I_EHSLocation                  as LocationRevision          on  LocHierarchy.EHSLocationUUID       = LocationRevision.EHSLocationUUID
                                                                                       and LocationRevision.RevisionStartDate <= $session.system_date
                                                                                       and LocationRevision.RevisionEndDate   >= $session.system_date

    inner join             I_EHSLocClassifier             as LocClassifier             on  LocHierarchy.EHSLocationUUID          = LocClassifier.EHSLocationUUID
                                                                                       and LocClassifier.EHSLocClassifierRefUUID = hextobin(
                                                                                                                  '0A94EF4591D71EDAB6DD6CD513B1A3D0'
                                                                            ) // Point of Waste Generation Classifier

    left outer to one join I_EHSLocClassifier             as LocClassifierGnrtr        on  LocHierarchy.EHSParentLocationUUID         = LocClassifierGnrtr.EHSLocationUUID
                                                                                       and LocClassifierGnrtr.EHSLocClassifierRefUUID = hextobin(
                                                                                                                  '0A94EF4591D71EDAB6DD6AE7E9E883CD'
                                                                            ) // Waste Generator Classifier

    left outer to one join I_EHSLocClassifier             as LocClassifierGnrtrCurrent on  LocHierarchy.EHSLocationUUID                      = LocClassifierGnrtrCurrent.EHSLocationUUID
                                                                                       and LocClassifierGnrtrCurrent.EHSLocClassifierRefUUID = hextobin(
                                                                                                                  '0A94EF4591D71EDAB6DD6AE7E9E883CD'
                                                                            ) // Waste Generator Classifier


  association [1..1] to I_WasteStreamLocationText as _LocText        on  $projection.WasteStreamPtOfGnrtnLocUUID = _LocText.EHSLocationUUID
                                                                     and _LocText.Language                       = $session.system_language

  association [1..1] to I_EHSLocationTypeText     as _LocTypeText    on  $projection.EHSLocationType = _LocTypeText.EHSLocationType
                                                                     and _LocTypeText.Language       = $session.system_language

  association [1..*] to I_EnvrmtWasteGnrtr        as _WasteGenerator on  $projection.EnvrmtWasteGnrtrUUID        = _WasteGenerator.EnvrmtWasteGnrtrUUID
                                                                     or  $projection.WasteStreamPtOfGnrtnLocUUID = _WasteGenerator.EnvrmtWasteGnrtrUUID

{

  key  LocHierarchy.EHSLocationUUID     as WasteStreamPtOfGnrtnLocUUID,

  key  case
         when LocClassifierGnrtrCurrent.EHSLocationUUID is not null
           or LocClassifierGnrtr.EHSLocationUUID is null
         then LocHierarchy.EHSLocationUUID
         else LocHierarchy.EHSParentLocationUUID
       end                              as EnvrmtWasteGnrtrUUID,

       LocationRevision.EHSLocationID   as WasteStreamPtOfGnrtnLocID,

       case
          when LocClassifierGnrtrCurrent.EHSLocationUUID is not null
            or LocClassifierGnrtr.EHSLocationUUID is null
          then LocHierarchy._EHSLocation.EHSLocationID
          else LocHierarchy._EHSParentLocation.EHSLocationID
        end                             as EnvrmtWasteGnrtrID,

       LocationRevision.EHSLocationType as EHSLocationType,

       @Semantics.text: true
       _LocText.EHSLocationName         as WasteStreamPtOfGnrtnLocName,

       @Semantics.text: true
       _LocTypeText.EHSLocationTypeText,

       _LocText,
       _LocTypeText,

       // DCL

       _WasteGenerator

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATION",
"I_EHSLOCATIONHIERARCHYREVISION",
"I_EHSLOCATIONROOT",
"I_EHSLOCATIONTYPETEXT",
"I_EHSLOCCLASSIFIER",
"I_EHSLOCHIERARCHYPATH",
"I_WASTESTREAMLOCATIONTEXT"
],
"ASSOCIATED":
[
"I_EHSLOCATIONTYPETEXT",
"I_ENVRMTWASTEGNRTR",
"I_WASTESTREAMLOCATIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/