@EndUserText: {label: 'Transportation Order Execution Enriched'}
@Analytics: {dataCategory: #DIMENSION,
internalName: #LOCAL}
@ObjectModel: {representativeKey: 'TransportationOrderEventUUID',
usageType: {serviceQuality: #C,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL}}
@VDM: {viewType: #COMPOSITE}
@AbapCatalog: {compiler: {compareFilter: true},
sqlViewName: 'ITOREXECUTIONE'}
@AccessControl: {authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA')}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
define view I_TranspOrdExecutionEnrcd
as select from I_TranspOrdExecution
/* Business Object related Node Associations*/
association [1..1] to I_TransportationOrderEnrcd as _TransportationOrderEnrcd on $projection.TransportationOrderUUID = _TransportationOrderEnrcd.TransportationOrderUUID
association [0..1] to I_TransportationOrderItemEnrcd as _TransportationOrderItemEnrcd on $projection.TransportationOrderItemUUID = _TransportationOrderItemEnrcd.TransportationOrderItemUUID
association [0..1] to I_TransportationOrderStopEnrcd as _TransportationOrderStopEnrcd on $projection.TransportationOrderStopUUID = _TransportationOrderStopEnrcd.TransportationOrderStopUUID
/* Foreign Key and Text Associations */
association [0..1] to I_CalendarDate as _TranspOrdEvtActualDate on $projection.TranspOrdEvtActualDate = _TranspOrdEvtActualDate.CalendarDate
association [0..1] to I_CalendarDate as _TranspOrdEvtExpdEndDate on $projection.TranspOrdEvtExpdEndDate = _TranspOrdEvtExpdEndDate.CalendarDate
association [0..1] to I_LocationBasic as _Location on $projection.LocationUUID = _Location.LocationUUID
{
key TransportationOrderEventUUID,
@ObjectModel.foreignKey.association: '_TransportationOrderEnrcd'
TransportationOrderUUID,
TranspOrdExecution,
@ObjectModel.foreignKey.association: '_TransportationOrderStopEnrcd'
TransportationOrderStopUUID,
@ObjectModel.foreignKey.association: '_TransportationOrderItemEnrcd'
TransportationOrderItemUUID,
/* Admin */
@Semantics.user.createdBy: true
CreatedByUser,
CreationDateTime,
@Semantics.user.lastChangedBy: true
LastChangedByUser,
ChangedDateTime,
/* Event */
@ObjectModel.foreignKey.association: '_TranspOrdEventCode'
TranspOrdEventCode,
@ObjectModel.foreignKey.association: '_TranspOrdEventStatus'
TranspOrdEventStatus,
@ObjectModel.foreignKey.association: '_TransportationActivity'
TransportationActivity,
@ObjectModel.foreignKey.association: '_TranspOrdEventIsRecalled'
TranspOrdEventIsRecalled,
TranspOrdEventReasonCode,
@Semantics.text: true
TranspOrdEventReasonDesc,
/* Duration and Dates */
TranspOrdEvtActualDateTime,
TranspOrdEvtActualDateTimeZone,
TranspOrdEvtExpdEndDateTime,
TranspOrdEvtEstimatedDateTime,
@ObjectModel.foreignKey.association: '_TranspOrdEvtActualDate'
cast(cast(substring(cast(TranspOrdEvtActualDateTime as abap.char(17)), 1, 8) as abap.dats) as /scmtms/vdm_actual_date preserving type) as TranspOrdEvtActualDate,
@ObjectModel.foreignKey.association: '_TranspOrdEvtExpdEndDate'
cast(cast(substring(cast(TranspOrdEvtExpdEndDateTime as abap.char(17)), 1, 8) as abap.dats) as /scmtms/vdm_expd_end_date preserving type) as TranspOrdEvtExpdEndDate,
_TransportationOrderStopEnrcd.TranspOrdStopPlanTranspDteTme as TranspOrdStopPlanTranspDteTme,
/* Location */
LocationUUID,
// LocationAdditionalUUID,
@Semantics.geoLocation.latitude: true
cast( cast( GeographicalLocationLatitude as abap.char(17)) as /scmtms/vdm_geolat preserving type) as GeographicalLocationLatitude,
@Semantics.geoLocation.longitude: true
cast( cast( GeographicalLocationLongitude as abap.char(17)) as /scmtms/vdm_geolon preserving type) as GeographicalLocationLongitude,
cast( cast( GeographicalLocationAltitude as abap.char(12)) as /scmtms/vdm_geoalt preserving type) as GeographicalLocationAltitude,
/* Discrepancy */
@ObjectModel.foreignKey.association: '_TranspOrdHasQtyDiscrepancy'
TranspOrdHasQtyDiscrepancy,
@ObjectModel.foreignKey.association: '_TranspOrdIsDiscrepant'
TranspOrdIsDiscrepant,
@ObjectModel.foreignKey.association: '_DiscrepancyType'
DiscrepancyType,
@ObjectModel.foreignKey.association: '_TranspOrdIsDscrptWthoutBlk'
TranspOrdIsDscrptWthoutBlk,
TranspOrdIsDiscrepantWithinTol,
/* Quantities (for Discrepacy only) */
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecGrossWeightUnit'
@DefaultAggregation: #SUM
TranspOrdExecGrossWeight,
@ObjectModel.foreignKey.association: '_TranspOrdExecGrossWeightUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecGrossWeightUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecGrossVolumeUnit'
@DefaultAggregation: #SUM
TranspOrdExecGrossVolume,
@ObjectModel.foreignKey.association: '_TranspOrdExecGrossVolumeUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecGrossVolumeUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecNetWeightUnit'
@DefaultAggregation: #SUM
TranspOrdExecNetWeight,
@ObjectModel.foreignKey.association: '_TranspOrdExecNetWeightUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecNetWeightUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecQuantityUnit'
@DefaultAggregation: #SUM
TranspOrdExecQuantity,
@ObjectModel.foreignKey.association: '_TranspOrdExecQuantityUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecAltvQtyUnit'
@DefaultAggregation: #SUM
TranspOrdExecAltvQty,
@ObjectModel.foreignKey.association: '_TranspOrdExecAltvQtyUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecAltvQtyUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecBaseQtyUnit'
@DefaultAggregation: #SUM
TranspOrdExecBaseQty,
@ObjectModel.foreignKey.association: '_TranspOrdExecBaseQtyUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecBaseQtyUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecTareWeightUnit'
@DefaultAggregation: #SUM
TranspOrdExecTareWeight,
@ObjectModel.foreignKey.association: '_TranspOrdExecTareWeightUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecTareWeightUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecNumberOfCtnsUnit'
@DefaultAggregation: #SUM
TranspOrdExecNumberOfCtns,
@ObjectModel.foreignKey.association: '_TranspOrdExecNumberOfCtnsUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecNumberOfCtnsUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecDngrsGdsExmppUnit'
@DefaultAggregation: #SUM
TranspOrdExecDngrsGdsExmpp,
@ObjectModel.foreignKey.association: '_TranspOrdExecDngrsGdsExmppUoM'
@Semantics.unitOfMeasure: true
TranspOrdExecDngrsGdsExmppUnit,
ShippersLoadAndCountQuantity,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecLengthUnit'
@DefaultAggregation: #MIN
TranspOrdExecLength,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecLengthUnit'
@DefaultAggregation: #MIN
TranspOrdExecWidth,
@Semantics.quantity.unitOfMeasure: 'TranspOrdExecLengthUnit'
@DefaultAggregation: #MIN
TranspOrdExecHeight,
@ObjectModel.foreignKey.association: '_TranspOrdExecLengthUnit'
@Semantics.unitOfMeasure: true
TranspOrdExecLengthUnit,
/* Associations */
_TransportationOrderEnrcd,
_TransportationOrderStopEnrcd,
_TransportationOrderItemEnrcd,
_CreatedByUser,
_DiscrepancyType,
_LastChangedByUser,
_Location,
_TranspOrdEventCode,
_TranspOrdEventIsRecalled,
_TranspOrdEventStatus,
_TranspOrdExecAltvQtyUnit,
_TranspOrdExecBaseQtyUnit,
_TranspOrdExecDngrsGdsExmppUoM,
_TranspOrdExecGrossVolumeUnit,
_TranspOrdExecGrossWeightUnit,
_TranspOrdExecLengthUnit,
_TranspOrdExecNetWeightUnit,
_TranspOrdExecNumberOfCtnsUnit,
_TranspOrdExecQuantityUnit,
_TranspOrdExecTareWeightUnit,
_TranspOrdHasQtyDiscrepancy,
_TranspOrdIsDiscrepant,
_TranspOrdIsDscrptWthoutBlk,
_TransportationActivity,
_TransportationOrder,
_TransportationOrderItem,
_TransportationOrderStop,
_TranspOrdEvtActualDate,
_TranspOrdEvtExpdEndDate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TRANSPORDEXECUTION",
"I_TRANSPORTATIONORDERSTOPENRCD"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_DISCREPANCYTYPE",
"I_LOCATIONBASIC",
"I_TRANSPORDEVENTCODE",
"I_TRANSPORDEVENTISRECALLED",
"I_TRANSPORDEVENTSTATUS",
"I_TRANSPORDHASQTYDISCREPANCY",
"I_TRANSPORDISDISCREPANT",
"I_TRANSPORDISDSCRPTWTHOUTBLK",
"I_TRANSPORTATIONACTIVITY",
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERENRCD",
"I_TRANSPORTATIONORDERITEM",
"I_TRANSPORTATIONORDERITEMENRCD",
"I_TRANSPORTATIONORDERSTOP",
"I_TRANSPORTATIONORDERSTOPENRCD",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[
"I_TRANSPORDEXECUTION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/