I_ProjDmndResourceAssignment

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #PUBLIC_LOCAL_API

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@AbapCatalog: {
    sqlViewName: 'IPROJDMNDRSCEA',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE ],
   semanticKey:       [ 'ProjDmndRsceAssgmt' ],
   representativeKey: 'ProjDmndRsceAssgmtUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Analytics: {
  dataExtraction: { 
    enabled: true,
    delta.changeDataCapture: {
      automatic: true
    }
  }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Resource Assignment to Rsce Dmnd'

define view I_ProjDmndResourceAssignment
  as select from R_ProjDmndResourceAssignment

  association [1..1] to I_ProjectDemand           as _Root                   on  $projection.ProjectDemandUUID = _Root.ProjectDemandUUID
  association [1..1] to I_ProjectDemandWork       as _Work                   on  $projection.ProjectDemandWorkUUID = _Work.ProjectDemandWorkUUID
  association [0..*] to I_ProjDmndRsceAssgmtDistr as _AssgmtDistribution     on  $projection.ProjDmndRsceAssgmtUUID = _AssgmtDistribution.ProjDmndRsceAssgmtUUID

  association [0..1] to I_UnitOfMeasure           as _RsceAssgmtQuantityUnit on  $projection.ProjDmndRsceAssgmtQuantityUnit        = _RsceAssgmtQuantityUnit.UnitOfMeasure
                                                                             and _RsceAssgmtQuantityUnit.UnitOfMeasureDimension    = 'TIME'
                                                                             and _RsceAssgmtQuantityUnit.SIUnitCnvrsnRateNumerator = 3600
  association [1..1] to I_PersonWorkAgreement_1   as _PersonWorkAgreement    on  $projection.ProjDmndRsceAssgmt = _PersonWorkAgreement.PersonWorkAgreement
{

  key ProjDmndRsceAssgmtUUID         as ProjDmndRsceAssgmtUUID,

      ProjectDemandWorkUUID          as ProjectDemandWorkUUID,

      ProjectDemandUUID              as ProjectDemandUUID,

      @ObjectModel.foreignKey.association:    '_PersonWorkAgreement'
      ProjDmndRsceAssgmt             as ProjDmndRsceAssgmt,

      @Semantics: { quantity : {unitOfMeasure: 'ProjDmndRsceAssgmtQuantityUnit'} }
      ProjDmndRsceAssgmtQuantity     as ProjDmndRsceAssgmtQuantity,

      @ObjectModel.foreignKey.association:    '_RsceAssgmtQuantityUnit'
      ProjDmndRsceAssgmtQuantityUnit as ProjDmndRsceAssgmtQuantityUnit,
      ProjectDemandSupplyDeliveryOrg as ProjectDemandSupplyDeliveryOrg,
      ProjectDemandSourceOfSupply    as ProjectDemandSourceOfSupply,
      ProjAssgmtLastUpdateSource     as ProjAssgmtLastUpdateSource,

      @Semantics.user.createdBy: true
      CreatedByUser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime               as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime             as LastChangeDateTime,


      /* Associations */
      _Root,
      _Work,
      _AssgmtDistribution,
      
      _RsceAssgmtQuantityUnit,
      _PersonWorkAgreement

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PROJDMNDRESOURCEASSIGNMENT"
],
"ASSOCIATED":
[
"I_PERSONWORKAGREEMENT_1",
"I_PROJDMNDRSCEASSGMTDISTR",
"I_PROJECTDEMAND",
"I_PROJECTDEMANDWORK",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/