I_UtilitiesBillingDocument

@EndUserText.label: 'Billing Document'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEUTILSBILLGDOC'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'UtilitiesBillingDocument'
//Privileged associations specified

@AccessControl.privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
@Metadata.allowExtensions:true
//@AbapCatalog.preserveKey:true

@AbapCatalog.compiler.compareFilter:true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION


define view I_UtilitiesBillingDocument
  as select from erch
  //association [0..1] to Z_I_UtilsBusinessTransactionTT as _UtilsBusinessTransactionTT on $projection.UtilsBusTransactionType        = _UtilsBusinessTransactionTT.UtilsBusTransactionType

  association [1..1] to I_UtilitiesBillingReason     as _UtilitiesBillingReason     on  $projection.UtilitiesBillingReason = _UtilitiesBillingReason.UtilitiesBillingReason
  association [1..1] to I_UtilsBillgDocSimulationRsn as _UtilsBillgDocSimulationRsn on  $projection.UtilsBillgSimulationReason = _UtilsBillgDocSimulationRsn.UtilsBillgSimulationReason
  association [0..1] to I_ManualUtilsBillgDocCrtnRsn as _ManualUtilsBillgDocCrtnRsn on  $projection.ManualUtilsBillgDocCrtnRsn = _ManualUtilsBillgDocCrtnRsn.ManualUtilsBillgDocCrtnRsn
  association [1..1] to I_Division                   as _Division                   on  $projection.Division = _Division.Division
  association [1..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_UtilsBillingDocReversalRsn as _UtilsBillingDocReversalRsn on  $projection.UtilsBillgDocReversalRsn = _UtilsBillingDocReversalRsn.UtilsBillgDocReversalRsn
  association [0..1] to I_UtilitiesPortion           as _UtilitiesPortion           on  $projection.UtilitiesPortion = _UtilitiesPortion.UtilitiesPortion
  association [0..1] to I_MeterReadingUnit           as _MeterReadingUnit           on  $projection.MeterReadingUnit = _MeterReadingUnit.MeterReadingUnit
  association [1..1] to I_BusinessPartner            as _BusinessPartner            on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to I_UtilitiesContract          as _UtilitiesContract          on  $projection.UtilitiesContract = _UtilitiesContract.UtilitiesContract
  association [1..1] to I_User                       as _CreatedByUser              on  $projection.UtilsBillgDocCreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser          on  $projection.UtilsBillgDocLastChangedByUser = _LastChangedByUser.UserID
  association [0..*] to I_UtilsBillgDocOutsrtgData   as _UtilsBillgDocOutsrtgData   on  $projection.UtilitiesBillingDocument = _UtilsBillgDocOutsrtgData.UtilitiesBillingDocument
  association [0..*] to I_UtilsBillgDocDvceLineItem  as _UtilsBillgDocDvceLineItem  on  $projection.UtilitiesBillingDocument = _UtilsBillgDocDvceLineItem.UtilitiesBillingDocument
  association [1..1] to I_UtilsAccountClass          as _UtilsAccountClass          on  $projection.UtilitiesAccountClass = _UtilsAccountClass.UtilitiesAccountClass
  association [1..1] to I_ContractAccountHeader      as _ContractAccountHeader      on  $projection.ContractAccount = _ContractAccountHeader.ContractAccount
  association [1..1] to I_ContractAccountPartner     as _ContractAccountPartner     on  $projection.ContractAccount = _ContractAccountPartner.ContractAccount
                                                                                    and $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
  association [0..1] to I_UtilsAccountDetnCode       as _UtilsAccountDetnCode       on  $projection.UtilitiesAccountDetnCode = _UtilsAccountDetnCode.UtilitiesAccountDetnCode
                                                                                    and $projection.Division                 = _UtilsAccountDetnCode.Division
                                                                                    and $projection.CompanyCode              = _UtilsAccountDetnCode.CompanyCode
{
  key cast(erch.belnr as e_belnr_vdm preserving type)                  as UtilitiesBillingDocument,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      erch.bukrs                                                       as CompanyCode,
      erch.gpartner                                                    as BusinessPartner,
      //@ObjectModel.foreignKey.association: '_ContractAccount'

      erch.vkont                                                       as ContractAccount,
      @ObjectModel.foreignKey.association: '_UtilitiesContract'
      erch.vertrag                                                     as UtilitiesContract,
      //@ObjectModel.foreignKey.association: '_UtilsBusinessTransactionTT'

      erch.hvorg                                                       as UtilsBusTransactionType,

      @ObjectModel.foreignKey.association: '_UtilitiesBillingReason'
      cast(erch.abrvorg as e_abrvorg_vdm preserving type)              as UtilitiesBillingReason,

      @Semantics.businessDate.from: true
      cast(erch.begabrpe as e_begabrpe_vdm preserving type)            as UtilsBillgPeriodStartDate,

      @Semantics.businessDate.to: true
      cast(erch.endabrpe as e_endabrpe_vdm preserving type)            as UtilsBillgPeriodEndDate,

      @ObjectModel.foreignKey.association: '_Division'
      erch.sparte                                                      as Division,

      @ObjectModel.foreignKey.association: '_UtilsBillgDocSimulationRsn'
      cast (erch.simulation as e_simulation_vdm preserving type)       as UtilsBillgSimulationReason,
      @Semantics.booleanIndicator:true
      erch.tobreleasd                                                  as UtilsBillgDocIsNotReleased,

      erch.stornodat                                                   as UtilsBillgDocReversalDate,

      @ObjectModel.foreignKey.association: '_UtilsBillingDocReversalRsn'
      erch.bcreason                                                    as UtilsBillgDocReversalRsn,

      erch.zuorddaa                                                    as UtilsBillgPeriodAllocationDate,

      @ObjectModel.foreignKey.association: '_UtilitiesPortion'
      erch.portion                                                     as UtilitiesPortion,

      @Semantics.businessDate.at: true
      cast(erch.abrdats as e_schedld_billg_dte_vdm preserving type)    as ScheduledUtilitiesBillingDate,

      @ObjectModel.foreignKey.association: '_MeterReadingUnit'
      erch.ableinh                                                     as MeterReadingUnit,

      cast(erch.adatsoll as e_schedld_mtrrdng_dte_vdm preserving type) as ScheduledMeterReadingDate,

      @ObjectModel.foreignKey.association: '_ManualUtilsBillgDocCrtnRsn'
      erch.bergrund                                                    as ManualUtilsBillgDocCrtnRsn,
      @Semantics.booleanIndicator:true
      erch.manbillrel                                                  as MnlUtilsBillgDocIsReldForInvcg,

      erch.billingrunno                                                as UtilitiesBillingRun,

      @Semantics.systemDate.createdAt: true
      cast(erch.erdat as e_erch_erdat_vdm preserving type)             as UtilsBillgDocCreationDate,

      @Semantics.user.createdBy: true
      erch.ernam                                                       as UtilsBillgDocCreatedByUser,

      @Semantics.systemDate.lastChangedAt: true
      erch.aedat                                                       as UtilsBillgDocLastChangeDate,

      @Semantics.user.lastChangedBy: true
      erch.aenam                                                       as UtilsBillgDocLastChangedByUser,

      erch.begru                                                       as AuthorizationGroup,

      @ObjectModel.foreignKey.association: '_UtilsAccountClass'
      erch.ktoklasse                                                   as UtilitiesAccountClass,

      erch.belnralt                                                    as UtilsPreviousBillingDocument,

      erch.abwvk                                                       as AltvContractAcctForCollvBills,

      @ObjectModel.foreignKey.association: '_UtilsAccountDetnCode'
      erch.kofiz                                                       as UtilitiesAccountDetnCode,

      erch.ptermtdat                                                   as UtilsPortionScheduleRecordDate,
      @Semantics.booleanIndicator:true
      erch.ercho_v                                                     as UtilsBillgDocHasOutsrtgData,

      erch.billing_period                                              as UtilsBillingPeriodValue,


      /* Associations */
      //_UtilsBusinessTransactionTT

      //_ContractAccount

      _UtilitiesBillingReason,
      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _UtilsBillgDocSimulationRsn,
      _ManualUtilsBillgDocCrtnRsn,
      _Division,
      _CompanyCode,
      _UtilsBillingDocReversalRsn,
      _UtilitiesPortion,
      _MeterReadingUnit,
      _BusinessPartner,
      _UtilitiesContract,
      _CreatedByUser,
      _LastChangedByUser,
      _UtilsBillgDocOutsrtgData,
      _UtilsBillgDocDvceLineItem,
      _UtilsAccountClass,
      _ContractAccountHeader,
      _ContractAccountPartner,
      _UtilsAccountDetnCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ERCH"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_DIVISION",
"I_MANUALUTILSBILLGDOCCRTNRSN",
"I_METERREADINGUNIT",
"I_USER",
"I_UTILITIESBILLINGREASON",
"I_UTILITIESCONTRACT",
"I_UTILITIESPORTION",
"I_UTILSACCOUNTCLASS",
"I_UTILSACCOUNTDETNCODE",
"I_UTILSBILLGDOCDVCELINEITEM",
"I_UTILSBILLGDOCOUTSRTGDATA",
"I_UTILSBILLGDOCSIMULATIONRSN",
"I_UTILSBILLINGDOCREVERSALRSN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/