I_UtilitiesContractHistory

@EndUserText.label: 'Utilities Contract History'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEUTILSCONTHIST'
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #ANALYTICAL_PROVIDER, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@AbapCatalog.compiler.compareFilter:true
@ObjectModel.representativeKey:'UtilitiesContract'
@Metadata.allowExtensions:true
//@AbapCatalog.preserveKey:true

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilitiesContractHistory
  as select from everh
  association [0..1] to I_UtilitiesInstallation       as _UtilitiesInstallation       on $projection.UtilitiesInstallation = _UtilitiesInstallation.UtilitiesInstallation
  //association [0..1] to I_UtilitiesContract           as _UtilitiesContract           on $projection.UtilsMstrAgrmtForIndivContract = _UtilitiesContract.UtilitiesContract

  association [0..1] to I_UtilitiesContract           as _UtilsMstrAgrmtForIndivContr on $projection.UtilsMstrAgrmtForIndivContract = _UtilsMstrAgrmtForIndivContr.UtilitiesContract
  association [1..1] to I_UtilitiesContract           as _UtilitiesContract           on $projection.UtilitiesContract = _UtilitiesContract.UtilitiesContract
  association [1..1] to I_UtilsContrHistFourDigitNmbr as _UtilsContrHistFourDigitNmbr on $projection.UtilitiesFourDigitNumber = _UtilsContrHistFourDigitNmbr.UtilitiesFourDigitNumber
{

  key everh.vertrag          as UtilitiesContract,

      @Semantics.businessDate.to: true
  key everh.bis              as UtilsContractValidityEndDate,

      @ObjectModel.foreignKey.association: '_UtilsContrHistFourDigitNmbr'
  key everh.num              as UtilitiesFourDigitNumber,

      @Semantics.businessDate.from: true
      everh.ab               as UtilsContractValidityStartDate,

      @ObjectModel.foreignKey.association: '_UtilitiesInstallation'
      everh.anlage           as UtilitiesInstallation,

      everh.crm_product      as UtilitiesProduct,

      everh.crm_object_id    as UtilsTransNumberInCRMDocument,

      everh.crm_object_pos   as UtilsItemNumberInCRMDocument,

      //      everh.campaign         as UtilitiesMarketingCampaign,


      //      @Semantics.businessDate.to: true

      everh.campaign_to_date as UtilsMarketingCampaignEndDate,

      everh.loevm            as DeletionIndicator,

      //@ObjectModel.foreignKey.association: '_UtilitiesContract'

      @ObjectModel.foreignKey.association: '_UtilsMstrAgrmtForIndivContr'
      everh.oucontract       as UtilsMstrAgrmtForIndivContract,

      everh.crm_item_descr   as UtilitiesContractDescription,


      /* Associations */
      _UtilitiesInstallation,
      _UtilsMstrAgrmtForIndivContr,
      _UtilitiesContract,
      _UtilsContrHistFourDigitNmbr
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EVERH"
],
"ASSOCIATED":
[
"I_UTILITIESCONTRACT",
"I_UTILITIESINSTALLATION",
"I_UTILSCONTRHISTFOURDIGITNMBR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/