I_SalesOrderRequest

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ISOR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser']
}
@EndUserText.label: 'Sales Order Request'
@ObjectModel:{
  representativeKey: 'SalesOrderRequest',
  usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}

@VDM: {
  viewType: #BASIC
}

define view I_SalesOrderRequest
  as select from sdsls_sor as SalesOrderRequest
  association [0..*] to I_SalesOrderRequestItem        as _Item                      on  $projection.SalesOrderRequest = _Item.SalesOrderRequest
  association [0..1] to I_SalesOrderRequestPartner     as _SoldToPartyAddress        on  $projection.SalesOrderRequest = _SoldToPartyAddress.SalesOrderRequest
                                                                                     and _SoldToPartyAddress.PartnerFunction = 'AG'
  association [0..1] to I_SalesOrderRequestPartner     as _ShipToPartyAddress        on  $projection.SalesOrderRequest = _ShipToPartyAddress.SalesOrderRequest
                                                                                     and _ShipToPartyAddress.PartnerFunction = 'WE'
  association [0..*] to I_SalesOrderRequestDerivedItem as _DerivedItem               on  $projection.SalesOrderRequest = _DerivedItem.SalesOrderRequest
  association [0..1] to I_SalesOrderRequestSource      as _SalesOrderRequestSource   on  $projection.SalesOrderRequest = _SalesOrderRequestSource.SalesOrderRequest
  association [0..1] to I_CompanyCode                  as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_SalesOrganization            as _SalesOrganization         on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel          as _DistributionChannel       on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_SlsOrganizationDistrChnl     as _SlsOrganizationDistrChnl  on  $projection.SalesOrganization   = _SlsOrganizationDistrChnl.SalesOrganization
                                                                                     and $projection.DistributionChannel = _SlsOrganizationDistrChnl.DistributionChannel
  association [0..1] to I_Division                     as _OrganizationDivision      on  $projection.OrganizationDivision = _OrganizationDivision.Division
  association [0..1] to I_Customer                     as _SoldToParty               on  $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_Customer                     as _ShipToParty               on  $projection.ShipToParty = _ShipToParty.Customer
  association [0..1] to I_Currency                     as _TransactionCurrency       on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_User                         as _CreatedByUser             on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser         on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_SlsOrdReqExtractionStatus    as _SlsOrdReqExtractionStatus on  $projection.SalesOrderReqExtractionStatus = _SlsOrdReqExtractionStatus.SalesOrderReqExtractionStatus
  association [0..1] to I_SalesOrderRequestCategory    as _SalesOrderRequestCategory on  $projection.SalesOrderRequestCategory = _SalesOrderRequestCategory.SalesOrderRequestCategory
  association [0..1] to I_SalesOrderType               as _SalesOrderType            on  $projection.SalesOrderType = _SalesOrderType.SalesOrderType
  association [0..1] to I_SlsOrdReqSimulationStatus    as _SlsOrdReqSimulationStatus on  $projection.SalesOrderReqSimulationStatus = _SlsOrdReqSimulationStatus.SalesOrderReqSimulationStatus
  association [0..1] to I_SlsOrdReqApprovalStatus      as _SlsOrdReqApprovalStatus   on  $projection.SalesOrderReqApprovalStatus = _SlsOrdReqApprovalStatus.SalesOrderReqApprovalStatus
{
  key SalesOrderRequest.salesorderrequest              as SalesOrderRequest,
      @ObjectModel.foreignKey.association: '_SalesOrderRequestCategory'
      SalesOrderRequest.salesorderrequestcategory      as SalesOrderRequestCategory,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      SalesOrderRequest.companycode                    as CompanyCode,
      SalesOrderRequest.uploadfilecontentbinary        as UploadFileContentBinary,
      SalesOrderRequest.salesorderrequestfilemimetype  as SalesOrderRequestFileMimeType,
      SalesOrderRequest.salesorderrequestfilename      as SalesOrderRequestFileName,
      SalesOrderRequest.salesorderrequestextractoruuid as SalesOrderRequestExtractorUUID,
      @ObjectModel.foreignKey.association: '_SlsOrdReqExtractionStatus'
      SalesOrderRequest.salesorderreqextractionstatus  as SalesOrderReqExtractionStatus,
      SalesOrderRequest.salesorderreqprocessingstatus  as SalesOrderReqProcessingStatus,
      @ObjectModel.foreignKey.association: '_SalesOrderType'
      SalesOrderRequest.salesordertype                 as SalesOrderType,
      @ObjectModel.foreignKey.association: '_SoldToParty'
//      SalesOrderRequest.soldtoparty                    as SoldToParty,

//      SalesOrderRequest.soldtopartyaddressid           as SoldToPartyAddressID,

      _SoldToPartyAddress.Customer                     as SoldToParty, 
      _SoldToPartyAddress.AddressID                    as SoldToPartyAddressID,

      @ObjectModel.foreignKey.association: '_ShipToParty'
//      SalesOrderRequest.shiptoparty                    as ShipToParty,

//      SalesOrderRequest.shiptopartyaddressid           as ShipToPartyAddressID,

      _ShipToPartyAddress.Customer                     as ShipToParty, 
      _ShipToPartyAddress.AddressID                    as ShipToPartyAddressID,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrderRequest.salesorganization              as SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      SalesOrderRequest.distributionchannel            as DistributionChannel,
      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      SalesOrderRequest.organizationdivision           as OrganizationDivision,
      SalesOrderRequest.purchaseorderbycustomer        as PurchaseOrderByCustomer,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      SalesOrderRequest.transactioncurrency            as TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderRequest.totalnetamount                 as TotalNetAmount,
      SalesOrderRequest.sdpricingprocedure             as SDPricingProcedure,
      SalesOrderRequest.salesorder                     as SalesOrder,
      SalesOrderRequest.createdbyuser                  as CreatedByUser,
      SalesOrderRequest.creationdatetime               as CreationDateTime,
      SalesOrderRequest.lastchangedbyuser              as LastChangedByUser,
      SalesOrderRequest.lastchangedatetime             as LastChangeDateTime,
      SalesOrderRequest.requesteddeliverydate          as RequestedDeliveryDate,
      @ObjectModel.foreignKey.association: '_SlsOrdReqSimulationStatus'
      SalesOrderRequest.salesorderreqsimulationstatus  as SalesOrderReqSimulationStatus,
      @ObjectModel.foreignKey.association: '_SlsOrdReqApprovalStatus'
      SalesOrderRequest.salesorderreqapprovalstatus    as SalesOrderReqApprovalStatus,
      SalesOrderRequest.lastsimulateddatetime          as LastSimulatedDateTime,
      SalesOrderRequest.salesorderrequestloghandle     as SalesOrderRequestLogHandle,
      SalesOrderRequest.slsordreqfilecontenthash       as SlsOrdReqFileContentHash,      
      SalesOrderRequest.slsordreqsilentdtamigrtnvers   as SlsOrdReqSilentDtaMigrtnVers,
      SalesOrderRequest.incotermsclassification        as IncotermsClassification,
      SalesOrderRequest.incotermsversion               as IncotermsVersion,
      SalesOrderRequest.incotermslocation1             as IncotermsLocation1,
      SalesOrderRequest.incotermslocation2             as IncotermsLocation2,
      SalesOrderRequest.customerpaymentterms           as CustomerPaymentTerms,
      SalesOrderRequest.fixedvaluedate                 as FixedValueDate,
      

      _Item,
      _DerivedItem,
      _SalesOrderType,
      _SalesOrderRequestSource,
      _CompanyCode,
      _SalesOrganization,
      _DistributionChannel,
      _OrganizationDivision,
      _SlsOrganizationDistrChnl,
      _SoldToParty,
      _SoldToPartyAddress,
      _ShipToParty,
      _ShipToPartyAddress,
      _TransactionCurrency,
      _CreatedByUser,
      _LastChangedByUser,
      _SlsOrdReqExtractionStatus,
      _SalesOrderRequestCategory,
      _SlsOrdReqSimulationStatus,
      _SlsOrdReqApprovalStatus

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESORDERREQUESTPARTNER",
"SDSLS_SOR"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESORDERREQUESTCATEGORY",
"I_SALESORDERREQUESTDERIVEDITEM",
"I_SALESORDERREQUESTITEM",
"I_SALESORDERREQUESTPARTNER",
"I_SALESORDERREQUESTSOURCE",
"I_SALESORDERTYPE",
"I_SALESORGANIZATION",
"I_SLSORDREQAPPROVALSTATUS",
"I_SLSORDREQEXTRACTIONSTATUS",
"I_SLSORDREQSIMULATIONSTATUS",
"I_SLSORGANIZATIONDISTRCHNL",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/