I_SuplrInvoiceAdditionalData

@EndUserText.label: 'Supplier Invoice Additional Data'
@VDM.viewType : #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API 
@AbapCatalog.sqlViewName: 'ISIADDITIONLDATA'
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking:#REQUIRED 
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true

define view I_SuplrInvoiceAdditionalData
  as select from    rbkp
   
  association [1..1] to I_SupplierInvoice as _SupplierInvoice on  $projection.SupplierInvoice = _SupplierInvoice.SupplierInvoice
                                                              and $projection.FiscalYear      = _SupplierInvoice.FiscalYear                                                   
  association [1..1] to I_Bank_2          as _Bank            on  $projection.BankCountry     = _Bank.BankCountry
                                                              and $projection.Bank            = _Bank.BankInternalID    
  association [1..1] to I_CompanyCode     as _CompanyCode     on  $projection.CompanyCode     = _CompanyCode.CompanyCode                                                                                                         
    
{ 

  key rbkp.belnr                                        as SupplierInvoice, 
  key rbkp.gjahr                                        as FiscalYear, 
      rbkp.name1                                        as InvoicingPartyName1,
      rbkp.name2                                        as InvoicingPartyName2,
      rbkp.name3                                        as InvoicingPartyName3,
      rbkp.name4                                        as InvoicingPartyName4,
      rbkp.pstlz                                        as PostalCode,
      rbkp.ort01                                        as CityName,
      rbkp.land1                                        as Country,
      rbkp.stras                                        as StreetAddressName,
      rbkp.pfach                                        as POBox,
      rbkp.pstl2                                        as POBoxPostalCode,
      rbkp.pskto                                        as PostOfficeBankAccount,
      rbkp.bankn                                        as BankAccount,      
      rbkp.bankl                                        as Bank,   
      rbkp.banks                                        as BankCountry,
      rbkp.stcd1                                        as TaxID1,
      rbkp.stcd2                                        as TaxID2,
      rbkp.stcd3                                        as TaxID3,
      rbkp.stcd4                                        as TaxID4,
      rbkp.stcd5                                        as TaxID5,
      rbkp.stkzu                                        as OneTmeAccountIsVATLiable,
      cast (rbkp.stkza as xfeld preserving type)        as OneTmeAcctIsEqualizationTxSubj,
      rbkp.regio                                        as Region,
      rbkp.bkont                                        as BankControlKey,
      rbkp.dtaws                                        as DataExchangeInstructionKey,
      rbkp.dtams                                        as DataMediumExchangeIndicator,
      cast (rbkp.spras as spras)                        as LanguageCode,
      rbkp.xcpdk                                        as IsOneTimeAccount,
      rbkp.empfg                                        as PaymentRecipient,
      rbkp.fityp                                        as AccountTaxType,
      rbkp.stcdt                                        as TaxNumberType,
      cast (rbkp.stkzn as xfeld preserving type)        as IsNaturalPerson,
      rbkp.bkref                                        as BankDetailReference,
      rbkp.j_1kfrepre                                   as RepresentativeName,
      rbkp.j_1kftbus                                    as BusinessType,
      rbkp.j_1kftind                                    as IndustryType,
      rbkp.anred                                        as FormOfAddressName,
      rbkp.stceg                                        as VATRegistration,
      rbkp.glo_re1_ot                                   as OneTimeAcctCntrySpecificRef1,
      rbkp.pyiban                                       as IBAN,   
      _Bank.SWIFTCode                                   as SWIFTCode,
      rbkp.intad                                        as OneTimeBusinessPartnerEmail, 
      
      @ObjectModel.foreignKey.association: '_CompanyCode'
      _SupplierInvoice.CompanyCode                      as CompanyCode, 
      _SupplierInvoice.IsEndOfPurposeBlocked            as IsEndOfPurposeBlocked,  
                                         
      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _SupplierInvoice,
      _Bank,
      _CompanyCode
} 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK_2",
"I_SUPPLIERINVOICE",
"RBKP"
],
"ASSOCIATED":
[
"I_BANK_2",
"I_COMPANYCODE",
"I_SUPPLIERINVOICE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/