I_PurchaseOrderItemTP

@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'IPURORDITMTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Transactional View for Purchase Order Item'

@ObjectModel: {
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    writeDraftPersistence: 'PURORDITMTP_D',
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem'],
    representativeKey: 'PurchaseOrderItem'
}

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API


define view I_PurchaseOrderItemTP
  as select from R_PurchaseOrderItem as Document

  association [1..1] to I_PurchaseOrderTP              as _PurchaseOrderTP              on  _PurchaseOrderTP.PurchaseOrder = $projection.PurchaseOrder
  
  association [1..*] to I_PurOrdAcctAssignmentTP       as _PurOrdAcctAssignmentTP       on  _PurOrdAcctAssignmentTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurOrdAcctAssignmentTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..*] to I_PurOrdPricingElementTP       as _PurOrdPricingElementTP       on  _PurOrdPricingElementTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurOrdPricingElementTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..*] to I_PurOrdScheduleLineTP         as _PurOrdScheduleLineTP         on  _PurOrdScheduleLineTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurOrdScheduleLineTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..1] to I_PurOrdDeliveryAddressTP      as _PurOrdDeliveryAddressTP      on  _PurOrdDeliveryAddressTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurOrdDeliveryAddressTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..1] to I_PurgDocumentItemCategoryText as _PurgDocumentItemCategoryText on  _PurgDocumentItemCategoryText.Language                       = $session.system_language
                                                                                        and _PurgDocumentItemCategoryText.PurchasingDocumentItemCategory = PurchaseOrderItemCategory
  association [0..1] to I_ProductTypeCodeText          as _ProductTypeCodeText          on  _ProductTypeCodeText.ProductTypeCode = $projection.ProductType
                                                                                        and _ProductTypeCodeText.Language        = $session.system_language
  association [0..1] to I_PurchaseOrderItemStatus      as _PurchaseOrderItemStatus      on  _PurchaseOrderItemStatus.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurchaseOrderItemStatus.PurchaseOrderItem = $projection.PurchaseOrderItem
                                                                    
  ----Extension Association
  association [1..1] to E_PurchasingDocumentItem       as _PurchaseOrderItemExtension   on  $projection.PurchaseOrder     = _PurchaseOrderItemExtension.PurchasingDocument
                                                                                        and $projection.PurchaseOrderItem = _PurchaseOrderItemExtension.PurchasingDocumentItem
  association [0..*] to I_PurchaseOrderItemNoteTP      as _PurchaseOrderItemNoteTP        on  _PurchaseOrderItemNoteTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                                        and _PurchaseOrderItemNoteTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [0..1] to I_WBSElementBasicData          as _WBSElement                   on  _WBSElement.WBSElementInternalID = $projection.WBSElementInternalID

{

      @ObjectModel.foreignKey.association: '_PurchaseOrderTP'
  key Document.PurchaseOrder,
  
  key cast (Document.PurchaseOrderItem as ebelp preserving type) as PurchaseOrderItem,
      PurchaseOrderItemUniqueID,
            
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.NetPriceAmount,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.PurchaseOrderItemCategory,
      _PurgDocumentItemCategoryText.PurgDocExternalItemCategory  as PurOrdExternalItemCategory,
      _PurgDocumentItemCategoryText.PurgDocItemCategoryName      as PurOrdItemCategoryName,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_ProductType'
      Document.ProductType,
      _ProductTypeCodeText.Name                                  as ProductTypeName,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_Material'
      Document.Material,
      Document.SupplierMaterialNumber,
      Document.ManufacturerPartNmbr,
      Document.ManufacturerMaterial,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      Document.MaterialGroup,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      @ObjectModel.foreignKey.association: '_Plant'
      Document.Plant,
      Document.PurchaseOrderItemText,
      Document.CompanyCode,
      Document.PurchasingDocumentDeletionCode,
      _PurchaseOrderItemStatus.PurchaseOrderItemStatus           as PurchaseOrderItemStatus,
      //      _PurchaseOrderItemCalcFields._PurchaseOrderItemStatus._PurchasingDocumentStatus.PurchasingDocumentStatus as PurchaseOrderItemStatus,

      Document.IsReturnsItem,
      Document.IsStatisticalItem,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.IsCompletelyDelivered,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.IsFinallyInvoiced,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.GoodsReceiptIsExpected,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.GoodsReceiptIsNonValuated,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.IsToBeAcceptedAtOrigin,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.InvoiceIsExpected,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.InvoiceIsGoodsReceiptBased,
      Document.EvaldRcptSettlmtIsAllowed,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.PriceChangeInSESIsAllowed, 
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.UnlimitedOverdeliveryIsAllowed,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.OverdelivTolrtdLmtRatioInPct,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.UnderdelivTolrtdLmtRatioInPct,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_PurchaseContract'
      Document.PurchaseContract,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_PurchaseContractItem'
      Document.PurchaseContractItem,
      Document.PurchaseRequisition,
      Document.PurchaseRequisitionItem,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.IsOrderAcknRqd,
      Document.RequestForQuotation,
      Document.RequestForQuotationItem,
      Document.SupplierQuotation,
      Document.SupplierQuotationItem,
      Document.MultipleAcctAssgmtDistribution,
      Document.PartialInvoiceDistribution,
      Document.PricingDateControl,
      Document.RequisitionerName,
      Document.PlannedDeliveryDurationInDays,
      Document.ConsumptionPosting,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_ServicePerformer'
      Document.ServicePerformer,
      Document.ServicePackage,
      Document.AccountAssignmentCategory,
      Document.CostCenter,
      Document.GLAccount,
      Document.WBSElementInternalID,
      _WBSElement.WBSElement                                     as WBSElementExternalID,
      _WBSElement.WBSDescription,
      Document.Fund,
      Document.BudgetPeriod,
      Document.FundsCenter,
      Document.CommitmentItem,
      Document.FunctionalArea,
      Document.GrantID,
      Document.EarmarkedFunds, //    deprecated, use EarmarkedFundsDocument

      Document.EarmarkedFundsDocument,
      Document.EarmarkedFundsItem, //    deprecated, use EarmarkedFundsDocumentItem

      Document.EarmarkedFundsDocumentItem,
      Document.ProfitCenter,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_StorageLocation'
      Document.StorageLocation,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      Document.OrderQuantity,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      Document.PurchaseOrderQuantityUnit,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
      Document.PurchasingInfoRecord,
      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      Document.IncotermsClassification,
      Document.IncotermsTransferLocation,
      Document.IncotermsLocation1,
      Document.IncotermsLocation2,

      // TM Location Handling

      cast( ' ' as tminco_loc_1_id )                             as IncotermsLocation1Identifier,
      cast( ' ' as tminco_loc_2_id )                             as IncotermsLocation2Identifier,
      cast( ' ' as tminco_loc_d_id )                             as IncotermsDvtgLocIdentifier,
      cast( ' ' as tminco_loc_d_descr )                          as IncotermsDvtgLocDescription,            
      Document.IncotermsSupChnLoc1AddlUUID,      
      Document.IncotermsSupChnLoc2AddlUUID,
      Document.IncotermsSupChnDvtgLocAddlUUID,
           
      Document.InternationalArticleNumber,
      Document.IntrastatServiceCode,
      Document.CommodityCode,
      Document.SupplierConfirmationControlKey,
      Document.PriceIsToBePrinted,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.TaxCode,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.TaxJurisdiction,
      Document.TaxCodeValidFromDate,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.TaxCountry,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.TaxDeterminationDate,
      Document.ShippingInstruction,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.ItemIsRejectedBySupplier,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.PurchasingInfoRecordUpdateCode                    as IsInfoRecordUpdated,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      case
        when PurchasingInfoRecordUpdateCode = '' or PurchasingInfoRecordUpdateCode is null
        then cast (' ' as infup)
        else cast ('X' as infup)
      end                                                        as InfoRecordIsToBeUpdated,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.PurgDocOrderAcknNumber,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderPriceUnit'
      Document.OrderPriceUnit,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      Document.NetPriceQuantity,
      Document.OrderPriceUnitToOrderUnitNmrtr,
      Document.OrdPriceUnitToOrderUnitDnmntr,
      Document.OrderItemQtyToBaseQtyNmrtr,
      Document.OrderItemQtyToBaseQtyDnmntr,
      @Semantics.unitOfMeasure: true
      Document.ItemVolumeUnit,
      @Semantics.unitOfMeasure: true
      Document.ItemWeightUnit,
      @Semantics.unitOfMeasure: true
      Document.BaseUnit,
      @Semantics.currencyCode: true
      Document.DocumentCurrency,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Document.NetAmount,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Document.EffectiveAmount,
//     //Foot Print Intigration 

      PFMTransDataFootprintUUID,
      // Additional Fields for hierarchy implementation

      Document.PurgConfigurableItemNumber,
      Document.PurgDocAggrgdSubitemCategory,
      Document.PurchasingParentItem,
      Document.PurgDocSubitemCategory,
      Document.PurgExternalSortNumber,
      // Added for hierarchy implementation

      cast( '' as rsnodeext )                                    as PurchasingHierarchyNode,
      cast( '' as rsnodeext )                                    as HierarchyParentNode,
      cast( 0 as  abap.int4 )                                    as HierarchyLevel,
      cast( 0 as   abap.int4 )                                   as HierarchyNodeSubTreeSize,
      cast( '' as abap.char(22) )                                as HierarchyDrillState,
      cast( 0 as  abap.int8  )                                   as HierarchyNodeOrdinalNumber,
      case
      when PurgDocAggrgdSubitemCategory = 'C'
      then cast('X' as mmpur_is_itemset)
      else cast(' ' as mmpur_is_itemset)
      end                                                        as PurchasingIsItemSet,
      case
        when ( InvoiceIsExpected = ' ' or InvoiceIsExpected is null ) and PurchaseOrderItemCategory <> '2' and PurchaseOrderItemCategory <> '7'
          then cast('X' as umson)
          else cast(' ' as umson)
      end                                                        as PurchasingItemIsFreeOfCharge, // -> logic from MEPO_ITEM_FILL_UMSON (include LMEPOF64)


      Document.ManualDeliveryAddressID,
      @ObjectModel.foreignKey.association: '_ReferenceDeliveryAddress'
      Document.ReferenceDeliveryAddressID,
      @ObjectModel.foreignKey.association: '_Customer'
      Document.Customer,

      case
       when ManualDeliveryAddressID = '' or ManualDeliveryAddressID is null then
         case
           when ReferenceDeliveryAddressID = '' or ReferenceDeliveryAddressID is null then
             case
               when Customer = '' or Customer is null then _Plant.AddressID
               else _Customer.AddressID
             end
           else ReferenceDeliveryAddressID
         end
       else ManualDeliveryAddressID
      end                                                        as ItemDeliveryAddressID,

      // S/4 Limit

      Document.ExpectedOverallLimitAmount,
      Document.OverallLimitAmount,
      Document.PurContractForOverallLimit,

      // fields from product compliance

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      Document.PurgProdCmplncSupplierStatus,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      Document.PurgProductMarketabilityStatus,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      Document.PurgSafetyDataSheetStatus,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      Document.PurgProdCmplncDngrsGoodsStatus,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      cast ('' as charg_d)                                       as Batch,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      cast ('' as lichn)                                         as BatchBySupplier,

      //Brazil Extension

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_BR_MaterialOrigin'
      Document.BR_MaterialOrigin,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_BR_MaterialUsage'
      Document.BR_MaterialUsage,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_BR_CFOPCategory'
      Document.BR_CFOPCategory,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      @ObjectModel.foreignKey.association: '_BR_NCM'
      BR_NCM,


      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      IN_GSTControlCode,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.BR_IsProducedInHouse,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      cast ('' as hghstmsgsvrtylvl)                                as HighestMessageSeverityLevel,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      cast ('' as poitmacctassgmtfieldsareenbld )                as POItmAcctAssgmtFieldsAreEnbld,

      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      _PurchaseOrderTP.IncotermsVersion,

      _PurchaseOrderTP.PurchasingOrganization                    as PurchasingOrganization,
      _PurchaseOrderTP.PurchasingGroup                           as PurchasingGroup,
      _PurchaseOrderTP.PurchaseOrderType                         as PurchaseOrderType,

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _PurchaseOrderTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PurOrdAcctAssignmentTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PurOrdPricingElementTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PurOrdScheduleLineTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PurOrdDeliveryAddressTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PurchaseOrderItemNoteTP,

      _Material,
       @Consumption.filter.hidden: true
      _Plant,

      _MaterialGroup,

      _PurchaseContract,

      _PurchaseContractItem,

      _IncotermsClassification,

      _ServicePerformer,
       @Consumption.filter.hidden: true
      _StorageLocation,

      _PurchasingInfoRecord,

      _OrderPriceUnit,

      _OrderQuantityUnit,

      _ProductType,

      _Customer,
       @Consumption.filter.hidden: true
      _PurchaseOrderTP._IncotermsVersion,
       @Consumption.filter.hidden: true
      _PurchaseOrderTP._PurchasingGroup,
       @Consumption.filter.hidden: true
      _PurchaseOrderTP._PurchasingOrganization,
      

      _BR_MaterialOrigin,

      _BR_MaterialUsage,

      _BR_CFOPCategory,

      _BR_NCM,

      _WBSElement,
      
      _ReferenceDeliveryAddress_2 as _ReferenceDeliveryAddress
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_PLANT",
"I_PRODUCTTYPECODETEXT",
"I_PURCHASEORDERITEMSTATUS",
"I_PURCHASEORDERTP",
"I_PURGDOCUMENTITEMCATEGORYTEXT",
"I_WBSELEMENTBASICDATA",
"R_PURCHASEORDERITEM"
],
"ASSOCIATED":
[
"E_PURCHASINGDOCUMENTITEM",
"I_ADDRESS_2",
"I_BR_CFOPCATEGORY",
"I_BR_MATERIALORIGIN",
"I_BR_MATERIALUSAGE",
"I_BR_NCM",
"I_BUSINESSPARTNER",
"I_CUSTOMER",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PRODUCTTYPECODE",
"I_PRODUCTTYPECODETEXT",
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASEORDERITEMNOTETP",
"I_PURCHASEORDERITEMSTATUS",
"I_PURCHASEORDERTP",
"I_PURCHASINGGROUP",
"I_PURCHASINGINFORECORDAPI01",
"I_PURCHASINGORGANIZATION",
"I_PURGDOCUMENTITEMCATEGORYTEXT",
"I_PURORDACCTASSIGNMENTTP",
"I_PURORDDELIVERYADDRESSTP",
"I_PURORDPRICINGELEMENTTP",
"I_PURORDSCHEDULELINETP",
"I_STORAGELOCATION",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_PURCHASEORDERTP",
"R_PURCHASEORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/