I_ServiceCostRate

@AbapCatalog.sqlViewName: 'IFISRVCOSTRATE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Interface View for Service Cost Rate'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #B,
        dataClass: #TRANSACTIONAL
    },
    supportedCapabilities: [
        #SQL_DATA_SOURCE,
        #CDS_MODELING_DATA_SOURCE,
        #CDS_MODELING_ASSOCIATION_TARGET,
        #EXTRACTION_DATA_SOURCE
    ]
}
@VDM.viewType: #BASIC

@Analytics:{
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        automatic: true
        }
    }
}

@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_ServiceCostRate_2'

define view I_ServiceCostRate
  as select from P_AccountingCostRate as _Rate
  // inner join   I_Ledger             as _Ledger on  _Rate.Ledger            = _Ledger.Ledger

  //                                             and _Ledger.IsLeadingLedger = 'X'

  association [0..1] to I_CompanyCode             as _CompanyCode             on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_CompanyCode             as _ReceivingCompanyCode    on  $projection.ReceivingCompanyCode = _ReceivingCompanyCode.CompanyCode
  association [0..1] to I_Currency                as _Currency                on  $projection.Currency = _Currency.Currency
  association [0..*] to I_CostCenter              as _CostCenter              on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                              and $projection.CostCenter      = _CostCenter.CostCenter
  association [0..1] to I_CostCenter              as _CurrentCostCenter       on  $projection.ControllingArea          = _CurrentCostCenter.ControllingArea
                                                                              and $projection.CostCenter               = _CurrentCostCenter.CostCenter
                                                                              and _CurrentCostCenter.ValidityStartDate <= $session.system_date
                                                                              and _CurrentCostCenter.ValidityEndDate   >= $session.system_date
  association [0..*] to I_CostCenterActivityType  as _CostCtrActivityType     on  $projection.ControllingArea = _CostCtrActivityType.ControllingArea
                                                                              and $projection.ActivityType    = _CostCtrActivityType.CostCtrActivityType
  association [0..1] to I_CostCenterActivityType  as _CurrentCostCtrActyType  on  $projection.ControllingArea               = _CurrentCostCtrActyType.ControllingArea
                                                                              and $projection.ActivityType                  = _CurrentCostCtrActyType.CostCtrActivityType
                                                                              and _CurrentCostCtrActyType.ValidityStartDate <= $session.system_date
                                                                              and _CurrentCostCtrActyType.ValidityEndDate   >= $session.system_date
  association [0..1] to I_WorkItem                as _WorkItem                on  $projection.WorkItem = _WorkItem.WorkItem
  association [0..*] to I_ServiceCostLevel        as _ServiceCostLevel        on  $projection.ServiceCostLevel = _ServiceCostLevel.ServiceCostLevel
  association [0..1] to I_ServiceCostLevel        as _CurrentServiceCostLevel on  $projection.ServiceCostLevel               = _CurrentServiceCostLevel.ServiceCostLevel
                                                                              and _CurrentServiceCostLevel.ValidityStartDate <= $session.system_date
                                                                              and _CurrentServiceCostLevel.ValidityEndDate   >= $session.system_date
  association [0..1] to I_Employment              as _Employment              on  $projection.PersonnelNumber = _Employment.EmploymentInternalID
                                                                              and _Employment.StartDate       <= $session.system_date
                                                                              and _Employment.EndDate         >= $session.system_date
  association [1]    to I_PersonWorkAgreement_1   as _PersonWorkAgreement     on  $projection.PersonnelNumber = _PersonWorkAgreement.PersonWorkAgreement                                                                            
  association [0..1] to I_WBSElement              as _WBSElement              on  $projection.WBSElementExternalID = _WBSElement.WBSElement
  association [0..1] to I_WBSElementByInternalKey as _WBSElementInternalID    on  $projection.WBSElementInternalID = _WBSElementInternalID.WBSElementInternalID
  association [0..1] to I_UnitOfMeasure           as _UnitOfMeasure           on  $projection.CostCtrActivityTypeQtyUnit = _UnitOfMeasure.UnitOfMeasure
  association [1..1] to E_AccountingCostRate      as _Extension               on  $projection.AccountingCostRateUUID = _Extension.AccountingCostRateUUID
{

  key AccountingCostRateUUID,

      _Rate.Ledger,
      CurrencyRole,
      CompanyCode,
      ControllingArea,

      CostCenter,
      ActivityType,
      IsIntercompanyRate,
      ReceivingCompanyCode,
      ServiceCostLevel,
      PersonnelNumber,
      
//      @API.element.releaseState: #DEPRECATED

//      @API.element.successor: 'WBSElementInternalID_2'

      WBSElementInternalID,
//      WBSElementInternalID_2,

//      @API.element.releaseState: #DEPRECATED

//      @API.element.successor: 'WBSElementExternalID_2'

      WBSElementExternalID,
//      WBSElementExternalID_2,


      WorkItem,
      TimeSheetOvertimeCategory,
      @Semantics.fiscal.year: true
      ValidityStartFiscalYear,
      @Semantics.fiscal.period: true
      ValidityStartFiscalPeriod,
      @Semantics.fiscal.yearPeriod: true
      cast((concat( ValidityStartFiscalYear, ValidityStartFiscalPeriod )) as fins_fyearperiod) as ValidityStartFiscalYearPeriod,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @Semantics.fiscal.year: true
      ValidityEndFiscalYear,
      @Semantics.fiscal.period: true
      ValidityEndFiscalPeriod,
      @Semantics.fiscal.yearPeriod: true
      cast((concat( ValidityEndFiscalYear, ValidityEndFiscalPeriod )) as fins_fyearperiod)     as ValidityEndFiscalYearPeriod,
      @Semantics.businessDate.to: true
      ValidityEndDate,

      @Semantics.unitOfMeasure:true
      CostCtrActivityTypeQtyUnit,
      @Semantics.currencyCode: true
      Currency,

      @Semantics.amount.currencyCode: 'Currency'
      cast(CostRateTotalAmount - CostRateFixedAmount as fco_rate_varbl_amount)                 as CostRateVarblAmount,
      CostRateScaleFactor,

      _CompanyCode,
      _ReceivingCompanyCode,
      _CostCenter,
      _CurrentCostCenter,
      _CostCtrActivityType,
      _CurrentCostCtrActyType,
      _ServiceCostLevel,
      _CurrentServiceCostLevel,
      _Employment,
      _PersonWorkAgreement,
      _WorkItem,
      _WBSElement,
      _WBSElementInternalID,
      _Currency,
      _UnitOfMeasure
}
where
      CostRateIsDeleted       = ''
  and BusinessTransactionType = 'MSCR'
  and PlanningCategory        = 'PLN'
  and CurrencyRole            = '00'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_ACCOUNTINGCOSTRATE"
],
"ASSOCIATED":
[
"E_ACCOUNTINGCOSTRATE",
"I_COMPANYCODE",
"I_COSTCENTER",
"I_COSTCENTERACTIVITYTYPE",
"I_CURRENCY",
"I_EMPLOYMENT",
"I_PERSONWORKAGREEMENT_1",
"I_SERVICECOSTLEVEL",
"I_UNITOFMEASURE",
"I_WBSELEMENT",
"I_WBSELEMENTBYINTERNALKEY",
"I_WORKITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/