I_UtilitiesContract

@EndUserText.label: 'Contract'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEUTILSCONTRACT'
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #ANALYTICAL_PROVIDER, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@AbapCatalog.compiler.compareFilter:true
@ObjectModel.representativeKey: 'UtilitiesContract'
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

//Privileged associations specified

@AccessControl.privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
@Metadata.allowExtensions: true

define view I_UtilitiesContract
  as select from ever
  association [0..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Division                    as _Division                    on  $projection.UtilitiesDivision = _Division.Division
  association [0..1] to I_UtilsBillgBlockReason       as _UtilsBillgBlockReason       on  $projection.UtilsBillgBlockReason = _UtilsBillgBlockReason.UtilsBillgBlockReason
  association [0..1] to I_UtilsBillgUnblockReason     as _UtilsBillgUnblockReason     on  $projection.UtilsBillgUnblockReason = _UtilsBillgUnblockReason.UtilsBillgUnblockReason
  association [0..1] to I_UtilitiesPortion            as _UtilitiesPortion            on  $projection.AlternativeUtilitiesPortion = _UtilitiesPortion.UtilitiesPortion
  association [1..1] to I_User                        as _CreatedByUser               on  $projection.UtilsContractCreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser           on  $projection.UtilsContractLastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_UtilitiesInstallation       as _UtilitiesInstallation       on  $projection.UtilitiesInstallation = _UtilitiesInstallation.UtilitiesInstallation
  association [0..1] to I_UtilsOutsrtgChkGrpBillg     as _UtilsOutsrtgChkGrpBillg     on  $projection.UtilsOutsrtgCheckGrpForBillg = _UtilsOutsrtgChkGrpBillg.UtilsOutsrtgCheckGrpForBillg
  association [1..1] to I_UtilsContrSpcfcBdgtBillgCyc as _UtilsContrSpcfcBdgtBillgCyc on  $projection.UtilsContrSpcfcBdgtBillgCycle = _UtilsContrSpcfcBdgtBillgCyc.UtilsContrSpcfcBdgtBillgCycle
  association [0..1] to I_UtilsAccountDetnCode        as _UtilsAccountDetnCode        on  $projection.UtilitiesAccountDetnCode = _UtilsAccountDetnCode.UtilitiesAccountDetnCode
                                                                                      and $projection.UtilitiesDivision        = _UtilsAccountDetnCode.Division
                                                                                      and $projection.CompanyCode              = _UtilsAccountDetnCode.CompanyCode
  association [0..1] to I_UtilsPlantOrCompanyCnsmpn   as _UtilsPlantOrCompanyCnsmpn   on  $projection.UtilsPlantOrCompanyConsumption = _UtilsPlantOrCompanyCnsmpn.UtilsPlantOrCompanyConsumption
  association [0..1] to I_InvcUtilsContractsJointly   as _InvcUtilsContractsJointly   on  $projection.UtilsContrJointInvcType = _InvcUtilsContractsJointly.UtilsContrJointInvcType
  association [0..1] to I_UtilsContrProcessingStatus  as _UtilsContrProcessingStatus  on  $projection.UtilsContractProcessingSts = _UtilsContrProcessingStatus.UtilsContractProcessingSts
  association [0..1] to I_UtilitiesServiceProvider    as _UtilitiesServiceProvider    on  $projection.UtilitiesServiceProvider = _UtilitiesServiceProvider.UtilitiesServiceProvider
  association [0..1] to I_UtilsBillgOutsortingGroup   as _UtilsBillgOutsortingGroup   on  $projection.UtilsBillgOutsortingReason = _UtilsBillgOutsortingGroup.UtilsBillgOutsortingReason
  association [0..1] to I_CADunningProcedure          as _CADunningProcedure          on  $projection.CADunningProcedure = _CADunningProcedure.CADunningProcedure
  association [1..*] to I_UtilitiesContractHistory    as _UtilitiesContractHistory    on  $projection.UtilitiesContract = _UtilitiesContractHistory.UtilitiesContract
  association [0..1] to I_UtilitiesPortion            as _LastUtilitiesPortion        on  $projection.LastUtilitiesPortion = _LastUtilitiesPortion.UtilitiesPortion
{
  key ever.vertrag                                                     as UtilitiesContract,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      ever.bukrs                                                       as CompanyCode,

      @ObjectModel.foreignKey.association: '_Division'
      ever.sparte                                                      as UtilitiesDivision,

      @ObjectModel.foreignKey.association:'_UtilitiesPortion'
      ever.portion                                                     as AlternativeUtilitiesPortion,

      cast(ever.manabr as e_contrisblldmnlly_vdm preserving type )     as UtilsContrIsBilledManually,

      @ObjectModel.foreignKey.association: '_UtilsBillgBlockReason'
      cast(ever.abrsperr as e_billgblockreason_vdm  preserving type )  as UtilsBillgBlockReason,

      @ObjectModel.foreignKey.association:'_UtilsBillgUnblockReason'
      cast(ever.abrfreig as e_billgunblockreason_vdm preserving type ) as UtilsBillgUnblockReason,

      @ObjectModel.foreignKey.association: '_UtilitiesInstallation'
      ever.anlage                                                      as UtilitiesInstallation,

      ever.vkonto                                                      as ContractAccount,

      cast(ever.einzdat as e_einzdat_vdm preserving type)              as UtilitiesMoveInDate,

      cast(ever.auszdat as e_ausdat_vdm preserving type)               as UtilitiesMoveOutDate,

      @Semantics.systemDate.createdAt: true
      ever.erdat                                                       as UtilsContractCreationDate,

      @Semantics.user.createdBy: true
      ever.ernam                                                       as UtilsContractCreatedByUser,

      @Semantics.systemDate.lastChangedAt: true
      ever.aedat                                                       as UtilsContractLastChangeDate,

      @Semantics.user.lastChangedBy: true
      ever.aenam                                                       as UtilsContractLastChangedByUser,

      @Semantics.booleanIndicator
      ever.billfinit                                                   as UtilsContrIsFinallyBilled,

      @ObjectModel.foreignKey.association: '_UtilsPlantOrCompanyCnsmpn'
      ever.eigenverbr                                                  as UtilsPlantOrCompanyConsumption,

      @ObjectModel.foreignKey.association: '_InvcUtilsContractsJointly'
      cast(ever.gemfakt as e_gemfakt_vdm preserving type)              as UtilsContrJointInvcType,

      ever.kuenddat                                                    as UtilitiesContractCanclnDate,

      ever.vbisdat                                                     as UtilitiesContractRenewalDate,

      @ObjectModel.foreignKey.association: '_CADunningProcedure'
      ever.mahnv                                                       as CADunningProcedure,

      @ObjectModel.foreignKey.association: '_UtilitiesServiceProvider'
      ever.serviceid                                                   as UtilitiesServiceProvider,

      @ObjectModel.foreignKey.association: '_UtilsContrProcessingStatus'
      cast(ever.bstatus as e_bearkz_vdm preserving type )              as UtilsContractProcessingSts,

      ever.begru                                                       as AuthorizationGroup,

      ever.loevm                                                       as DeletionIndicator,

      @ObjectModel.foreignKey.association: '_UtilsOutsrtgChkGrpBillg'
      ever.ausgrup                                                     as UtilsOutsrtgCheckGrpForBillg,

      ever.vbez                                                        as UtilitiesContractDescription,

      @ObjectModel.foreignKey.association: '_UtilsAccountDetnCode'
      cast(ever.kofiz as e_kofiz_vdm preserving type )                 as UtilitiesAccountDetnCode,

      @ObjectModel.foreignKey.association: '_UtilsContrSpcfcBdgtBillgCyc'
      cast(ever.abszyk as e_abszykv_vdm preserving type )              as UtilsContrSpcfcBdgtBillgCycle,

      @ObjectModel.foreignKey.association: '_UtilsBillgOutsortingGroup'
      cast(ever.manoutsort  as e_manoutsort_vdm preserving type)       as UtilsBillgOutsortingReason,

      @ObjectModel.foreignKey.association:'_LastUtilitiesPortion'
      ever.lastportion                                                 as LastUtilitiesPortion,

      /* Associations */
      _Division,
      _CompanyCode,
      _UtilsBillgBlockReason,
      _UtilsBillgUnblockReason,
      _CreatedByUser,
      _LastChangedByUser,
      _UtilitiesPortion,
      _UtilitiesInstallation,
      _UtilsOutsrtgChkGrpBillg,
      _UtilsContrSpcfcBdgtBillgCyc,
      _UtilsAccountDetnCode,
      _UtilsPlantOrCompanyCnsmpn,
      _InvcUtilsContractsJointly,
      _UtilsContrProcessingStatus,
      _UtilsBillgOutsortingGroup,
      _UtilitiesServiceProvider,
      _CADunningProcedure,
      _UtilitiesContractHistory,
      _LastUtilitiesPortion
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EVER"
],
"ASSOCIATED":
[
"I_CADUNNINGPROCEDURE",
"I_COMPANYCODE",
"I_DIVISION",
"I_INVCUTILSCONTRACTSJOINTLY",
"I_USER",
"I_UTILITIESCONTRACTHISTORY",
"I_UTILITIESINSTALLATION",
"I_UTILITIESPORTION",
"I_UTILITIESSERVICEPROVIDER",
"I_UTILSACCOUNTDETNCODE",
"I_UTILSBILLGBLOCKREASON",
"I_UTILSBILLGOUTSORTINGGROUP",
"I_UTILSBILLGUNBLOCKREASON",
"I_UTILSCONTRPROCESSINGSTATUS",
"I_UTILSCONTRSPCFCBDGTBILLGCYC",
"I_UTILSOUTSRTGCHKGRPBILLG",
"I_UTILSPLANTORCOMPANYCNSMPN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/