I_UtilitiesInvoicingDocument

@EndUserText.label: 'Invoicing Document'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEINVOICINGDOC'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'UtilitiesInvoicingDocument'
@Metadata.allowExtensions:true
//@AbapCatalog.preserveKey:true

@AbapCatalog.compiler.compareFilter:true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilitiesInvoicingDocument
  as select from erdk
  association [1..1] to I_UtilitiesInvoicingReason as _UtilitiesInvoicingReason on $projection.UtilitiesInvoicingReason = _UtilitiesInvoicingReason.UtilitiesInvoicingReason
  association [0..1] to I_UtilsInvcgDocReversalRsn as _UtilsInvcgDocReversalRsn on $projection.UtilsInvcgDocReversalRsn = _UtilsInvcgDocReversalRsn.UtilsInvcgDocReversalRsn
  association [1..1] to I_UtilsInvcgPrntBlockRsn   as _UtilsInvcgPrntBlockRsn   on $projection.UtilsInvcgDocPrintBlockRsn = _UtilsInvcgPrntBlockRsn.UtilsInvcgDocPrintBlockRsn
  association [0..1] to I_UtilitiesPortion         as _UtilitiesPortion         on $projection.UtilitiesPortion = _UtilitiesPortion.UtilitiesPortion
  association [1..1] to I_UtilitiesBillingReason   as _UtilitiesBillingReason   on $projection.UtilitiesBillingReason = _UtilitiesBillingReason.UtilitiesBillingReason
  association [0..1] to I_BusinessPartner          as _BusinessPartner          on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  //association [0..1] to I_ContractAccount as _ContractAccount on $projection.ContractAccount = _ContractAccount.ContractAccount

  association [0..1] to I_Currency                 as _Currency                 on $projection.TransactionCurrency = _Currency.Currency
  association [0..1] to I_User                     as _CreatedByUser            on $projection.UtilsInvcgDocCreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                     as _LastChangedByUser        on $projection.UtilsInvcgDocLastChangedByUser = _LastChangedByUser.UserID
{
  key cast (erdk.opbel as e_printdoc_vdm preserving type) as UtilitiesInvoicingDocument,

      //@Semantics.businessDate.at: true

      erdk.druckdat                                       as UtilitiesInvoicingDocPrintDate,

      //      @Semantics.calendarItem.due: true

      erdk.faedn                                          as NetDueDate,

      //      @Semantics.calendarItem.due: true

      erdk.faeds                                          as CashDiscountDueDate,

      erdk.sktpz                                          as CashDiscountPercent,

      @Semantics.businessDate.at: true
      erdk.budat                                          as PostingDate,

      //@Semantics.businessDate.at: true

      erdk.bldat                                          as DocumentDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      //@DefaultAggregation: #SUM

      erdk.total_amnt                                     as TotalAmountInTransactionCrcy,

      @Semantics.currencyCode: true
      erdk.total_waer                                     as TransactionCurrency,

      erdk.pymet                                          as PaymentMethod,

      @ObjectModel.foreignKey.association: '_UtilitiesInvoicingReason'
      erdk.ergrd                                          as UtilitiesInvoicingReason,
      @Semantics.booleanIndicator:true
      erdk.stokz                                          as UtilsInvcgDocIsReversed,

      @ObjectModel.foreignKey.association: '_UtilsInvcgDocReversalRsn'
      erdk.icreason                                       as UtilsInvcgDocReversalRsn,

      erdk.intopbel                                       as ReversalUtilsInvcgDocument,
      @Semantics.booleanIndicator:true
      erdk.tobreleasd                                     as UtilsInvcgDocIsNotReleased,
      @Semantics.booleanIndicator:true
      erdk.simulated                                      as UtilsInvcgDocIsSimulated,
      @Semantics.booleanIndicator:true
      erdk.invoiced                                       as UtilsInvcgDocumentIsPosted,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      erdk.partner                                        as BusinessPartner,

      //@ObjectModel.foreignKey.association: '_ContractAccount'

      erdk.vkont                                          as ContractAccount,

      @ObjectModel.foreignKey.association: '_UtilitiesPortion'
      erdk.portion                                        as UtilitiesPortion,

      @ObjectModel.foreignKey.association: '_UtilitiesBillingReason'
      erdk.abrvorg                                        as UtilitiesBillingReason,

      erdk.fikey                                          as CAReconciliationKey,

      erdk.invoicing_party                                as UtilitiesInvoicingParty,

      @Semantics.systemDate.createdAt: true
      erdk.erdat                                          as UtilsInvcgDocCreationDate,

      @Semantics.user.createdBy: true
      erdk.ernam                                          as UtilsInvcgDocCreatedByUser,

      @Semantics.systemDate.lastChangedAt: true
      erdk.aedat                                          as UtilsInvcgDocLastChangeDate,

      @Semantics.user.lastChangedBy: true
      erdk.aenam                                          as UtilsInvcgDocLastChangedByUser,

      //@Semantics.businessDate.at: true

      erdk.sto_budat                                      as OriginalUtilsInvcgDocRvslDate,

      erdk.sto_opbel                                      as OriginalUtilsInvcgDocument,

      @ObjectModel.foreignKey.association: '_UtilsInvcgPrntBlockRsn'
      erdk.printlock                                      as UtilsInvcgDocPrintBlockRsn,

      erdk.begru                                          as AuthorizationGroup,


      /* Associations */
      _UtilitiesInvoicingReason,
      _UtilsInvcgDocReversalRsn,
      _UtilsInvcgPrntBlockRsn,
      _UtilitiesPortion,
      _UtilitiesBillingReason,
      _BusinessPartner,
      //_ContractAccount,

      _Currency,
      _CreatedByUser,
      _LastChangedByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ERDK"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_USER",
"I_UTILITIESBILLINGREASON",
"I_UTILITIESINVOICINGREASON",
"I_UTILITIESPORTION",
"I_UTILSINVCGDOCREVERSALRSN",
"I_UTILSINVCGPRNTBLOCKRSN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/