I_REJournalEntryValnObjMapping

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'RE Mapping between Journal Entry and Valuation Object'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_REJournalEntryValnObjMapping
  as select from I_JournalEntryItem    as _JournalEntryItem
    inner join   I_REDocumentHeader    as _REDocumentHeader    on _REDocumentHeader.OriginalReferenceDocument = concat(
      _JournalEntryItem.ReferenceDocument, _JournalEntryItem.ReferenceDocumentContext
    )
    inner join   I_REDocumentItem      as _REDocumentItem      on  _REDocumentHeader.RealEstateDocumentUUID = _REDocumentItem.RealEstateDocumentUUID
                                                               and _JournalEntryItem.ReferenceDocumentItem  = substring(
      _REDocumentItem.REReferenceDocumentItem, 5, 6
    )
    inner join   I_REValuationCashFlow as _REValuationCashFlow on _REValuationCashFlow.REValuationCashFlowRecordUUID = _REDocumentItem.REDocumentReferenceUUID
    inner join   I_RECondition         as _RECondition         on _RECondition.REConditionUUID = _REValuationCashFlow.REConditionUUID

  association [0..1] to I_REServiceGroupBasicData      as _REServiceGroup      on _RECondition.REStatusObjectCalculation = _REServiceGroup.REStatusObject
  association [0..1] to I_REContractSubject            as _REContractSubject   on _RECondition.REStatusObjectCalculation = _REContractSubject.REStatusObject
  association [0..1] to I_REIntegrationObjectBasicData as _REIntegrationObject on _RECondition.REStatusObjectCalculation = _REIntegrationObject.REStatusObject
  association [0..1] to I_REFlowType                   as _REFlowType          on _REValuationCashFlow.REFlowType        = _REFlowType.REFlowType
  association [0..1] to I_REConditionType              as _REConditionType     on _REValuationCashFlow.REConditionType   = _REConditionType.REConditionType
{
  key _JournalEntryItem.CompanyCode,
  key _JournalEntryItem.FiscalYear,
  key _JournalEntryItem.AccountingDocument,
  key _JournalEntryItem.LedgerGLLineItem,
      _REValuationCashFlow.REFlowType,
      _REValuationCashFlow.REConditionType,
//      _REValuationCashFlow.REBookedFlowType,

      _RECondition.REStatusObjectCalculation       as REStatusObject,
      _REServiceGroup.RealEstateServiceGroupNumber as RealEstateServiceGroupNumber,
      _REIntegrationObject.REIntegrationObjectNumber,
      _REContractSubject.REContractSubjectNumber,

      /* Associations */
      _REContractSubject,
      _REIntegrationObject,
      _REServiceGroup,
      _REConditionType,
      _REFlowType

}
where
       _JournalEntryItem.ReferenceDocumentType      =  'REACI'
  and(
       _JournalEntryItem._Ledger.IsLeadingLedger    =  'X'
    or _JournalEntryItem.AccountingDocumentCategory =  'L'
  )
  and  _RECondition.REStatusObjectCalculation       <> ''
group by
  _JournalEntryItem.CompanyCode,
  _JournalEntryItem.FiscalYear,
  _JournalEntryItem.AccountingDocument,
  _JournalEntryItem.LedgerGLLineItem,
  _RECondition.REStatusObjectCalculation,
  _REServiceGroup.RealEstateServiceGroupNumber,
  _REIntegrationObject.REIntegrationObjectNumber,
  _REContractSubject.REContractSubjectNumber,
  _REValuationCashFlow.REFlowType,
//  _REValuationCashFlow.REBookedFlowType,

  _REValuationCashFlow.REConditionType
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYITEM",
"I_LEDGER",
"I_RECONDITION",
"I_RECONTRACTSUBJECT",
"I_REDOCUMENTHEADER",
"I_REDOCUMENTITEM",
"I_REINTEGRATIONOBJECTBASICDATA",
"I_RESERVICEGROUPBASICDATA",
"I_REVALUATIONCASHFLOW"
],
"ASSOCIATED":
[
"I_RECONDITIONTYPE",
"I_RECONTRACTSUBJECT",
"I_REFLOWTYPE",
"I_REINTEGRATIONOBJECTBASICDATA",
"I_RESERVICEGROUPBASICDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/