I_CostCenterActivityType

@ObjectModel.representativeKey: 'CostCtrActivityType'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: [ #ANALYTICAL_DIMENSION ]

@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #M
}

@EndUserText.label: 'Cost Center Activity Type'
@Analytics:{
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        automatic: true
        }
    }
}
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFICCACTTYP'
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

//--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

@AccessControl.privilegedAssociations: ['_ControllingAreaText']
// ]--GENERATED

@Consumption.filter.businessDate.at: true

define view I_CostCenterActivityType
as select from csla

  //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

  association [0..1] to I_ControllingArea      as _ControllingAreaText on   $projection.ControllingArea = _ControllingAreaText.ControllingArea
  // ]--GENERATED

association [0..*] to I_CostCenterActivityTypeText   as _Text                on $projection.ControllingArea     = _Text.ControllingArea 
                                                                                   and $projection.CostCtrActivityType = _Text.CostCtrActivityType
                                                                                   and $projection.ValidityEndDate     = _Text.ValidityEndDate
association[1]     to I_ControllingArea              as _ControllingArea     on $projection.ControllingArea     = _ControllingArea.ControllingArea
association [0..*] to I_CostCtrActytypeCostCtrCat    as _CostCenterCategory  on  $projection.ControllingArea     = _CostCenterCategory.ControllingArea
                                                                                   and $projection.CostCtrActivityType = _CostCenterCategory.CostCtrActivityType
                                                                                   and $projection.ValidityEndDate     = _CostCenterCategory.ValidityEndDate
association[0..1]  to I_CostCenterActivityTypeCat    as _CostCtrActivityTypeCategory on $projection.CostCtrActivityTypeCategory = _CostCtrActivityTypeCategory.CostCtrActivityTypeCategory
association[1]     to I_UnitOfMeasure                as _UnitOfMeasure       on $projection.CostCtrActivityTypeQtyUnit = _UnitOfMeasure.UnitOfMeasure
association [0..*] to I_CostCtrActivityTypeHierNode  as _CostCtrActivityTypeHierNode on $projection.ControllingArea = _CostCtrActivityTypeHierNode.ControllingArea
                                                                                   and $projection.CostCtrActivityType = _CostCtrActivityTypeHierNode.CostCtrActivityType 
{
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.association: '_ControllingAreaText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_ControllingArea' //Inserted by VDM CDS Suite Plugin

@EndUserText.label: 'Controlling Area'
  key cast( kokrs as fis_kokrs preserving type ) as ControllingArea,
@ObjectModel.hierarchy.association: '_CostCtrActivityTypeHierNode'
@ObjectModel.text.association: '_Text'
  key lstar as CostCtrActivityType,
@Semantics.businessDate.to: true  
  key datbi as ValidityEndDate,
@Semantics.businessDate.from: true
      datab as ValidityStartDate,
@Semantics.unitOfMeasure:true
      leinh as CostCtrActivityTypeQtyUnit,
@ObjectModel.foreignKey.association: '_CostCtrActivityTypeCategory' //Inserted by VDM CDS Suite Plugin

      latyp as CostCtrActivityTypeCategory,
      vksta as AllocationCostElement,
      auseh as CostCtrActivityTypeOutpQtyUnit,
      ersda as CreationDate,
      usnam as EnteredByUser,
      hrkft as CostOriginGroup,
      latypi  as ActlPostgCostCenterActyTypeCat,
@DefaultAggregation: #SUM
//@Semantics: { quantity : {unitOfMeasure: 'CostCtrActivityTypeQtyUnit'} } 

      ausfk   as OutputQuantityFactor,
      sprkz   as ActivityTypeIsBlocked,
      fixvo   as FixedCostIsPredistributed,
      tarkz   as PriceAllocationMethod,
      yrate   as PeriodPriceIsAverage,
      tarkz_i as ActualPriceAllocationMethod,
      manist  as ActualQuantityIsSetManually,
      manplan as PlanQuantityIsSetManually,
      kstty   as CostCtrActivityTypeValidCat,
      lark1   as CostCtrActyTypeIsCtrlgRlvtComp,
      lark2   as CostCtrActyTypeIsHumRsceRlvt,
  _Text,
  _ControllingArea,
  _CostCenterCategory,
  _CostCtrActivityTypeCategory,
  _CostCtrActivityTypeHierNode,
  _UnitOfMeasure,
 // _CostCtrActivityTypeHierNode,

      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.hidden: true
      _ControllingAreaText
      // ]--GENERATED



};   
 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CSLA"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_COSTCENTERACTIVITYTYPECAT",
"I_COSTCENTERACTIVITYTYPETEXT",
"I_COSTCTRACTIVITYTYPEHIERNODE",
"I_COSTCTRACTYTYPECOSTCTRCAT",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/