I_WBSElementVersionData

@AbapCatalog: {
  sqlViewName: 'IWBSELVERSDATA',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'WBS Element Version Data'
@ObjectModel: {
    usageType: {
        serviceQuality: #B,
        sizeCategory : #XL,
        dataClass: #MASTER
    }
}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define view I_WBSElementVersionData
  as select from           vsprps_cn
    left outer to one join vsprte_cn on  vsprps_cn.pspnr = vsprte_cn.posnr
                                     and vsprps_cn.psphi = vsprte_cn.psphi
                                     and vsprps_cn.vsnmr = vsprte_cn.vsnmr

  association [1..1] to I_ProjectVersionData       as _Project                on  $projection.ProjectInternalID = _Project.ProjectInternalID
                                                                              and $projection.Version           = _Project.Version
  association [0..1] to I_CompanyCode              as _CompanyCode            on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea          as _ControllingArea        on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_FunctionalArea           as _FunctionalArea         on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..*] to I_ProfitCenter             as _ProfitCenter           on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                              and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..*] to I_CostCenter               as _ResponsibleCostCenter  on  $projection.ControllingArea       = _ResponsibleCostCenter.ControllingArea
                                                                              and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
  association [0..1] to I_Plant                    as _Plant                  on  $projection.Plant = _Plant.Plant
  association [0..1] to I_FactoryCalendar          as _FactoryCalendar        on  $projection.FactoryCalendar = _FactoryCalendar.FactoryCalendar
  association [0..*] to I_CostCenter               as _CostCenter             on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                              and $projection.CostCenter      = _CostCenter.CostCenter
  association [1..1] to I_Projecttype              as _ProjectType            on  $projection.ProjectType = _ProjectType.ProjectType
  association [1..1] to I_Prioritycode             as _PriorityCode           on  $projection.PriorityCode = _PriorityCode.PriorityCode
  association [1..1] to I_ControllingObjectClass   as _ControllingObjectClass on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [1..1] to I_BusinessArea             as _BusinessArea           on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson      on  $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  association [0..1] to I_ProjectApplicant         as _ProjectApplicant       on  $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
  association [1..1] to E_WBSElementVersionData    as _Extension              on  $projection.WBSElementInternalID = _Extension.WBSElementInternalID
                                                                              and $projection.Version              = _Extension.Version
{
  key cast ( vsprps_cn.pspnr as ps_s4_pspnr preserving type )           as WBSElementInternalID,
  key cast ( vsprps_cn.vsnmr as vsnmr_v preserving type )               as Version,
      @ObjectModel.text.element: 'WBSDescription'
      vsprps_cn.posid_edit                                              as WBSElementExternalID,
      @ObjectModel.text.element: 'WBSDescription'
      cast ( vsprps_cn.posid as ps_posid_edit preserving type )         as WBSElement,
      vsprps_cn.poski                                                   as WBSElementShortID,
      @Semantics.text: true
      cast ( vsprps_cn.post1 as ps_s4_post1 preserving type )           as WBSDescription,
      cast ( vsprps_cn.vernr as ps_s4_vernr preserving type )           as ResponsiblePerson,
      cast ( vsprps_cn.verna as ps_s4_verna preserving type )           as ResponsiblePersonName,
      cast ( vsprps_cn.astnr as ps_s4_astnr preserving type )           as ApplicantCode,
      vsprps_cn.astna                                                   as ApplicantName,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast ( vsprps_cn.pbukr as bukrs preserving type )                 as CompanyCode,
      cast ( vsprps_cn.pgsbr as gsber preserving type )                 as BusinessArea,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      cast ( vsprps_cn.pkokr as ps_s4_kokrs preserving type )           as ControllingArea,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      cast ( vsprps_cn.func_area as fkber preserving type )             as FunctionalArea,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      vsprps_cn.prctr                                                   as ProfitCenter,
      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      cast ( vsprps_cn.fkstl as ps_s4_fkstl preserving type )           as ResponsibleCostCenter,
      @ObjectModel.foreignKey.association: '_Plant'
      vsprps_cn.werks                                                   as Plant,
      vsprps_cn.slwid                                                   as FreeDefinedTableFieldSemantic,
      @ObjectModel.foreignKey.association: '_FactoryCalendar'
      cast ( vsprps_cn.fabkl as stkal preserving type )                 as FactoryCalendar,
      cast ( vsprps_cn.pspri as nw_prio preserving type )               as PriorityCode,
      cast ( vsprps_cn.pwpos as ps_pwpos preserving type )              as Currency,
      vsprps_cn.kalsm                                                   as CostingSheet,
      @ObjectModel.foreignKey.association: '_CostCenter'
      cast ( vsprps_cn.kostl as ps_kostl preserving type )              as CostCenter,
      cast ( vsprps_cn.akstl as ps_s4_akstl preserving type )           as RequestingCostCenter,
      //_Project.ProjectObject,

      @ObjectModel.foreignKey.association: '_Project'
      cast ( vsprps_cn.psphi as ps_s4_proj_pspnr preserving type )      as ProjectInternalID,
      cast ( vsprps_cn.fakkz as ps_fakkz preserving type )              as WBSElementIsBillingElement,
      vsprps_cn.objnr                                                   as WBSElementObject,
      vsprps_cn.imprf                                                   as InvestmentProfile,
      vsprps_cn.xstat                                                   as WBSIsStatisticalWBSElement,
      cast ( vsprps_cn.belkz as ps_s4_belkz preserving type )           as WBSIsAccountAssignmentElement,
      vsprps_cn.prart                                                   as ProjectType,
      cast ( vsprps_cn.plakz as ps_plakz preserving type )              as WBSElementIsPlanningElement,
      vsprps_cn.stort                                                   as WorkCenterLocation,
      vsprps_cn.abgsl                                                   as ResultAnalysisInternalID,
      vsprps_cn.txjcd                                                   as TaxJurisdiction,
      cast ( vsprps_cn.tplnr as tplnr_unconverted preserving type )     as FunctionalLocation,
      @Semantics.user.createdBy: true
      vsprps_cn.ernam                                                   as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      vsprps_cn.erdat                                                   as CreationDate,
      @Semantics.user.lastChangedBy: true
      vsprps_cn.aenam                                                   as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      vsprps_cn.aedat                                                   as LastChangeDate,
      vsprps_cn.fkokr                                                   as RespCostCenterControllingArea,
      cast ( vsprps_cn.plint as plint_t preserving type )               as WBSIsMarkedForIntegratedPlng,
      vsprps_cn.equnr                                                   as Equipment,
      vsprps_cn.aennr                                                   as ProjectObjectChangeNumber,
      vsprps_cn.stufe                                                   as WBSElementHierarchyLevel,
      cast ( vsprps_cn.zschl as fin_ovhkey preserving type )            as OverheadCode,
      cast ( vsprps_cn.adpsp as ps_s4_addcompare_core preserving type ) as ReferenceElement,
      vsprps_cn.zschm                                                   as ProjInterestCalcProfile,
      cast ( vsprps_cn.evgew as ev_weightd preserving type )            as ProgressAnlysAggregationWeight,
      vsprps_cn.akokr                                                   as ReqgCostCenterControllingArea,
      vsprps_cn.txtsp                                                   as Language,
      cast( vsprps_cn.loevm as ps_s4_loevm )                            as IsMarkedForDeletion,
      @Semantics.booleanIndicator: true
      vsprps_cn.grpkz                                                   as WBSElementIsGroupingWBSElement,
      vsprps_cn.clasf                                                   as WBSElementIsUsedInProjSmmry,
      vsprps_cn.klvar                                                   as CostingVariant,
      cast ( pstrt as ps_s4_pstrt preserving type )                     as BasicStartDate,
      cast ( estrt as ps_s4_estrt preserving type )                     as ForecastedStartDate,
      cast ( istrt as ps_s4_istrt preserving type )                     as ActualStartDate,
      cast ( pende as ps_s4_pende preserving type )                     as BasicEndDate,
      cast ( eende as ps_s4_eende preserving type )                     as ForecastedEndDate,
      cast ( iende as ps_s4_iende preserving type )                     as ActualEndDate,
      @Semantics.quantity.unitOfMeasure: 'BasicDurationUnit'
      cast ( pdaur as ps_s4_pdaur preserving type )                     as BasicDuration,
      @Semantics.unitOfMeasure: true
      cast ( peinh as ps_s4_peinh preserving type )                     as BasicDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'ForecastedDurationUnit'
      cast( edaur as ps_s4_edaur preserving type )                      as ForecastedDuration,
      @Semantics.unitOfMeasure: true
      cast ( eeinh as ps_s4_eeinh preserving type )                     as ForecastedDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'ActualDurationUnit'
      cast ( idaur as ps_s4_idaur preserving type )                     as ActualDuration,
      @Semantics.unitOfMeasure: true
      cast ( ieinh as ps_ieinh preserving type )                        as ActualDurationUnit,
      cast ( pstrm as ps_gstrs preserving type )                        as SchedldBasicEarliestStartDate,
      cast ( petrm as ps_s4_gltrs preserving type )                     as ScheduledBasicLatestEndDate,
      cast ( estrm as ps_s4_gstpp preserving type )                     as SchedldFcstdEarliestStartDate,
      cast ( eetrm as ps_s4_gltpp preserving type )                     as LatestSchedldFcstdEndDate,
      cast ( vistr as ps_s4_istvorl preserving type )                   as TentativeActualStartDate,
      cast ( viend as ps_s4_ienvorl preserving type )                   as TentativeActualEndDate,
      vsprps_cn.vname                                                   as JointVenture,
      vsprps_cn.recid                                                   as JointVentureCostRecoveryCode,
      vsprps_cn.etype                                                   as JointVentureEquityType,
      vsprps_cn.otype                                                   as JntVntrProjectType,
      vsprps_cn.jibcl                                                   as JntIntrstBillgClass,
      vsprps_cn.jibsa                                                   as JntIntrstBillgSubClass,
      vsprps_cn.subpr                                                   as SubProject,
      vsprps_cn.izwek                                                   as InvestmentReason,
      vsprps_cn.isize                                                   as InvestmentScale,
      vsprps_cn.iumkz                                                   as EnvironmentalInvestmentReason,
      vsprps_cn.abukr                                                   as RequestingCompanyCode,
      vsprps_cn.zuord                                                   as NetworkAssignmentType,
      vsprps_cn.ktrg                                                    as CostObject,
      vsprps_cn.fplnr                                                   as BillingPlan,
      cast ( vsprps_cn.scope as ps_s4_scope_cv )                        as ControllingObjectClass,
      cast ( vsprps_cn.usr00 as usr00prps preserving type )             as FreeDefinedAttribute01,
      cast ( vsprps_cn.usr01 as usr01prps preserving type )             as FreeDefinedAttribute02,
      cast ( vsprps_cn.usr02 as usr02prps preserving type )             as FreeDefinedAttribute03,
      cast ( vsprps_cn.usr03 as usr03prps preserving type )             as FreeDefinedAttribute04,
      @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity1Unit'
      cast ( vsprps_cn.usr04 as usr04prps preserving type )             as FreeDefinedQuantity1,
      cast ( vsprps_cn.use04 as use04prps preserving type )             as FreeDefinedQuantity1Unit,
      @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity2Unit'
      cast ( vsprps_cn.usr05 as usr05prps preserving type )             as FreeDefinedQuantity2,
      cast ( vsprps_cn.use05 as use05prps preserving type )             as FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      cast ( vsprps_cn.usr06 as abap.curr( 13, 2 ) )                    as FreeDefinedAmount1,
      cast ( vsprps_cn.use06 as use06prps preserving type )             as FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      cast ( vsprps_cn.usr07 as abap.curr( 13, 2 ) )                    as FreeDefinedAmount2,
      cast ( vsprps_cn.use07 as use07prps preserving type )             as FreeDefinedAmount2Currency,
      cast ( vsprps_cn.usr08 as usr08prps preserving type )             as FreeDefinedDate1,
      cast ( vsprps_cn.usr09 as usr09prps preserving type )             as FreeDefinedDate2,
      cast ( vsprps_cn.usr10 as usr10prps preserving type )             as FreeDefinedIndicator1,
      cast ( vsprps_cn.usr11 as usr11prps preserving type )             as FreeDefinedIndicator2,
      case dats_is_valid( vsprte_cn.pstrs )
                when 0
                then '00000000'
                else vsprte_cn.pstrs
                end                                                     as SchedldBasicLatestStartDate,
      cast ( case dats_is_valid( vsprte_cn.petrf )
                when 0
                then '00000000'
                else vsprte_cn.petrf
                end  as ps_s4_getre preserving type )                   as SchedldBasicEarliestEndDate,
      cast ( case dats_is_valid( vsprte_cn.estrs )
                when 0
                then '00000000'
                else vsprte_cn.estrs
                end  as ps_s4_gstrp preserving type )                   as LatestSchedldFcstdStartDate,
      cast ( case dats_is_valid( vsprte_cn.eetrf )
                when 0
                then '00000000'
                else vsprte_cn.eetrf
                end  as ps_s4_gltrp preserving type )                   as SchedldFcstdEarliestEndDate,

      _Project,
      _CompanyCode,
      _ControllingArea,
      _FunctionalArea,
      _ProfitCenter,
      _ResponsibleCostCenter,
      _Plant,
      _FactoryCalendar,
      _CostCenter,
      _ProjectType,
      _PriorityCode,
      _ControllingObjectClass,
      _BusinessArea,
      @Consumption.hidden: true
      _ResponsiblePerson,
      @Consumption.hidden: true
      _ProjectApplicant
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VSPRPS_CN",
"VSPRTE_CN"
],
"ASSOCIATED":
[
"E_WBSELEMENTVERSIONDATA",
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_FACTORYCALENDAR",
"I_FUNCTIONALAREA",
"I_PLANT",
"I_PRIORITYCODE",
"I_PROFITCENTER",
"I_PROJECTAPPLICANT",
"I_PROJECTRESPONSIBLEPERSON",
"I_PROJECTTYPE",
"I_PROJECTVERSIONDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/