I_PT_SAFTAcctgDocCustAddrHist

@AbapCatalog.sqlViewName: 'IPTSAFTACCADRHST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@EndUserText.label: 'SAF-T PT AccountingDoc CustAddr History'
define view I_PT_SAFTAcctgDocCustAddrHist
  as select from    I_PT_AcctgDocCustAddrVers as Version

    left outer join I_CustomerCompany         as CustomerCompany        on  Version.Customer    = CustomerCompany.Customer
                                                                        and Version.CompanyCode = CustomerCompany.CompanyCode
    left outer join I_GLAccountInCompanyCode  as GLAccountInCompanyCode on  CustomerCompany.ReconciliationAccount = GLAccountInCompanyCode.GLAccount
                                                                        and CustomerCompany.CompanyCode           = GLAccountInCompanyCode.CompanyCode

    inner join      I_PT_SAFTCustAddrHist     as History                on  Version.Customer                  = History.Customer
                                                                        and Version.PortugueseCustomerVersion = History.PortugueseCustomerVersion
{
  key Version.CompanyCode                                                               as CompanyCode,
  key Version.FiscalYear                                                                as FiscalYear,
  key Version.AccountingDocument                                                        as AccountingDocument,
  key Version.Customer                                                                  as Customer,

      cast(
      concat(Version.Customer,concat('_',Version.PortugueseCustomerVersion))
      as sipt_kunnr_with_version)                                                       as PortugueseCustomerWithVersion,

      cast(
      case
      when GLAccountInCompanyCode.AlternativeGLAccount is not initial
      then GLAccountInCompanyCode.AlternativeGLAccount
      when CustomerCompany.ReconciliationAccount is not initial
      then CustomerCompany.ReconciliationAccount
      else ''
      end as akont)                                                                     as ReconciliationAccount,

      History.CustomerVATRegistration                                                   as CustomerVATRegistration,

      History.CompanyName                                                               as CompanyName,

      cast(
      concat_with_space(History.PartnerFirstName,History.PartnerLastName,1)
      as saft_pt_contact_name)                                                          as ContactPersonName,

      History.CustomerSupplierAddress                                                   as CustomerSupplierAddress,

      History.CityName                                                                  as CityName,

      History.PostalCode                                                                as PostalCode,

      History.Country                                                                   as Country,

      History.PhoneNumber                                                               as PhoneNumber,

      History.FaxNumber                                                                 as FaxNumber,

      History.EmailAddress                                                              as EmailAddress,
      
      History.SearchURLAddress                                                          as SearchURLAddress,
      
      /* Associations */
      //FOR DPP AUTHORIZATION CHECK

      Version._Customer

};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERCOMPANY",
"I_GLACCOUNTINCOMPANYCODE",
"I_PT_ACCTGDOCCUSTADDRVERS",
"I_PT_SAFTCUSTADDRHIST"
],
"ASSOCIATED":
[
"I_CUSTOMER"
],
"BASE":
[
"I_PT_ACCTGDOCCUSTADDRVERS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/