I_EHSLocation

DDL: I_EHSLOCATION Type: view BASIC

EHS Location

I_EHSLocation is a Basic CDS View (Dimension) that provides data about "EHS Location" in SAP S/4HANA. It reads from 1 data source (I_EHSLocationRevision) and exposes 47 fields with key fields EHSLocationUUID, RevisionEndDate. It has 2 associations to related views.

1 data source(s) 47 fields

Data Sources (1)

SourceAliasJoin Type
I_EHSLocationRevision I_EHSLocationRevision from

Associations (2)

CardinalityTargetAliasCondition
[0..*] I_EHSLocationHierarchy _EHSLocationHierarchy $projection.EHSLocationUUID = _EHSLocationHierarchy.EHSLocationUUID
[1..1] I_EHSLocationRoot _EHSLocationRoot $projection.EHSLocationUUID = _EHSLocationRoot.EHSLocationUUID

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName ILOCATION view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
EndUserText.label EHS Location view
AccessControl.authorizationCheck #CHECK view
Analytics.dataCategory #DIMENSION view
Analytics.dataExtraction.enabled true view
VDM.viewType #BASIC view
ObjectModel.representativeKey EHSLocationUUID view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MASTER view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.allowExtensions true view
Consumption.filter.businessDate.at true view

Fields (47)

KeyFieldSource TableSource FieldDescription
KEY EHSLocationUUID I_EHSLocationRevision EHSLocationUUID
KEY RevisionEndDate I_EHSLocationRevision RevisionEndDate
RevisionStartDate I_EHSLocationRevision RevisionStartDate
EHSLocationRevisionUUID I_EHSLocationRevision EHSLocationRevisionUUID
CreationDateTime I_EHSLocationRevision CreationDateTime
CreatedByUser I_EHSLocationRevision CreatedByUser
LastChangeDateTime I_EHSLocationRevision LastChangeDateTime
LastChangedByUser I_EHSLocationRevision LastChangedByUser
EHSLocationType I_EHSLocationRevision EHSLocationType
EHSLocationStatus I_EHSLocationRevision EHSLocationStatus
Plant I_EHSLocationRevision Plant
EHSLocationPhone I_EHSLocationRevision EHSLocationPhone
CompanyCode I_EHSLocationRevision CompanyCode
BusinessArea I_EHSLocationRevision BusinessArea
CostCenter I_EHSLocationRevision CostCenter
ControllingArea I_EHSLocationRevision ControllingArea
OrganizationalUnit I_EHSLocationRevision OrganizationalUnit
StorageLocation I_EHSLocationRevision StorageLocation
EHSLocationAuthorizationGroup I_EHSLocationRevision EHSLocationAuthorizationGroup
Country I_EHSLocationRevision Country
Region I_EHSLocationRevision Region
CityName I_EHSLocationRevision CityName
StreetName I_EHSLocationRevision StreetName
PostalCode I_EHSLocationRevision PostalCode
Equipment I_EHSLocationRevision Equipment
FunctionalLocation I_EHSLocationRevision FunctionalLocation
Latitude I_EHSLocationRevision Latitude
Longitude I_EHSLocationRevision Longitude
EHSLocationID _EHSLocationRoot EHSLocationID
_BusinessArea I_EHSLocationRevision _BusinessArea
_CompanyCode I_EHSLocationRevision _CompanyCode
_ControllingArea I_EHSLocationRevision _ControllingArea
_OrganizationalUnit I_EHSLocationRevision _OrganizationalUnit
_StorageLocation I_EHSLocationRevision _StorageLocation
_Country I_EHSLocationRevision _Country
_CreatedByUser I_EHSLocationRevision _CreatedByUser
_EHSLocationRevisionName I_EHSLocationRevision _EHSLocationRevisionName
_EHSLocationAuthGroup I_EHSLocationRevision _EHSLocationAuthGroup
_EHSLocationStatus I_EHSLocationRevision _EHSLocationStatus
_EHSLocationType I_EHSLocationRevision _EHSLocationType
_LastChangedByUser I_EHSLocationRevision _LastChangedByUser
_Plant I_EHSLocationRevision _Plant
_Region I_EHSLocationRevision _Region
_Equipment I_EHSLocationRevision _Equipment
_FunctionalLocation I_EHSLocationRevision _FunctionalLocation
_EHSLocationRoot _EHSLocationRoot
_EHSLocationHierarchy _EHSLocationHierarchy 
@AbapCatalog:{
    sqlViewName: 'ILOCATION',
    compiler.compareFilter: true,
    preserveKey:true 
}
@EndUserText.label: 'EHS Location'
@AccessControl.authorizationCheck: #CHECK
@Analytics: { dataCategory:#DIMENSION , dataExtraction.enabled:true }
@VDM.viewType: #BASIC --#COMPOSITE
@ObjectModel:{
    representativeKey: 'EHSLocationUUID',
    // used for BOBF Master Data Object

    usageType:{ serviceQuality: #C,        // < 15 msec

                             sizeCategory:  #M,         // < 100.000

                             dataClass: #MASTER }
  }


// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
// Begin correction 2765428 - 07.03.2019  **************************

@Consumption.filter.businessDate.at: true
// End correction 2765428 - 07.03.2019  ****************************



define view I_EHSLocation
  as select from I_EHSLocationRevision
  association [0..*] to I_EHSLocationHierarchy as _EHSLocationHierarchy on $projection.EHSLocationUUID = _EHSLocationHierarchy.EHSLocationUUID
  association [1..1] to I_EHSLocationRoot      as _EHSLocationRoot      on $projection.EHSLocationUUID = _EHSLocationRoot.EHSLocationUUID
{
      @ObjectModel.hierarchy.association: '_EHSLocationHierarchy'
      @ObjectModel.text.association: '_EHSLocationRevisionName'
  key I_EHSLocationRevision.EHSLocationUUID,

      @Semantics.businessDate.to
  key I_EHSLocationRevision.RevisionEndDate,


      @Semantics.businessDate.from
      I_EHSLocationRevision.RevisionStartDate,
      I_EHSLocationRevision.EHSLocationRevisionUUID,

      I_EHSLocationRevision.CreationDateTime,
      I_EHSLocationRevision.CreatedByUser,
      I_EHSLocationRevision.LastChangeDateTime,
      I_EHSLocationRevision.LastChangedByUser,

      I_EHSLocationRevision.EHSLocationType,
      I_EHSLocationRevision.EHSLocationStatus,
      I_EHSLocationRevision.Plant,
      I_EHSLocationRevision.EHSLocationPhone,
      
      //--[ GENERATED:012:29JlHNUf7jY4oS0yl5vKTW

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

      I_EHSLocationRevision.CompanyCode,
      //--[ GENERATED:012:29JlHNUf7jY4oS0yl5vKTW

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BusinessAreaStdVH',
                     element: 'BusinessArea' }
        }]
      // ]--GENERATED

      I_EHSLocationRevision.BusinessArea,
      //--[ GENERATED:012:29JlHNUf7jY4oS0yl5vKTW

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CostCenterStdVH',
                     element: 'CostCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      I_EHSLocationRevision.CostCenter,
      I_EHSLocationRevision.ControllingArea,
      I_EHSLocationRevision.OrganizationalUnit,
      I_EHSLocationRevision.StorageLocation,
      I_EHSLocationRevision.EHSLocationAuthorizationGroup,
      I_EHSLocationRevision.Country,
      I_EHSLocationRevision.Region,
      I_EHSLocationRevision.CityName,
      I_EHSLocationRevision.StreetName,
      I_EHSLocationRevision.PostalCode,

      //--[ GENERATED:012:29JlHNUf7jY4oS0yl5vKTW

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EquipmentStdVH',
                     element: 'Equipment' }
        }]
      // ]--GENERATED

      I_EHSLocationRevision.Equipment,
      //--[ GENERATED:012:29JlHNUf7jY4oS0yl5vKTW

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FunctionalLocationStdVH',
                     element: 'FunctionalLocation' }
        }]
      // ]--GENERATED

      I_EHSLocationRevision.FunctionalLocation,

      I_EHSLocationRevision.Latitude,
      I_EHSLocationRevision.Longitude,

      _EHSLocationRoot.EHSLocationID,

      /* Associations */
      I_EHSLocationRevision._BusinessArea,
      I_EHSLocationRevision._CompanyCode,
      I_EHSLocationRevision._ControllingArea,
      I_EHSLocationRevision._OrganizationalUnit,
      I_EHSLocationRevision._StorageLocation,
      //        I_EHSLocationRevision._CostCenter,

      I_EHSLocationRevision._Country,
      I_EHSLocationRevision._CreatedByUser,
      I_EHSLocationRevision._EHSLocationRevisionName,
      I_EHSLocationRevision._EHSLocationAuthGroup,
      I_EHSLocationRevision._EHSLocationStatus,
      I_EHSLocationRevision._EHSLocationType,
      I_EHSLocationRevision._LastChangedByUser,
      I_EHSLocationRevision._Plant,
      I_EHSLocationRevision._Region,
      I_EHSLocationRevision._Equipment,
      I_EHSLocationRevision._FunctionalLocation,
      _EHSLocationRoot,
      _EHSLocationHierarchy
      //        ,

      //        _EHSLocationHierarchy.EHSLocHierarchyUUID,

      //        _EHSLocationHierarchy._EHSLocationHierarchyRevision

}
where
       I_EHSLocationRevision.RevisionStartDate <= $session.system_date
  and  I_EHSLocationRevision.RevisionEndDate   >= $session.system_date // consider current location revisions only

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATIONREVISION",
"I_EHSLOCATIONROOT"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_EHSLOCATIONAUTHZNGROUP",
"I_EHSLOCATIONHIERARCHY",
"I_EHSLOCATIONREVISIONNAMET",
"I_EHSLOCATIONROOT",
"I_EHSLOCATIONSTATUS",
"I_EHSLOCATIONTYPE",
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_ORGUNIT",
"I_PLANT",
"I_REGION",
"I_STORAGELOCATION",
"I_USER"
],
"BASE":
[
"I_EHSLOCATIONREVISION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More