I_PlanCostRate

@AbapCatalog.sqlViewName: 'IFIPLANCOSTRATE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Interface View for Plan Cost Rate'
@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #B,
        dataClass: #TRANSACTIONAL
    }
}
@VDM.viewType: #BASIC
define view I_PlanCostRate
  as select from P_AccountingCostRate as _Rate
    left outer to one join  I_Ledger             as _Ledger on  _Rate.Ledger            = _Ledger.Ledger
//                                                 and _Ledger.IsLeadingLedger = 'X'

  association [0..1] to I_CompanyCode            as _CompanyCode            on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Currency               as _Currency               on  $projection.Currency = _Currency.Currency
  association [0..*] to I_CostCenter             as _CostCenter             on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                            and $projection.CostCenter      = _CostCenter.CostCenter
  association [0..1] to I_CostCenter             as _CurrentCostCenter      on  $projection.ControllingArea          = _CurrentCostCenter.ControllingArea
                                                                            and $projection.CostCenter               = _CurrentCostCenter.CostCenter
                                                                            and _CurrentCostCenter.ValidityStartDate <= $session.system_date
                                                                            and _CurrentCostCenter.ValidityEndDate   >= $session.system_date
  association [0..1] to I_PlanningCategory       as _PlanningCategory       on  $projection.PlanningCategory = _PlanningCategory.PlanningCategory
  association [0..*] to I_CostCenterActivityType as _CostCtrActivityType    on  $projection.ControllingArea = _CostCtrActivityType.ControllingArea
                                                                            and $projection.ActivityType    = _CostCtrActivityType.CostCtrActivityType
  association [0..1] to I_CostCenterActivityType as _CurrentCostCtrActyType on  $projection.ControllingArea               = _CurrentCostCtrActyType.ControllingArea
                                                                            and $projection.ActivityType                  = _CurrentCostCtrActyType.CostCtrActivityType
                                                                            and _CurrentCostCtrActyType.ValidityStartDate <= $session.system_date
                                                                            and _CurrentCostCtrActyType.ValidityEndDate   >= $session.system_date
  association [0..1] to I_UnitOfMeasure          as _UnitOfMeasure          on  $projection.CostCtrActivityTypeQtyUnit = _UnitOfMeasure.UnitOfMeasure
  association [1..1] to E_AccountingCostRate     as _Extension              on  $projection.AccountingCostRateUUID = _Extension.AccountingCostRateUUID
{

  key AccountingCostRateUUID,

      _Rate.Ledger,
      CurrencyRole,
      CompanyCode,
      ControllingArea,

      CostCenter,
      ActivityType,
      PlanningCategory,

      @Semantics.fiscal.year: true
      ValidityStartFiscalYear,
      @Semantics.fiscal.period: true
      ValidityStartFiscalPeriod,
      @Semantics.fiscal.yearPeriod: true
      cast((concat( ValidityStartFiscalYear, ValidityStartFiscalPeriod )) as fins_fyearperiod)    as ValidityStartFiscalYearPeriod,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @Semantics.fiscal.year: true
      ValidityEndFiscalYear,
      @Semantics.fiscal.period: true
      ValidityEndFiscalPeriod,
      @Semantics.fiscal.yearPeriod: true
      cast((concat( ValidityEndFiscalYear, ValidityEndFiscalPeriod )) as fins_fyearperiod)        as ValidityEndFiscalYearPeriod,
      @Semantics.businessDate.to: true
      ValidityEndDate,

      @Semantics.unitOfMeasure:true
      CostCtrActivityTypeQtyUnit,
      @Semantics.currencyCode: true
      Currency,

      @Semantics.amount.currencyCode: 'Currency'
      CostRateFixedAmount,
      @Semantics.amount.currencyCode: 'Currency'
      CostRateTotalAmount,
      @Semantics.amount.currencyCode: 'Currency'
      cast(CostRateTotalAmount - CostRateFixedAmount as fco_rate_varbl_amount)                    as CostRateVarblAmount,
      CostRateScaleFactor,
      ControllingObject,
      CostObject,
      AccountingCostRateDesc,

      _CompanyCode,
      _CostCenter,
      _CurrentCostCenter,
      _CostCtrActivityType,
      _CurrentCostCtrActyType,
      _Currency,
      _UnitOfMeasure,
      _PlanningCategory
}
where CostRateIsDeleted = '' and BusinessTransactionType = 'MPCR' and PlanningCategory = 'PLN' and CurrencyRole = '00'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGER",
"P_ACCOUNTINGCOSTRATE"
],
"ASSOCIATED":
[
"E_ACCOUNTINGCOSTRATE",
"I_COMPANYCODE",
"I_COSTCENTER",
"I_COSTCENTERACTIVITYTYPE",
"I_CURRENCY",
"I_PLANNINGCATEGORY",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/