R_PROJDMNDRESOURCEASSIGNMENT

CDS View

Resource Assignment to Rsce Dmnd

R_PROJDMNDRESOURCEASSIGNMENT is a CDS View in S/4HANA. Resource Assignment to Rsce Dmnd. It contains 9 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 9 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_ProjDmndRsceAssignmentSum view from CONSUMPTION Sum of the Staffed Efforts
I_ProjDmndResourceAssignment view from BASIC Resource Assignment to Rsce Dmnd
I_ProjDmndResourceAssignmentTP view_entity from TRANSACTIONAL Resource Assignment to Resource Dmnd - TP
P_ProjDmndStaffedResources view from COMPOSITE Staffed resources on workpackages w/ staffing info

Fields (9)

KeyField CDS FieldsUsed in Views
KEY ProjDmndRsceAssgmtUUID ProjDmndRsceAssgmtUUID 1
KEY ProjectDemandUUID ProjectDemandUUID 2
_Root _Root 2
_RsceAssgmtQuantityUnit _RsceAssgmtQuantityUnit 1
_Work _Work 1
ProjDmndRsceAssgmt ProjDmndRsceAssgmt 1
ProjDmndRsceAssgmtQuantity ProjDmndRsceAssgmtQuantity 1
ProjDmndRsceAssgmtQuantityUnit ProjDmndRsceAssgmtQuantityUnit 1
ProjectDemandWorkUUID ProjectDemandWorkUUID 1 
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
   semanticKey:       [ 'ProjDmndRsceAssgmt' ],
   representativeKey: 'ProjDmndRsceAssgmtUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Resource Assignment to Rsce Dmnd'

define view entity R_ProjDmndResourceAssignment
  as select from resourceassgmt

  association [1..1] to R_ProjectDemand           as _Root                   on  $projection.ProjectDemandUUID = _Root.ProjectDemandUUID
  association [1..1] to R_ProjectDemandWork       as _Work                   on  $projection.ProjectDemandWorkUUID = _Work.ProjectDemandWorkUUID
  association [0..*] to R_ProjDmndRsceAssgmtDistr as _AssgmtDistribution     on  $projection.ProjDmndRsceAssgmtUUID = _AssgmtDistribution.ProjDmndRsceAssgmtUUID

  association [0..1] to I_UnitOfMeasure           as _RsceAssgmtQuantityUnit on  $projection.ProjDmndRsceAssgmtQuantityUnit        = _RsceAssgmtQuantityUnit.UnitOfMeasure
                                                                             and _RsceAssgmtQuantityUnit.UnitOfMeasureDimension    = 'TIME'
                                                                             and _RsceAssgmtQuantityUnit.SIUnitCnvrsnRateNumerator = 3600
  association [1..1] to I_PersonWorkAgreement_1   as _PersonWorkAgreement    on  $projection.ProjDmndRsceAssgmt = _PersonWorkAgreement.PersonWorkAgreement   
{

  key projdmndrsceassgmtuuid         as ProjDmndRsceAssgmtUUID,

      projectdemandworkuuid          as ProjectDemandWorkUUID,

      projectdemanduuid              as ProjectDemandUUID,

      @ObjectModel.foreignKey.association:    '_PersonWorkAgreement'
      projdmndrsceassgmt             as ProjDmndRsceAssgmt,

      @Semantics: { quantity : {unitOfMeasure: 'ProjDmndRsceAssgmtQuantityUnit'} }
      projdmndrsceassgmtquantity     as ProjDmndRsceAssgmtQuantity,

      @ObjectModel.foreignKey.association:    '_RsceAssgmtQuantityUnit'
      projdmndrsceassgmtquantityunit as ProjDmndRsceAssgmtQuantityUnit,
       
      //Casting to a type which annotates Change Document Relevance as false. This field is already written into Change Document in root node .

      //cast(projectuuid as tv_proj_dmnd_uuid_chg_doc preserving type ) as ProjectUUID, "commented out, please see message 2380013083

      cast(projectuuid as tv_project_uuid_chg_doc preserving type ) as ProjectUUID,    
      
      //Casting to a type which annotates Change Document Relevance as false. This field is already written into Change Document in root node .

      //cast(referencedobjectuuid as tv_proj_dmnd_uuid_chg_doc preserving type ) as ReferencedObjectUUID, "commented out, please see message 2380013083

      cast(referencedobjectuuid as tv_dmnd_ref_obj_uuid_chg_doc preserving type ) as ReferencedObjectUUID,
            
      projectdemandsupplyidentifier  as ProjectDemandSupplyIdentifier,
      projectdemandsupplydeliveryorg as ProjectDemandSupplyDeliveryOrg,
      projectdemandsourceofsupply    as ProjectDemandSourceOfSupply,
      projassgmtlastupdatesource     as ProjAssgmtLastUpdateSource,
      projdmndrsceworkassgmtoid      as ProjDmndRsceWorkAssgmtOID,
      projdmndrscewrkfrcpersonoid    as ProjDmndRsceWrkfrcPersonOID,
      projdmndrsceassgmtstartdate    as ProjDmndRsceAssgmtStartDate,
      projdmndrsceassgmtenddate      as ProjDmndRsceAssgmtEndDate,

      @Semantics.user.createdBy: true
      createdbyuser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      creationdatetime               as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      lastchangedbyuser              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime             as LastChangeDateTime,


      /* Associations */
      _Root,
      _Work,
      _AssgmtDistribution,
      _RsceAssgmtQuantityUnit,
      _PersonWorkAgreement      

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"RESOURCEASSGMT"
],
"ASSOCIATED":
[
"I_PERSONWORKAGREEMENT_1",
"I_UNITOFMEASURE",
"R_PROJDMNDRSCEASSGMTDISTR",
"R_PROJECTDEMAND",
"R_PROJECTDEMANDWORK"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More