I_REVALUATIONCASHFLOW

@AbapCatalog.sqlViewName: 'IRECECFVAL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Valuation Cash Flow'

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_REValuationCashFlow
  as select from vicecfrule

  association [1..1] to I_REContract              as _REContract               on  $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [0..1] to I_REDocumentHeader        as _REDocumentHeader         on  $projection.REDocumentReferenceUUID = _REDocumentHeader.RealEstateDocumentUUID
  association [1..1] to I_RECondition             as _RECondition              on  $projection.REConditionUUID = _RECondition.REConditionUUID
  association [0..1] to I_REConditionType         as _REConditionType          on  $projection.REConditionType = _REConditionType.REConditionType
  association [0..1] to I_RETaxType               as _RETaxType                on  $projection.TaxCountry = _RETaxType.Country
                                                                               and $projection.RETaxType  = _RETaxType.RETaxType
  association [0..1] to I_RETaxGroup              as _RETaxGroup               on  $projection.RETaxGroup = _RETaxGroup.TaxGroup
  association [0..1] to I_Country                 as _TaxCountry               on  $projection.TaxCountry = _TaxCountry.Country
  association [0..1] to I_REFlowType              as _REFlowType               on  $projection.REFlowType = _REFlowType.REFlowType
  association [0..1] to I_REFlowType              as _REOriglFlowType          on  $projection.REOriginalFlowType = _REOriglFlowType.REFlowType
  association [0..1] to I_RERelshpOriglToFlowType as _RERelshpOriglToFlowType  on  $projection.RERelshpOriglToFlowType = _RERelshpOriglToFlowType.RERelshpOriglToFlowType
  association [0..1] to I_REFlowType              as _REBookedFlowType         on  $projection.REBookedFlowType = _REBookedFlowType.REFlowType
  association [0..1] to I_RERelshpOriglToFlowType as _RERelshpBookedToFlowType on  $projection.RERelshpBookedToFlowType = _RERelshpBookedToFlowType.RERelshpOriglToFlowType
  association [0..1] to I_RECashFlowItemOrigin    as _RECashFlowItemOrigin     on  $projection.CashFlowItemOrigin = _RECashFlowItemOrigin.CashFlowItemOrigin
  association [0..1] to I_RECashFlowPostingStatus as _RECashFlowPostingStatus  on  $projection.CashFlowPostingStatus = _RECashFlowPostingStatus.CashFlowPostingStatus
  association [0..1] to I_User                    as _CreatedByUser            on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                    as _ChangedByUser            on  $projection.LastChangedByUser = _ChangedByUser.UserID
{
      @ObjectModel.foreignKey.association: '_REContract'
  key intreno                                                    as InternalRealEstateNumber,
  key ruleguid                                                   as REValuationRuleUUID,
  key processguid                                                as REValuationProcessUUID,
  key cfguid                                                     as REValuationCashFlowRecordUUID,
      termno                                                     as RETermNumber,
      cerule                                                     as REValuationRule,
      cftype                                                     as RECashFlowType,
      @ObjectModel.foreignKey.association: '_RECashFlowItemOrigin'
      cfwherefrom                                                as CashFlowItemOrigin,
      objnr                                                      as REStatusObject,
      assetobjnr                                                 as REStatusObjectAsset,
      @ObjectModel.foreignKey.association: '_RECondition'
      condguid                                                   as REConditionUUID,
      condvalidfrom                                              as ValidityStartDate,
      dbervon                                                    as CalculationPeriodStartDate,
      dberbis                                                    as CalculationPeriodEndDate,
      atage                                                      as NumberOfDays,
      //        duedate,

      dfaell                                                     as PaymentDueDate,
      dvalut                                                     as CalculationDate,
//      @Semantics.amount.currencyCode: 'REConditionCurrency'

//      bbwhr                                                      as FinTransFlowNomAmtPosition,

      @Semantics.currencyCode: true
      swhrkond                                                   as REConditionCurrency,
      interestrate                                               as REInterestRate,
      isinitialcosts                                             as REValuationIsInitialCost,
      isrepaymentdif                                             as REValuationIsLiabilityDiff,
      //  isdeferralsadjustment,

      //  isreconobligation,

      iscompleteretirement                                       as REValnIsCompleteRetirement,
      //  isretroactivechange,

      isreduction                                                as REValuationIsReduction,
      @ObjectModel.foreignKey.association: '_REDocumentHeader'
      refguid                                                    as REDocumentReferenceUUID,
      refguid2                                                   as REDocumentReference2UUID,
      refguid3                                                   as REDocumentReference3UUID,
      refguid4                                                   as REDocumentReference4UUID,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      rerf                                                       as CreatedByUser,
      derf                                                       as CreationDate,
      terf                                                       as CreationTime,
      reher                                                      as RESourceOfCreation,
      @ObjectModel.foreignKey.association: '_ChangedByUser'
      rbear                                                      as LastChangedByUser,
      dbear                                                      as LastChangeDate,
      tbear                                                      as LastChangeTime,
      rbher                                                      as RESourceOfChange,
      isreversed                                                 as IsReversed,
      splitforguid                                               as SplitCashFlowRecordUUID,
      splitbasis                                                 as RecordIsBasisForSplit,
      //  evaluationpoint,

      //  assetreduction,

      //  correctionguid,

      valuationengine                                            as REValuationEngine,
      @Semantics.amount.currencyCode: 'RECashFlowLoclCurrency'
      lcnetamount                                                as RECashFlowLoclNetAmount,
      @Semantics.amount.currencyCode: 'RECashFlowLoclCurrency'
      lcgrossamount                                              as RECashFlowLoclGrossAmount,
      @Semantics.amount.currencyCode: 'RECashFlowLoclCurrency'
      lctaxamount                                                as RECashFlowLoclTaxAmount,
      @Semantics.currencyCode: true
      localcurr                                                  as RECashFlowLoclCurrency,
      @Semantics.amount.currencyCode: 'RECashFlowConditionCurrency'
      ccnetamount                                                as RECashFlowConditionNetAmount,
      @Semantics.amount.currencyCode: 'RECashFlowConditionCurrency'
      ccgrossamount                                              as RECashFlowConditionGrossAmount,
      @Semantics.amount.currencyCode: 'RECashFlowConditionCurrency'
      cctaxamount                                                as RECashFlowConditionTaxAmount,
      @Semantics.currencyCode: true
      condcurr                                                   as RECashFlowConditionCurrency,
      @ObjectModel.foreignKey.association: '_RETaxType'
      taxtype                                                    as RETaxType,
      @ObjectModel.foreignKey.association: '_RETaxGroup'
      taxgroup                                                   as RETaxGroup,
      txjcd                                                      as TaxJurisdiction,
      isgross                                                    as REIsConditionGrossAmount,
      @ObjectModel.foreignKey.association: '_TaxCountry'
      taxcountry                                                 as TaxCountry,
      @ObjectModel.foreignKey.association: '_REFlowType'
      flowtype                                                   as REFlowType,
      @ObjectModel.foreignKey.association: '_REOriglFlowType'
      cast( origflowtype as recdoflowtype preserving type )      as REOriginalFlowType,
      @ObjectModel.foreignKey.association: '_RERelshpOriglToFlowType'
      cast( refflowrel as recdorefflowrel preserving type )      as RERelshpOriglToFlowType,
      @ObjectModel.foreignKey.association: '_RECashFlowPostingStatus'
      cast( cfstatus as recfvdmcfstatus preserving type )        as CashFlowPostingStatus,
      fdelete                                                    as IsToBeArchived,
      origduedate                                                as REOriglDueDate,
      @ObjectModel.foreignKey.association: '_REConditionType'
      condtype                                                   as REConditionType,
      postingdate                                                as PostingDate,
      documentdate                                               as DocumentDate,
      valuationdate                                              as ExchangeRateDate,
      reversal_for                                               as REReversalForUUID,
      reversal_by                                                as REReversalByUUID,
      followup_for                                               as REFollowUpPostingUUID,
      @ObjectModel.foreignKey.association: '_REBookedFlowType'
      cast( book_flowtype as recdbflowtype preserving type )     as REBookedFlowType,
      @ObjectModel.foreignKey.association: '_RERelshpBookedToFlowType'
      cast( book_refflowrel as recdbrefflowrel preserving type ) as RERelshpBookedToFlowType,
      taxdate                                                    as RETaxCalcDate,
      modduedate                                                 as REModifiedDueDate,
      calcduedate                                                as RECalcDueDate,
      ctrule                                                     as RECurrencyTranslationRule,
      @Semantics.amount.currencyCode: 'RECashFlowLoclCurrency'
      ctlcnetamount                                              as RETrnsltnRuleLoclNetAmount,
      @Semantics.amount.currencyCode: 'RECashFlowLoclCurrency'
      ctlcgrossamount                                            as RETrnsltnRuleLoclGrossAmount,
      @Semantics.amount.currencyCode: 'RECashFlowLoclCurrency'
      ctlctaxamount                                              as RETrnsltnRuleLoclTaxAmount,
      cast( ctrate as kurrf_not_converted preserving type )      as ExchangeRate,
      cast( ctrateorig as kurrf_not_converted preserving type )  as REOriginExchangeRate,
      ctpostcdcurr                                               as REIsPostInConditionCurrency,
      ctdatereq                                                  as REPlndTranslationDate,
      ctdateact                                                  as REActlTranslationDate,
      ctdateactorig                                              as REOriglActlTranslationDate,
      ctdatefromcfpos                                            as REIsTranslationDateFrmCashFlow,

      /* Associations */
      _REContract,
      _RECondition,
      _REConditionType,
      _REDocumentHeader,
      _CreatedByUser,
      _ChangedByUser,
      _RETaxType,
      _RETaxGroup,
      _TaxCountry,
      _REFlowType,
      _REOriglFlowType,
      _RECashFlowItemOrigin,
      _RERelshpOriglToFlowType,
      _RECashFlowPostingStatus,
      _REBookedFlowType,
      _RERelshpBookedToFlowType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VICECFRULE"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_RECASHFLOWITEMORIGIN",
"I_RECASHFLOWPOSTINGSTATUS",
"I_RECONDITION",
"I_RECONDITIONTYPE",
"I_RECONTRACT",
"I_REDOCUMENTHEADER",
"I_REFLOWTYPE",
"I_RERELSHPORIGLTOFLOWTYPE",
"I_RETAXGROUP",
"I_RETAXTYPE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/