I_SupplierActivitySuplrParty

@EndUserText.label: 'Supplier Activity Supplier Party'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'ISUPACTSUPPTY'
define view I_SupplierActivitySuplrParty
  as select from    I_SupplierActivityParty as party
    left outer join I_BusinessPartner             on I_BusinessPartner.BusinessPartner = party.SLCParty
                                                  and party.SLCPartyType = 'S'
    left outer join I_Supplier_to_BusinessPartner on I_Supplier_to_BusinessPartner.BusinessPartnerUUID = I_BusinessPartner.BusinessPartnerUUID
    left outer join I_Supplier                    on I_Supplier.Supplier = I_Supplier_to_BusinessPartner.Supplier

  association [1..1] to I_SupplierActivity as _SupplierActivity on $projection.SuplrActyUUID = _SupplierActivity.SuplrActyUUID
  association [0..1] to I_Supplier                   as _Supplier                   on _Supplier.Supplier = $projection.Supplier
  association [0..1] to I_BusinessPartner            as _BusinessPartner            on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..*] to I_SupplierSustainabilityData as _SupplierSustainabilityData on $projection.BusinessPartner = _SupplierSustainabilityData.BusinessPartner
  association [0..1] to I_SupplierControlData        as _SupplierControlData        on $projection.BusinessPartner = _SupplierControlData.BusinessPartner
{
    key SuplrActyPartyUUID,
      
      SuplrActyUUID,
    
      I_BusinessPartner.BusinessPartnerUUID                               as BusinessPartnerUUID,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      cast(substring( SLCParty,1,10) as bu_partner preserving type)                      as BusinessPartner,

      @ObjectModel.foreignKey.association: '_Supplier'
      cast(I_Supplier_to_BusinessPartner.Supplier as /srmsmc/supplier_id preserving type) as Supplier,

      @UI.hidden:true
      @Consumption.hidden:true
      I_Supplier.AuthorizationGroup,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController1,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController2,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController3,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController4,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController5,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController6,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController7,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController8,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController9,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataController10,
      @Consumption.hidden: true
      @UI.hidden: true
      I_Supplier.DataControllerSet,

      // Associations

      _Supplier,
      _BusinessPartner,
      _SupplierActivity,
      _SupplierSustainabilityData,
      _SupplierControlData

}
where
      SLCPartyType = 'S'
  and SLCPartyRole = '2'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_SUPPLIER",
"I_SUPPLIERACTIVITYPARTY",
"I_SUPPLIER_TO_BUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_SUPPLIER",
"I_SUPPLIERACTIVITY",
"I_SUPPLIERCONTROLDATA",
"I_SUPPLIERSUSTAINABILITYDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/