I_PT_ACCTGDOCCUSTADDRVERS

CDS View

PT AccountingDoc CustAddr Version

I_PT_ACCTGDOCCUSTADDRVERS is a CDS View in S/4HANA. PT AccountingDoc CustAddr Version. It contains 5 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 5 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_PT_SAFTAcctgDocCustAddrHist view from COMPOSITE SAF-T PT AccountingDoc CustAddr History

Fields (5)

KeyField CDS FieldsUsed in Views
KEY AccountingDocument AccountingDocument 1
KEY CompanyCode CompanyCode 1
KEY Customer Customer 1
KEY FiscalYear FiscalYear 1
_Customer _Customer 1 
@AbapCatalog.sqlViewName: 'IPTACCADRVERS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('BLOCKED_DATA_INCLUDED')
@EndUserText.label: 'PT AccountingDoc CustAddr Version'
define view I_PT_AcctgDocCustAddrVers
  as select from I_PT_AcctgDocDgtlSgntr      as Signature

    inner join   I_OperationalAcctgDocItem   as OperationalAcctgDocItem on  Signature.CompanyCode        = OperationalAcctgDocItem.CompanyCode
                                                                        and Signature.FiscalYear         = OperationalAcctgDocItem.FiscalYear
                                                                        and Signature.AccountingDocument = OperationalAcctgDocItem.AccountingDocument

    inner join   I_PT_CustomerAddressVersion as Version                 on OperationalAcctgDocItem.Customer              =  Version.Customer
                                                                        and(
                                                                          Signature.PortugueseDigitalSignatureDate       >  Version.PortugueseDigitalSignatureDate
                                                                          or(
                                                                            Signature.PortugueseDigitalSignatureDate     =  Version.PortugueseDigitalSignatureDate
                                                                            and Signature.PortugueseDigitalSignatureTime >= Version.PortugueseDigitalSignatureTime
                                                                          )
                                                                        )
{
  key OperationalAcctgDocItem.CompanyCode                                                              as CompanyCode,
  key OperationalAcctgDocItem.FiscalYear                                                               as FiscalYear,
  key OperationalAcctgDocItem.AccountingDocument                                                       as AccountingDocument,
  key OperationalAcctgDocItem.Customer                                                                 as Customer,

      cast(max(PortugueseCustomerVersion) as sipt_data_version)                                        as PortugueseCustomerVersion,

      /* Associations */
      //FOR DPP AUTHORIZATION CHECK      

      OperationalAcctgDocItem._Customer
}
group by
  OperationalAcctgDocItem.CompanyCode,
  OperationalAcctgDocItem.FiscalYear,
  OperationalAcctgDocItem.AccountingDocument,
  OperationalAcctgDocItem.Customer;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OPERATIONALACCTGDOCITEM",
"I_PT_ACCTGDOCDGTLSGNTR",
"I_PT_CUSTOMERADDRESSVERSION"
],
"ASSOCIATED":
[
"I_CUSTOMER"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More