I_SupplierEvalResponse

@EndUserText.label: 'Supplier Evaluation Response'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ISUPLREVALRESP'
@ObjectModel.semanticKey:  [ 'SupplierEvalResponse' ]
@ObjectModel.representativeKey: 'SuplrEvalRspUUID'
@ObjectModel.compositionRoot: true 
define view I_SupplierEvalResponse as select from /srmsmc/d_srs_rt
  association [0..1] to I_PurchasingCategory as _PurchasingCategory on $projection.PurgCatUUID = _PurchasingCategory.PurgCatUUID
  association [0..1] to I_SupplierEvalRspAppraiser as _Appraiser  on $projection.SuplrEvalRspUUID = _Appraiser.SuplrEvalRspUUID
  association [0..1] to I_SupplierEvalRspPurchaserResp as _PurchaserResponsible  on $projection.SuplrEvalRspUUID = _PurchaserResponsible.SuplrEvalRspUUID 
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language   
  association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..*] to I_SupplierEvalResponseLanguage as _SupplierEvalResponseLanguage on _SupplierEvalResponseLanguage.SuplrEvalRspUUID = $projection.SuplrEvalRspUUID
  association [0..*] to I_SupplierEvalResponseQnaire as _SupplierEvalResponseQnaire on _SupplierEvalResponseQnaire.SuplrEvalRspUUID = $projection.SuplrEvalRspUUID
  association [0..*] to I_SupplierEvalResponseExtName as _SupplierEvalResponseExtName 
        on $projection.SuplrEvalRspUUID = _SupplierEvalResponseExtName.SuplrEvalRspUUID 
  association [0..1] to I_SupplierEvalRespSuplrParty as _Supplier  on $projection.SuplrEvalRspUUID = _Supplier.SuplrEvalRspUUID
  association [0..1] to I_SuplrEvalRspLifecycleStsCM as _SuplrEvalRspLifecycleStsCM  on $projection.SuplrEvalRspLifecycleStatus = _SuplrEvalRspLifecycleStsCM.SuplrEvalRspLifecycleStatus
  association [0..1] to I_SuplrEvalRspLifecycleStsApp as _SuplrEvalRspLifecycleStsApp on $projection.SuplrEvalRspLifecycleStatus = _SuplrEvalRspLifecycleStsApp.SuplrEvalRspLifecycleStatus
  
{

   //keys

   key cast(db_key as /srmsmc/srs_uuid preserving type) as SuplrEvalRspUUID, 

   cast(node_cat_key as /srmsmc/category preserving type) as SupplierEvalResponseCatType,
   
   @ObjectModel.text.element: 'SuplrEvalRspName'
   cast(id as /srmsmc/evaluation_response_id preserving type) as SupplierEvalResponse, 

   //Content

   @Semantics.text: true
   cast(name as /srmsmc/srs_name preserving type) as SuplrEvalRspName,  

   @Semantics.businessDate.from: true
   cast(eval_start_date as /srmsmc/start_date preserving type) as SuplrEvalStartDate, 
   
   @Semantics.businessDate.to: true
   cast(eval_end_date as /srmsmc/end_date preserving type) as SuplrEvalEndDate, 
   
   cast(submission_date as /srmsmc/submission_date_ts preserving type) as SuplrEvalSubmissionDateTime, 
   
   cast(crea_date_time as /srmsmc/created_on_ts preserving type) as CreationDateTime,
   
   cast(deadline as /srmsmc/deadline preserving type) as SuplrEvalDeadlineDate,
       
   cast(puc_key as /srmsmc/puc_uuid preserving type) as PurgCatUUID,
 
   cast( crea_uname as vdm_createdbyuserid) as CreatedByUser,
    
   cast( lchg_date_time as /srmsmc/last_changed_on_ts preserving type) as  LastChangeDateTime,
    
   cast( lchg_uname as vdm_lastchangedbyuserid) as LastChangedByUser,

   @Semantics.language: true
   @ObjectModel.foreignKey.association: '_Language'
   cast(language_code as /srmsmc/language preserving type)  as Language,
   
   //Status

   @ObjectModel.foreignKey.association: '_SuplrEvalRspLifecycleStsCM'
   cast( lifecycle_stcd as /srmsmc/status preserving type) as SuplrEvalRspLifecycleStatus, 
   //token,

   
   //Associations

   _SuplrEvalRspLifecycleStsCM,
   _SuplrEvalRspLifecycleStsApp,
   _CreatedByUser,
   _LastChangedByUser,
   _Supplier,
   _Appraiser,
   _PurchaserResponsible,
//   _ContactCard,

   _SupplierEvalResponseLanguage,
   _Language,
   _PurchasingCategory,
   
   @ObjectModel.association.type:  #TO_COMPOSITION_CHILD   
   _SupplierEvalResponseQnaire,
   
   _SupplierEvalResponseExtName
}  
                                                                                        
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SRMSMC/D_SRS_RT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PURCHASINGCATEGORY",
"I_SUPLREVALRSPLIFECYCLESTSAPP",
"I_SUPLREVALRSPLIFECYCLESTSCM",
"I_SUPPLIEREVALRESPONSEEXTNAME",
"I_SUPPLIEREVALRESPONSELANGUAGE",
"I_SUPPLIEREVALRESPONSEQNAIRE",
"I_SUPPLIEREVALRESPSUPLRPARTY",
"I_SUPPLIEREVALRSPAPPRAISER",
"I_SUPPLIEREVALRSPPURCHASERRESP",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/