I_PurInfCndPeriodWithDraft

@AbapCatalog.sqlViewName: 'I_PURINFCNDPRDWD'
@EndUserText.label: 'Conditions Records Validity with Draft'
@ObjectModel.writeDraftPersistence: 'INFREC_HDR_CND_D'
@ObjectModel.draftEnabled:true
@VDM.viewType: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.semanticKey: ['Plant', 'PurchasingInfoRecordCategory', 'PurchasingOrganization', 'PurchasingInfoRecord', 'ConditionValidityEndDate' ]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
//@Metadata.ignorePropagatedAnnotations: true


define view I_PurInfCndPeriodWithDraft
  as select from I_PurInfCndPeriod as Document
  association [1..1] to I_PurgInfoRecordWWithDraft as _PurgInfoRecordWWithDraft on  _PurgInfoRecordWWithDraft.Plant                        = $projection.Plant
                                                                                and _PurgInfoRecordWWithDraft.PurchasingInfoRecordCategory = $projection.PurchasingInfoRecordCategory
                                                                                and _PurgInfoRecordWWithDraft.PurchasingOrganization       = $projection.PurchasingOrganization
                                                                                and _PurgInfoRecordWWithDraft.PurchasingInfoRecord         = $projection.PurchasingInfoRecord
  association [0..1] to I_Currency                 as _DocumentCurrency         on  _DocumentCurrency.Currency = $projection.ConditionRateValueUnit
  association [0..*] to I_PurConditionText         as _ConditionText            on  _ConditionText.ConditionType = $projection.ConditionType

{

  key  Document.ConditionValidityEndDate,
  key  Document.Plant,
  key  Document.PurchasingInfoRecordCategory,
  key  Document.PurchasingOrganization,
  key  Document.PurchasingInfoRecord,
  key  Document.ConditionRecord,
       @ObjectModel.mandatory: true
       @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
       Document.ConditionValidityEndDate as ConditionValdtyEndDateForEdit,

       Document.ConditionSequentialNumber,
       @ObjectModel.readOnly: true
       Document.ConditionType,
       @ObjectModel.mandatory: true
       @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
       Document.ConditionValidityStartDate,
       Document.ConditionRateValue,
       //      @ObjectModel.foreignKey.association: '_DocumentCurrency'

       Document.ConditionRateValueUnit,
       @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
       Document.ConditionQuantity,
       Document.ConditionQuantityUnit,
       Document.ConditionApplication,
       Document.ConditionCalculationType,
       Document.ConditionIsDeleted,
       Document.ConditionToBaseQtyNmrtr,
       Document.ConditionToBaseQtyDnmntr,
       Document.BaseUnit,

       @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
       _PurgInfoRecordWWithDraft,

       _DocumentCurrency,

       _ConditionText


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURINFCNDPERIOD"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_PURCONDITIONTEXT",
"I_PURGINFORECORDWWITHDRAFT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/