I_PURINFCNDPERIOD

CDS View

CONDITONS VALIDITY

I_PURINFCNDPERIOD is a CDS View in S/4HANA. CONDITONS VALIDITY. It contains 19 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 19 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
I_PurInfCndPeriodWithDraft view from TRANSACTIONAL Conditions Records Validity with Draft
P_PurgInfoRecdPrcCalc view from CONSUMPTION Info Record Price Conversion
P_PurgInfoRecdVarcCalc view from CONSUMPTION Private View for PIR Variance
P_PurgInfoRecdVarcCalc view left_outer CONSUMPTION Private View for PIR Variance
P_PurInfoRecdPrHist view union_all CONSUMPTION Private View for Purchasing Info Record Price History

Fields (19)

KeyField CDS FieldsUsed in Views
KEY ConditionRecord ConditionRecord 2
KEY ConditionValidityEndDate ConditionValdtyEndDateForEdit,ConditionValidityEndDate 3
KEY Plant Plant 3
KEY PurchasingInfoRecord PurchasingInfoRecord 2
KEY PurchasingInfoRecordCategory PurchasingInfoRecordCategory 3
KEY PurchasingOrganization PurchasingOrganization 3
BaseUnit BaseUnit 1
ConditionApplication ConditionApplication 1
ConditionCalculationType ConditionCalculationType 1
ConditionIsDeleted ConditionIsDeleted 2
ConditionQuantity ConditionQuantity 1
ConditionQuantityUnit ConditionQuantityUnit 2
ConditionRateValue ConditionRateValue 2
ConditionRateValueUnit ConditionRateValueUnit 2
ConditionSequentialNumber ConditionSequentialNumber 1
ConditionToBaseQtyDnmntr ConditionToBaseQtyDnmntr 1
ConditionToBaseQtyNmrtr ConditionToBaseQtyNmrtr 1
ConditionType ConditionType 2
ConditionValidityStartDate ConditionValidityStartDate 2 
@AbapCatalog.sqlViewName: 'IPURINFCNDPRD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@EndUserText.label: 'CONDITONS VALIDITY'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.semanticKey: ['Plant', 'PurchasingInfoRecordCategory', 'PurchasingOrganization', 'PurchasingInfoRecord', 'ConditionValidityEndDate' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_PurInfCndPeriod
  as select distinct from I_PurInfCndHelpr as ConditionHelper

    inner join            konp             as ConditionDetails on  ConditionHelper.ConditionRecord = ConditionDetails.knumh
                                                               and ConditionDetails.loevm_ko       = ''

  association [1..1] to I_PurgInfoRecordWithOrgData as _InfoRecord       on  $projection.PurchasingInfoRecord         = _InfoRecord.PurchasingInfoRecord
                                                                         and $projection.Plant                        = _InfoRecord.Plant
                                                                         and $projection.PurchasingInfoRecordCategory = _InfoRecord.PurchasingInfoRecordCategory
                                                                         and $projection.PurchasingOrganization       = _InfoRecord.PurchasingOrganization


  association [0..1] to I_Currency                  as _DocumentCurrency on  $projection.ConditionRateValueUnit = _DocumentCurrency.Currency

  association [1..*] to I_PurConditionText          as _ConditionText    on  $projection.ConditionType = _ConditionText.ConditionType
{

  key ConditionHelper.PurchasingInfoRecord,

  key ConditionHelper.PurchasingOrganization,

  key ConditionHelper.PurchasingInfoRecordCategory,

  key ConditionHelper.Plant,

      @Semantics.businessDate.to: true
  key cast(ConditionHelper.ConditionValidityEndDate as abap.dats)    as ConditionValidityEndDate,

  key ConditionHelper.ConditionRecord,

      ConditionDetails.kopos                                         as ConditionSequentialNumber,

      //      @ObjectModel.foreignKey.association: '_ConditionText'

      @ObjectModel.text.association: '_ConditionText'
      ConditionDetails.kschl                                         as ConditionType,

      @Semantics.businessDate.from: true
      cast (ConditionHelper.ConditionValidityStartDate as abap.dats) as ConditionValidityStartDate,

      @Semantics.amount.currencyCode: 'ConditionRateValueUnit'
      @DefaultAggregation: #NONE
      ConditionDetails.kbetr                                         as ConditionRateValue,

      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      ConditionDetails.konwa                                         as ConditionRateValueUnit,

      ConditionDetails.kpein                                         as ConditionQuantity,

      ConditionDetails.kmein                                         as ConditionQuantityUnit,

      ConditionDetails.kappl                                         as ConditionApplication,

      ConditionDetails.krech                                         as ConditionCalculationType,

      ConditionDetails.loevm_ko                                      as ConditionIsDeleted,

      ConditionDetails.kumza                                         as ConditionToBaseQtyNmrtr,
      ConditionDetails.kumne                                         as ConditionToBaseQtyDnmntr,

      @ObjectModel.readOnly: true
      ConditionDetails.meins                                         as BaseUnit,

      _ConditionText,

      _DocumentCurrency,

      _InfoRecord

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURINFCNDHELPR",
"KONP"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_PURCONDITIONTEXT",
"I_PURGINFORECORDWITHORGDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More