I_ProjectVersionData

@AbapCatalog: {
  sqlViewName: 'IPROJVERSDAT',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Project Version Data'
@ObjectModel: {
    representativeKey: 'ProjectInternalID',
    usageType: {
        serviceQuality: #B,
        sizeCategory : #L,
        dataClass: #TRANSACTIONAL
    }
}
@VDM.viewType: #BASIC

define view I_ProjectVersionData
  as select from vsproj_cn
  association [0..1] to I_ProjectResponsiblePerson   as _ResponsiblePerson         on  $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  association [0..1] to I_ProjectApplicant           as _ProjectApplicant          on  $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
  association [1..1] to I_ProjectProfileCode         as _ProjectProfileCode        on  $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode
  association [1..*] to I_ProfitCenter               as _ProfitCenter              on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                   and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [1..*] to I_NetworkProfile             as _NetworkProfile            on  $projection.NetworkProfile = _NetworkProfile.NetworkProfile
  association [1..*] to I_TaxJurisdiction            as _TaxJurisdiction           on  $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
  association [1..1] to I_Interestcalculationprofile as _ProjInterestCalcProfile   on  $projection.ProjInterestCalcProfile = _ProjInterestCalcProfile.ProjInterestCalcProfile
  association [1..1] to I_FunctionalArea             as _FunctionalArea            on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [1..1] to I_PlanningMethod             as _ProjBasicDatePlanMethName on  $projection.PlanningMethForProjBasicDate = _ProjBasicDatePlanMethName.PlanningMethForProjBasicDate
  association [1..1] to I_PlanningMethod             as _ProjFcstdDatePlanMethName on  $projection.PlanningMethForProjFcstdDate = _ProjFcstdDatePlanMethName.PlanningMethForProjBasicDate
  association [1..1] to I_Wbsschedulingprofile       as _Wbsschedulingprofile      on  $projection.WBSSchedulingProfile = _Wbsschedulingprofile.WBSSchedulingProfile
  association [1..1] to I_ControllingObjectClass     as _ControllingObjectClass    on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass

{
  key cast ( vsproj_cn.pspnr as ps_s4_proj_pspnr preserving type )  as ProjectInternalID,
  key cast ( vsproj_cn.vsnmr as ps_s4_vsnmr preserving type )       as Version,
      @ObjectModel.text.element: 'ProjectDescription'
      vsproj_cn.pspid_edit                                          as ProjectExternalID,
      cast( vsproj_cn.pspid as cc_ps_pspid )                        as Project,
      cast( vsproj_cn.post1 as ps_s4_proj_post1_v1 preserving type) as ProjectDescription,
      vsproj_cn.profl                                               as ProjectProfileCode,
      cast ( vsproj_cn.vernr as ps_s4_vernr )                       as ResponsiblePerson,
      cast ( vsproj_cn.verna as ps_s4_verna )                       as ResponsiblePersonName,
      vsproj_cn.prctr                                               as ProfitCenter,
      cast ( vsproj_cn.vkokr as kokrs )                             as ControllingArea,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.plfaz as ps_plfaz_chg )                      as PlannedStartDate,
      @Semantics.calendar.dayOfMonth: true
      cast ( vsproj_cn.plsez as ps_plsez_chg )                      as PlannedEndDate,
      cast ( vsproj_cn.loevm as ps_s4_loevm )                       as IsMarkedForDeletion,
      cast ( vsproj_cn.astnr as ps_s4_astnr )                       as ApplicantCode,
      vsproj_cn.objnr                                               as ProjectObject,
      cast ( vsproj_cn.vgplf as ps_s4_vgplf )                       as PlanningMethForProjBasicDate,
      cast ( vsproj_cn.ewplf as ps_s4_ewplf )                       as PlanningMethForProjFcstdDate,
      cast ( vsproj_cn.vbukr as bukrs )                             as CompanyCode,
      cast (vsproj_cn.ernam as ernam )                              as CreatedByUser,
      cast (vsproj_cn.erdat as erdat)                               as CreationDate,
      cast ( vsproj_cn.aenam as ps_s4_aenam )                       as LastChangedByUser,
      cast ( vsproj_cn.aedat as ps_s4_aedat )                       as LastChangeDate,
      vsproj_cn.astna                                               as ApplicantName,
      cast ( vsproj_cn.vgsbr as gsber )                             as BusinessArea,
      vsproj_cn.werks                                               as Plant,
      cast ( vsproj_cn.kostl as kostl )                             as CostCenter,
      cast ( vsproj_cn.scope as ps_s4_scope_cv )                    as ControllingObjectClass,
      cast ( vsproj_cn.sprog as pshlp_forecast_start_de )           as ForecastedStartDate,
      cast ( vsproj_cn.eprog as ps_s4_forecast_finish )             as ForecastedEndDate,
      cast ( vsproj_cn.pwhie as ps_pwhie )                          as Currency,
      cast ( vsproj_cn.kalid as appca )                             as FactoryCalendar,
      vsproj_cn.vprof                                               as NetworkProfile,
      cast ( vsproj_cn.besta as psb_stock )                         as ProjectHasOwnStock,
      vsproj_cn.xstat                                               as WBSIsStatisticalWBSElement,
      cast ( vsproj_cn.txjcd as wb2_txjcd_busvol )                  as TaxJurisdiction,
      cast ( vsproj_cn.zschm as ps_zschm )                          as ProjInterestCalcProfile,
      vsproj_cn.imprf                                               as InvestmentProfile,
      vsproj_cn.bprof                                               as BudgetProfile,
      vsproj_cn.pprof                                               as PlanningProfile,
      cast ( vsproj_cn.func_area as fkber )                         as FunctionalArea,
      cast ( vsproj_cn.zteht as cgpl_duration_unit )                as SchedulingDurationUnit,
      cast ( vsproj_cn.scprf as ps_s4_schdprf )                     as WBSSchedulingProfile,
      vsproj_cn.slwid                                               as FreeDefinedTableFieldSemantic,
      cast ( vsproj_cn.usr00 as usr00proj preserving type )         as FreeDefinedAttribute01,
      cast ( vsproj_cn.usr01 as usr01proj preserving type )         as FreeDefinedAttribute02,
      cast ( vsproj_cn.usr02 as usr02proj preserving type )         as FreeDefinedAttribute03,
      cast ( vsproj_cn.usr03 as usr03proj preserving type )         as FreeDefinedAttribute04,
      @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity1Unit'
      cast ( vsproj_cn.usr04 as usr04proj preserving type )         as FreeDefinedQuantity1,
      cast ( vsproj_cn.use04 as use04proj preserving type )         as FreeDefinedQuantity1Unit,
      @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity2Unit'
      cast ( vsproj_cn.usr05 as usr05proj preserving type )         as FreeDefinedQuantity2,
      cast ( vsproj_cn.use05 as use05proj preserving type )         as FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      cast ( vsproj_cn.usr06 as usr06proj preserving type )         as FreeDefinedAmount1,
      cast ( vsproj_cn.use06 as use06proj preserving type )         as FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      cast ( vsproj_cn.usr07 as usr07proj preserving type )         as FreeDefinedAmount2,
      cast ( vsproj_cn.use07 as use07proj preserving type )         as FreeDefinedAmount2Currency,
      cast ( vsproj_cn.usr08 as usr08proj preserving type )         as FreeDefinedDate1,
      cast ( vsproj_cn.usr09 as usr09proj preserving type )         as FreeDefinedDate2,
      cast ( vsproj_cn.usr10 as usr10proj preserving type )         as FreeDefinedIndicator1,
      cast ( vsproj_cn.usr11 as usr11proj preserving type )         as FreeDefinedIndicator2,

      _ResponsiblePerson,
      _ProjectApplicant,
      _ProjectProfileCode,
      _NetworkProfile,
      _ProjInterestCalcProfile,
      _FunctionalArea,
      _TaxJurisdiction,
      _Wbsschedulingprofile,
      _ProfitCenter,
      _ProjBasicDatePlanMethName,
      _ProjFcstdDatePlanMethName,
      _ControllingObjectClass
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VSPROJ_CN"
],
"ASSOCIATED":
[
"I_CONTROLLINGOBJECTCLASS",
"I_FUNCTIONALAREA",
"I_INTERESTCALCULATIONPROFILE",
"I_NETWORKPROFILE",
"I_PLANNINGMETHOD",
"I_PROFITCENTER",
"I_PROJECTAPPLICANT",
"I_PROJECTPROFILECODE",
"I_PROJECTRESPONSIBLEPERSON",
"I_TAXJURISDICTION",
"I_WBSSCHEDULINGPROFILE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/