I_SupplierControlData

@AbapCatalog.sqlViewName: 'ISUPPLIERCONTROL'
@EndUserText.label: 'Supplier Control and Information Data'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK

define view I_SupplierControlData
  as select from    /srmsmc/d_s_ctrl as SupplierControlData

  association [1..1] to I_BusinessPartner            as _BusinessPartner            on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [0..1] to I_SupplierQualificationLvl   as _SupplierQualificationLvl   on $projection.SupplierQualificationLevel = _SupplierQualificationLvl.SupplierQualificationLevel
  association [1..1] to I_Indicator                  as _IsPreferredSupplier        on $projection.IsPreferredSupplier = _IsPreferredSupplier.IndicatorValue
  association [1..1] to I_Indicator                  as _IsStrategicPartner         on $projection.IsStrategicPartner = _IsStrategicPartner.IndicatorValue
  association [1..1] to I_SLCMgmtStrategicImportance as _SLCMgmtStrategicImportance on $projection.SLCSupplierStrategicImportance = _SLCMgmtStrategicImportance.SLCSupplierStrategicImportance
  association [1..1] to I_SLCMgmtABCClassification   as _SLCMgmtABCClassification   on $projection.SupplierABCClassificationCode = _SLCMgmtABCClassification.SupplierABCClassificationCode

{
       @ObjectModel.foreignKey.association: '_BusinessPartner'
  key  SupplierControlData.partner            as BusinessPartner,

       @Consumption.hidden: true
       @UI.hidden: true
       _BusinessPartner.AuthorizationGroup,
       
       @Consumption.hidden: true
       @UI.hidden: true
       _BusinessPartner.IsBusinessPurposeCompleted,

       @ObjectModel.foreignKey.association: '_IsPreferredSupplier'
       preferred_suppl                       as IsPreferredSupplier,

       @ObjectModel.foreignKey.association: '_IsStrategicPartner'
       strat_partner                         as IsStrategicPartner,

       @ObjectModel.foreignKey.association: '_SupplierQualificationLvl'
       cust_qual_level                       as SupplierQualificationLevel,

       @ObjectModel.foreignKey.association: '_SLCMgmtABCClassification'
       abc_class                             as SupplierABCClassificationCode,

       @ObjectModel.foreignKey.association: '_SLCMgmtStrategicImportance'
       strat_importance                      as SLCSupplierStrategicImportance,


       _IsPreferredSupplier,
       _IsStrategicPartner,
       _SupplierQualificationLvl,
       _BusinessPartner,
       _SLCMgmtStrategicImportance,
       _SLCMgmtABCClassification

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"/SRMSMC/D_S_CTRL"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_INDICATOR",
"I_SLCMGMTABCCLASSIFICATION",
"I_SLCMGMTSTRATEGICIMPORTANCE",
"I_SUPPLIERQUALIFICATIONLVL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/