I_SalesOrderRequestDerivedItem

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ISORDI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Sales Order Request Derived Item'
@ObjectModel:{
  representativeKey: 'SalesOrderRequestItem',
  usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}

@VDM: {
  viewType: #BASIC
}

define view I_SalesOrderRequestDerivedItem
  as select from sdsls_sordi as SalesOrderRequestDerivedItem

  association [0..1] to I_SalesOrderRequest     as _SalesOrderRequest     on  $projection.SalesOrderRequest = _SalesOrderRequest.SalesOrderRequest
  association [0..1] to I_SalesOrderRequestItem as _SalesOrderRequestItem on  $projection.SalesOrderRequest     = _SalesOrderRequestItem.SalesOrderRequest
                                                                          and $projection.SalesOrderRequestItem = _SalesOrderRequestItem.SalesOrderRequestItem
  association [0..1] to I_Product               as _Product               on  $projection.Product = _Product.Product
  association [0..1] to I_UnitOfMeasure         as _RequestedQuantityUnit on  $projection.RequestedQuantityUnit = _RequestedQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure         as _OrderQuantityUnit     on  $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
  association [0..1] to I_Currency              as _TransactionCurrency   on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  
{
      @ObjectModel.foreignKey.association: '_SalesOrderRequest'
  key SalesOrderRequestDerivedItem.salesorderrequest           as SalesOrderRequest,
      @ObjectModel.foreignKey.association: '_SalesOrderRequestItem'
  key SalesOrderRequestDerivedItem.salesorderrequestitem       as SalesOrderRequestItem,
  key SalesOrderRequestDerivedItem.salesorderitem              as SalesOrderItem,
      SalesOrderRequestDerivedItem.higherlevelitem             as HigherLevelItem,
      @ObjectModel.foreignKey.association: '_Product'
      SalesOrderRequestDerivedItem.product                     as Product,
      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      @Semantics.valueRange.minimum: 0
      SalesOrderRequestDerivedItem.requestedquantity           as RequestedQuantity,
      @ObjectModel.foreignKey.association: '_RequestedQuantityUnit'
      @Semantics.unitOfMeasure: true
      SalesOrderRequestDerivedItem.requestedquantityunit       as RequestedQuantityUnit,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderRequestDerivedItem.netamount                   as NetAmount,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode: true
      SalesOrderRequestDerivedItem.transactioncurrency         as TransactionCurrency,
      SalesOrderRequestDerivedItem.salesorderitemcategory      as SalesOrderItemCategory,
      SalesOrderRequestDerivedItem.materialbycustomer          as MaterialByCustomer,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      SalesOrderRequestDerivedItem.confddelivqtyinorderqtyunit as ConfdDelivQtyInOrderQtyUnit,
      SalesOrderRequestDerivedItem.confirmeddeliverydate       as ConfirmedDeliveryDate,
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      @Semantics.unitOfMeasure: true
      SalesOrderRequestDerivedItem.orderquantityunit           as OrderQuantityUnit,
      SalesOrderRequestDerivedItem.requesteddeliverydate       as RequestedDeliveryDate,

      _SalesOrderRequest,
      _SalesOrderRequestItem,
      _Product,
      _RequestedQuantityUnit,
      _TransactionCurrency,
      _OrderQuantityUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SDSLS_SORDI"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_PRODUCT",
"I_SALESORDERREQUEST",
"I_SALESORDERREQUESTITEM",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/