C_UtilsInvcgDocOutsrtgData

@EndUserText.label: 'Outsorting Data for Invoicing Document'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CEINVCGDOCOUTDAT'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.presentationVariant:[{
    requestAtLeast:  [ 'UtilsInvoicingCheckValue1',
                       'UtilsInvoicingCheckName1',
                       'UtilsInvoicingCheckValue2',
                       'UtilsInvoicingCheckName2',
                       'UtilsInvoicingCheckValue3',
                       'UtilsInvoicingCheckName3',
                       'UtilsInvoicingCheckValue4',
                       'UtilsInvoicingCheckName4',
                       'UtilsInvoicingCheckText',
                       'UtilsInvoicingCheckName5' ]
}]
define view C_UtilsInvcgDocOutsrtgData
  as select from I_UtilsInvcgDocOutsrtgData   as UtilsInvcgDocOutsrtgData
    inner join   I_UtilitiesInvoicingDocument as UtilitiesInvoicingDocument on UtilitiesInvoicingDocument.UtilitiesInvoicingDocument = UtilsInvcgDocOutsrtgData.UtilitiesInvoicingDocument

{
       @UI.hidden: true
       @ObjectModel.foreignKey.association: '_UtilitiesInvoicingDocument'
  key  UtilsInvcgDocOutsrtgData.UtilitiesInvoicingDocument,

       @UI.hidden: true
  key  UtilsInvcgDocOutsrtgData.UtilsInvcgDocSqncNmbrOutsrtg,

       @UI.textArrangement: #TEXT_SEPARATE
       @UI.lineItem: [{ position: 10, importance: #HIGH }]
       @ObjectModel.foreignKey.association: '_UtilitiesInvoicingCheck'
       UtilsInvcgDocOutsrtgData.UtilitiesInvoicingCheck,

       @UI.lineItem: [{ position: 20, importance: #HIGH }]
       UtilsInvcgDocOutsrtgData.UtilsOutsrtdInvcgDocDvtgValue,

       cast(cast('' as abap.char(8)) as e_outsrtgchkgrpinvcg_vdm preserving type) as UtilsOutsrtgCheckGrpForInvcg,

       cast(0 as abap.dec(11,3) )                                                 as UtilsInvoicingCheckValue1,

       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingCheck._Text[1: Language=$session.system_language].UtilsInvoicingCheckName1,

       cast(0 as abap.dec(11,3) )                                                 as UtilsInvoicingCheckValue2,

       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingCheck._Text[1: Language=$session.system_language].UtilsInvoicingCheckName2,

       cast(0 as abap.dec(11,3) )                                                 as UtilsInvoicingCheckValue3,

       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingCheck._Text[1: Language=$session.system_language].UtilsInvoicingCheckName3,

       cast(0 as abap.dec(11,3) )                                                 as UtilsInvoicingCheckValue4,

       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingCheck._Text[1: Language=$session.system_language].UtilsInvoicingCheckName4,

       cast('' as abap.char(10) )                                                 as UtilsInvoicingCheckText,

       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingCheck._Text[1: Language=$session.system_language].UtilsInvoicingCheckName5,

       @UI.hidden: true
       UtilsInvcgDocOutsrtgData.UtilsInvcgDocIsReldBackground,

       /* Associations */
       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingDocument,
       UtilsInvcgDocOutsrtgData._UtilitiesInvoicingCheck

}
where
      UtilsInvcgDocOutsrtgData.UtilsInvcgDocReleasedByUser  = '' //Not Released

  and UtilsInvcgDocOutsrtgData.UtilsInvcgOutsortingReason   = '' //Not Manually Outsorted

  and UtilitiesInvoicingDocument.UtilsInvcgDocIsNotReleased = 'X' //Not Released

  and UtilitiesInvoicingDocument.UtilsInvcgDocIsReversed    = ''  //Not Reversed

  and UtilitiesInvoicingDocument.UtilsInvcgDocIsSimulated   = ''  //Not Simulated

//  and UtilsInvcgDocOutsrtgData.UtilsInvcgDocIsReldBackground = '' // Not released

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_UTILITIESINVOICINGCHECK",
"I_UTILITIESINVOICINGCHECKTEXT",
"I_UTILITIESINVOICINGDOCUMENT",
"I_UTILSINVCGDOCOUTSRTGDATA"
],
"ASSOCIATED":
[
"I_UTILITIESINVOICINGCHECK",
"I_UTILITIESINVOICINGDOCUMENT"
],
"BASE":
[
"I_UTILSINVCGDOCOUTSRTGDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/