I_SupplierEvalRespSuplrParty

@EndUserText.label: 'Supplier Evaluation Response Supplier Party'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'ISUPEVALRSSUPPTY'
define view I_SupplierEvalRespSuplrParty
  as select from    I_SupplierEvalResponseParty as party
    inner join I_BusinessPartner             on I_BusinessPartner.BusinessPartner = party.SLCParty
                                            and party.SLCPartyType                  = 'S'
    inner join I_Supplier_to_BusinessPartner on I_Supplier_to_BusinessPartner.BusinessPartnerUUID = I_BusinessPartner.BusinessPartnerUUID
    inner join I_Supplier                    on I_Supplier.Supplier = I_Supplier_to_BusinessPartner.Supplier
  association [0..1] to I_Supplier                    as _Supplier                    on _Supplier.Supplier = $projection.Supplier
  association [0..1] to I_BusinessPartner             as _BusinessPartner             on _BusinessPartner.BusinessPartner = $projection.BusinessPartner
  association [1..1] to I_SupplierEvalResponse        as _SupplierEvalResponse        on $projection.SuplrEvalRspUUID = _SupplierEvalResponse.SuplrEvalRspUUID
  association [0..1] to I_SupplierEvalRspPartyAddress as _SupplierEvalRspPartyAddress on $projection.SuplrEvalRspPartyUUID = _SupplierEvalRspPartyAddress.SuplrEvalRspPartyUUID
{
      @UI.hidden: true
  key SuplrEvalRspPartyUUID,

      @UI.hidden: true
      SuplrEvalRspUUID,

      @UI.hidden: true
      @Consumption.hidden: true
      I_BusinessPartner.BusinessPartnerUUID,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      cast ( substring(SLCParty,1,10 ) as bu_partner preserving type)                     as BusinessPartner,

      @ObjectModel.foreignKey.association: '_Supplier'
      cast(I_Supplier_to_BusinessPartner.Supplier as /srmsmc/supplier_id preserving type) as Supplier,

      @UI.hidden:true
      @Consumption.hidden:true
      I_Supplier.AuthorizationGroup,
      
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController1,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController2,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController3,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController4,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController5,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController6,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController7,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController8,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController9,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataController10,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Supplier.DataControllerSet,

      EmailAddress,

      // Associations

      _Supplier,
      _BusinessPartner,
      _SupplierEvalResponse,
      _SupplierEvalRspPartyAddress

}
where
      SLCPartyType = 'S'
  and SLCPartyRole = '2'
  and I_Supplier.AuthorizationGroup is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_SUPPLIER",
"I_SUPPLIEREVALRESPONSEPARTY",
"I_SUPPLIER_TO_BUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_SUPPLIER",
"I_SUPPLIEREVALRESPONSE",
"I_SUPPLIEREVALRSPPARTYADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/