I_PurOrdScheduleLineTP

@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'IPOSCHEDLINETP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Transactional View for PO Schedule Line'

@ObjectModel: {
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem', 'ScheduleLine'],
    representativeKey: 'ScheduleLine',
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    writeDraftPersistence: 'POSCHEDLINETP_D'
}

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_PurOrdScheduleLineTP
  as select from I_PurOrdScheduleLineBasic as Document

  association [1..1] to I_PurchaseOrderTP     as _PurchaseOrderTP     on  _PurchaseOrderTP.PurchaseOrder = $projection.PurchaseOrder
  association [1..1] to I_PurchaseOrderItemTP as _PurchaseOrderItemTP on  _PurchaseOrderItemTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                      and _PurchaseOrderItemTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..*] to I_POSubcontractingComponentTP as _SubcontractingComponent on  _SubcontractingComponent.PurchaseOrder     = $projection.PurchaseOrder
                                                                      and _SubcontractingComponent.PurchaseOrderItem = $projection.PurchaseOrderItem    
                                                                      and _SubcontractingComponent.ScheduleLine = $projection.ScheduleLine                                                                   

{

      @ObjectModel.foreignKey.association: '_PurchaseOrderTP'
  key Document.PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItemTP'
  key Document.PurchaseOrderItem,
  key Document.PurchaseOrderScheduleLine as ScheduleLine,

      Document.ScheduleLineDeliveryDate,

      Document.PerformancePeriodStartDate,

      Document.PerformancePeriodEndDate,
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      Document.ScheduleLineOrderQuantity,

      Document.SchedLineStscDeliveryDate,

      Document.RoughGoodsReceiptQty,

      Document.PurchaseOrderQuantityUnit,

      Document.PurchaseRequisition,

      Document.PurchaseRequisitionItem,
      
      Document.Batch,
      
      Document.BatchBySupplier,
      
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      cast ('' as hghstmsgsvrtylvl)  as  HighestMessageSeverityLevel,

      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _PurchaseOrderTP,
      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _PurchaseOrderItemTP,
      @ObjectModel.association.type: #TO_COMPOSITION_CHILD      
      _SubcontractingComponent,

      Document._PurchaseRequisitionItem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURORDSCHEDULELINEBASIC"
],
"ASSOCIATED":
[
"I_POSUBCONTRACTINGCOMPONENTTP",
"I_PURCHASEORDERITEMTP",
"I_PURCHASEORDERTP",
"I_PURCHASEREQUISITIONITEM"
],
"BASE":
[
"I_PURORDSCHEDULELINEBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/