I_NetworkActivity

@EndUserText.label: 'Network Activity Details'
@VDM.viewType: #BASIC
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@AccessControl.privilegedAssociations: ['_MRPController'] //, '_Extension']

@AbapCatalog.sqlViewName: 'INETWORKACTIVITY'
@AbapCatalog.preserveKey: true
@ObjectModel.representativeKey: 'NetworkActivity'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
define view I_NetworkActivity
  as select from    afvc
    left outer join afvv               on  afvc.aufpl = afvv.aufpl
                                       and afvc.aplzl = afvv.aplzl
    left outer join afvu               on  afvc.aufpl = afvu.aufpl
                                       and afvc.aplzl = afvu.aplzl
    left outer join afvc as SuperiorNA on  afvc.sumnr = SuperiorNA.aplzl
                                       and afvc.aufpl = SuperiorNA.aufpl
    left outer join afko               on afvc.aufpl = afko.aufpl
    inner join      aufk               on  afko.aufnr = aufk.aufnr
                                       and aufk.autyp = '20'
    inner join      t430               on t430.steus = afvc.steus
  association [0..1] to I_ProjectNetwork          as _ProjectNetwork                on  $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork
  association [0..1] to I_Project                 as _Project                       on  afko.pronr = _Project.ProjectInternalID
  association [1..1] to I_WBSElement              as _WBSElement                    on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..*] to I_ProfitCenter            as _ProfitCenter                  on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                    and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [0..1] to I_OperationControlProfile as _ControlProfile                on  $projection.NetworkActivityControlProfile = _ControlProfile.OperationControlProfile
  // I_OperationControlProfile doesnot need BillOfOperationsApplication.            and _ControlProfile.BillOfOperationsApplication != ''

  association [0..1] to I_WorkCenter              as _WorkCenter                    on  afvc.arbid = _WorkCenter.WorkCenterInternalID
                                                                                    and _WorkCenter.WorkCenterTypeCode != ''
  association [0..1] to I_MRPController           as _MRPController                 on  $projection.Plant = _MRPController.Plant
                                                                                    and afko.dispo        = _MRPController.MRPController
  association [0..1] to I_Plant                   as _Plant                         on  afvc.werks = _Plant.Plant
  association [0..1] to I_Supplier                as _Supplier                      on  afvc.lifnr = _Supplier.Supplier
  //  association [0..1] to I_CostElement             as _CostElement                   on  $projection.CostElement     = _CostElement.CostElement

  //                                                                                    and $projection.ControllingArea = _CostElement.ControllingArea

  association [0..1] to I_PurchasingOrganization  as _PurchasingOrganization        on  afvc.ekorg = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_PurchasingGroup         as _PurchasingGroup               on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_MaterialGroup           as _MaterialGroup                 on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_CompanyCode             as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea         as _ControllingArea               on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..*] to I_CostCenterActivityType  as _CostCenterActivityType        on  $projection.ControllingArea     = _CostCenterActivityType.ControllingArea
                                                                                    and $projection.CostCtrActivityType = _CostCenterActivityType.CostCtrActivityType
  association [0..1] to I_TaxJurisdiction         as _TaxJurisdiction               on  $projection.TaxJurisdiction              = _TaxJurisdiction.TaxJurisdiction
                                                                                    and $projection.TaxJurisdictionCalcProcedure = _TaxJurisdiction.TaxJurisdictionCalcProcedure
  association [0..1] to I_ControllingObjectClass  as _ControllingObjectClass        on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [0..1] to I_FunctionalArea          as _FunctionalArea                on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_BusinessArea            as _BusinessArea                  on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_StatusObjectStatusBasic as _ActivityConfirmed             on  $projection.NetworkActivityObject = _ActivityConfirmed.StatusObject
                                                                                    and _ActivityConfirmed.StatusCode     = 'I0009'
  association [0..1] to I_StatusObjectStatusBasic as _ActivityPartiallyConfirmed    on  $projection.NetworkActivityObject      = _ActivityPartiallyConfirmed.StatusObject
                                                                                    and _ActivityPartiallyConfirmed.StatusCode = 'I0010'
  association [0..1] to I_UnitOfMeasure           as _NetworkActivityQuantityUnit   on  $projection.NetworkActivityQuantityUnit = _NetworkActivityQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _StandardDurationUnit          on  $projection.StandardDurationUnit = _StandardDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _NtwkActivityWorkQuantityUnit  on  $projection.NtwkActivityWorkQuantityUnit = _NtwkActivityWorkQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _FcstdStandardDurationUnit     on  $projection.FcstdStandardDurationUnit = _FcstdStandardDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _ForecastedMinimumDurationUnit on  $projection.ForecastedMinimumDurationUnit = _ForecastedMinimumDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _StartDateOffsetDurationUnit   on  $projection.StartDateOffsetDurationUnit = _StartDateOffsetDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _EndDateOffsetDurationUnit     on  $projection.EndDateOffsetDurationUnit = _EndDateOffsetDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure           as _ActivityConfFcstdDurationUnit on  $projection.ActivityConfFcstdDurationUnit = _ActivityConfFcstdDurationUnit.UnitOfMeasure
  association [1..1] to E_NetworkActivity         as _Extension                     on  afvc.aufpl = _Extension.ProjectNetworkInternalID
                                                                                    and afvc.aplzl = _Extension.NetworkActivityInternalID
  // Multilanguage Short text

  association [0..1] to I_ProjectObjectShortText  as _ActivityShortText             on  _ActivityShortText.Language   = $session.system_language
                                                                                    and _ActivityShortText.ProjectApplicationIdentifier = 'PS'
                                                                                    and _ActivityShortText.ProjectObjectType = 'NV'
                                                                                    and $projection.NetworkActivityObject = _ActivityShortText.ProjectObjectNode
  // DPP Changes - To Use I_Project association in DCL

  //  association [0..1] to I_Project                 as _Project                    on  $projection.ProjectInternalID = _Project.ProjectInternalID


{
      // semantics to be checked and added

      // cast / gtc / logic

      @ObjectModel.foreignKey.association: '_ProjectNetwork'
  key cast ( afko.aufnr as ps_s4_aufnr )                                                                                as  ProjectNetwork, //Network ID - cast

      @ObjectModel.text.element: 'NetworkActivityDescription'
  key cast ( afvc.vornr as pt_vornr_receiver )                                                                          as  NetworkActivity, //Activity ID


      cast ( afvc.ltxa1 as ps_s4_ltxa1 )                                                                                as  NetworkActivityDescription, //Activity description

      //Fields applicable to Version

      //Version group


      cast ( SuperiorNA.vornr as cats_elemt )                                                                           as  SuperiorNtwkActivityExternalID, //Element

      case when afvc.projn = '00000000'
      then
       _Project.Project
      else
      _WBSElement._Project.Project end                                                                                  as  Project, //Project ID


      case when afvc.projn = '00000000'
      then
      _Project.ProjectWithCodingMask
      else
      _WBSElement._Project.ProjectWithCodingMask end                                                                    as  ProjectWithCodingMask, //Project ID


      case when afvc.projn = '00000000'
      then
      _Project.ProjectDescription
      else
      _WBSElement._Project.ProjectDescription end                                                                       as  ProjectDescription, //Project Description

      @ObjectModel.foreignKey.association: '_ProfitCenter'
      cast ( afvc.prctr as prctr )                                                                                      as  ProfitCenter, // Profit Center

      //cast ( _ProfitCenter._Text.ProfitCenterName as fis_mcpct ) as ProfitCenterName, //Profit center name

      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSElement      end                                                                                   as  WBSElement, //WBS element


      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSElementWithCodingMask      end                                                                     as  WBSElementWithCodingMask, //WBS element


      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSDescription       end                                                                              as  WBSDescription, //WBS element name

      @ObjectModel.foreignKey.association: '_ControlProfile'
      cast ( afvc.steus as qsteus )                                                                                     as  NetworkActivityControlProfile, //Control key

      //cast ( _ControlProfile._Text.OperationControlProfileName as PS_S4_PPH_STEUTXT ) as OperationControlProfileName, //Control key text

      //@ObjectModel.foreignKey.association: '_WorkCenter'

      cast ( _WorkCenter.WorkCenter as pph_arbpl )                                                                      as  WorkCenter, //Work center

      //cast ( _WorkCenter._Text.WorkCenterText as PS_S4_WORKCENTERTEXT ) as WorkCenterText //work center name

      cast ( afvc.loekz as ps_s4_loevm )                                                                                as  IsMarkedForDeletion, //Deletion Indicator

      //@ObjectModel.foreignKey.association: '_Plant'

      _Plant.Plant                                                                                                      as  Plant, // Plant

      _Plant.PlantName                                                                                                  as  PlantName, // Plant Name

      //System Status

      //User Status

      cast ( afvc.rstra as cp_rstra )                                                                                   as  LeadTimeReductionStrategy, //Reduction strategy

      //@ObjectModel.foreignKey.association: '_Supplier'

      afvc.lifnr                                                                                                        as  Supplier, // Supplier

      _Supplier.BPSupplierName                                                                                          as  SupplierName, //supplier name

    //  @OData.v2.amount.noDecimalShift: true

      cast ( afvc.peinh as mlpeinh )                                                                                    as  NetworkActivityPriceBaseQty, // Price unit

      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      cast ( afvc.preis as preis )                                                                                      as  ExternalProcessingPrice, // Price

      //  @ObjectModel.foreignKey.association: '_CostElement'

      cast ( afvc.sakto as kstar )                                                                                      as  CostElement, //Cost element

      @Semantics.currencyCode: true
      cast ( afvc.waers as waers )                                                                                      as  NetworkActivityCurrency, // Currency


      cast ( afvc.infnr as ps_s4_pph_infnr )                                                                            as  PurchasingInfoRecord, // Info Record

      //@ObjectModel.foreignKey.association: '_PurchasingOrganization'

      cast ( afvc.ekorg as ps_s4_ekorg )                                                                                as  PurchasingOrganization, // Purchasing Organization

      cast ( _PurchasingOrganization.PurchasingOrganizationName as ps_s4_mm_a_purg_org_name )                           as  PurchasingOrganizationName, //Purchasing Organization Desc

      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      afvc.ekgrp                                                                                                        as  PurchasingGroup, // Purchasing Group

      @EndUserText.label: 'Purchasing Group Description'
      _PurchasingGroup.PurchasingGroupName                                                                              as  PurchasingGroupName, //Purchasing group Desc

      @ObjectModel.foreignKey.association: '_MaterialGroup'
      cast ( afvc.matkl as matkl )                                                                                      as  MaterialGroup, // Material group

      //Material group text

      cast ( afvc.ddehn as ps_s4_daudehn )                                                                              as  StandardDurationIsFlexible, // as daudehn )  // Flexible duration

      @ObjectModel.foreignKey.association: '_CompanyCode'
      afvc.bukrs                                                                                                        as  CompanyCode, // Company Code

      @EndUserText.label: 'Company Code Name'
      _CompanyCode.CompanyCodeName                                                                                      as  CompanyCodeName, // Company Code Name - cast not possible

      @ObjectModel.foreignKey.association: '_ControllingArea'
      aufk.kokrs                                                                                                        as  ControllingArea, //Controlling area

      //@EndUserText.label: 'Controlling Area Name'

      //_ControllingArea.ControllingAreaName                                                            as  ControllingAreaName, // Controlling Area Name - cast not possible

      cast ( afvc.indet as indet )                                                                                      as  OperationCalculationControl, //Calculation key

      @ObjectModel.foreignKey.association: '_CostCenterActivityType'
      cast ( afvc.larnt as lstar )                                                                                      as  CostCtrActivityType, // Activity type

      //activity type name

      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      cast ( afvc.prkst as prkst )                                                                                      as  NetworkActivityCost, // Amount

      cast ( afvc.banfn as ps_s4_banfn )                                                                                as  PurchaseRequisition, //Purchase requisition

      cast ( afvc.bnfpo as ps_s4_bnfpo )                                                                                as  PurchaseRequisitionItem, //Requisition item

      cast ( afvc.kalid as appca )                                                                                      as  FactoryCalendar, //Calendar

      cast ( afvc.vertl as ps_s4_cr_vertn)                                                                              as  CapacityRequirementDistrKey, // as cr_vertn ) as DKey: netwk cap req.

      cast ( afvc.pprio as prioritaet )                                                                                 as  NetworkActivityPriority, //Priority

      cast (afvc.txjcd as ps_s4_txjcd )                                                                                 as  TaxJurisdiction, // Jurisdiction code

      //Jurisdiction code description

      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      cast ( afvc.scope as ps_s4_scope_cv )                                                                             as  ControllingObjectClass, //Object class

      //Object class name

      @ObjectModel.foreignKey.association: '_BusinessArea'
      cast ( afvc.gsber as gsber )                                                                                      as  BusinessArea, //Business area

      //business area name

      cast ( afvc.evgew as ev_weightd )                                                                                 as  ProgressAnlysAggregationWeight, //POC weight

      @Semantics.currencyCode: true
      cast ( afvc.owaer as owaer )                                                                                      as  NetworkActivityObjectCurrency, //Object currency

      cast ( afvc.afnam as afnam )                                                                                      as  RequisitionerUser, //Requisitioner


      cast ( afvc.kzfix as ps_s4_cn_kzfix )                                                                             as  PurgInfoRecdDataIsFixed, //Price_is_fixed


      @Semantics.unitOfMeasure: true
      cast ( afvv.meinh as ps_s4_vorme )                                                                                as  NetworkActivityQuantityUnit, //Unit Of Measure For Activity

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NetworkActivityQuantityUnit'
      cast ( afvv.mgvrg as ps_s4_mgvrg )                                                                                as  ActivityQuantity, //Activity quantity

      cast ( afvv.plifz as ps_s4_plifz )                                                                                as  PlannedDeliveryDurationInDays, //Planned delivery time

      @Semantics.unitOfMeasure: true
      cast ( afvv.daune as ps_s4_daunore )                                                                              as  StandardDurationUnit, //Normal duration/unit

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'StandardDurationUnit'
      cast ( afvv.dauno as ps_s4_daunor )                                                                               as  StandardDuration, //Normal duration

      @Semantics.quantity.unitOfMeasure: 'MinimumDurationUnit'
      cast ( afvv.daumi as ps_s4_daumin )                                                                               as  MinimumDuration, //Min. duration

      @Semantics.unitOfMeasure: true
      cast ( afvv.daume as ps_s4_daumine )                                                                              as  MinimumDurationUnit, //Minimum duration unit

      cast ( afvv.einsa as ps_s4_einschra )                                                                             as  ActyBscStartDateConstraintType, // Start constraint (B)

      cast ( afvv.einse as ps_s4_einschre )                                                                             as  ActyBscEndDateConstraintType, //Finish constraint(B)

      @Semantics.unitOfMeasure: true
      cast ( afvv.arbeh as iwein )                                                                                      as  NtwkActivityWorkQuantityUnit, //Unit for work

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      round ( cast ( afvv.arbei as ps_s4_arbeit ),2)                                                                    as  PlannedWorkQuantity, // Work

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      round ( cast ( afvv.ismnw as co_ismnw ),2)                                                                        as  ActualWorkQuantity, // Actual Work


      @Semantics.businessDate.from
      cast ( afvv.fsavd as ps_gstrs )                                                                                   as  SchedldBasicEarliestStartDate, //Earliest start date (basic)

      @Semantics.businessDate.to
      cast ( afvv.fsedd as ps_getre )                                                                                   as  SchedldBasicEarliestEndDate, // Earliest finish date (basic)

      @Semantics.businessDate.from
      cast ( afvv.ssavd as ps_gstre )                                                                                   as  SchedldBasicLatestStartDate, //Latest start date (basic)

      @Semantics.businessDate.to
      cast ( afvv.ssedd as ps_s4_gltrs )                                                                                as  ScheduledBasicLatestEndDate, // Latest finish date (basic)

      @Semantics.businessDate.from
      cast ( afvv.isdd as ps_s4_istrt )                                                                                 as  ActualStartDate, //Actual start date

      @Semantics.businessDate.to
      cast ( afvv.iedd as ps_s4_iende )                                                                                 as  ActualEndDate, // Actual finish date

      @Semantics.businessDate.from
      cast ( afvv.ewstd as ps_s4_ewstd )                                                                                as  ForecastedStartDate, // Forecast start date

      @Semantics.businessDate.to
      cast ( afvv.ewend as ps_s4_ewend )                                                                                as  ForecastedEndDate, // Forecast finish date

      @Semantics.businessDate.from
      cast ( afvv.ntanf as ps_s4_ntanf )                                                                                as  ConstraintDateForBscStartDate, // Basic start date - cast

      @Semantics.businessDate.to
      cast ( afvv.ntend as ps_s4_ntend )                                                                                as  ConstraintDateForBscEndDate, //Basic finish date - cast

      @Semantics.businessDate.from
      cast ( afvv.fpavd as ps_s4_gstpp )                                                                                as  SchedldFcstdEarliestStartDate, // Erl. start date (F)

      @Semantics.businessDate.to
      cast ( afvv.fpedd as ps_s4_gltrp )                                                                                as  SchedldFcstdEarliestEndDate, //Erl Finish Date (F)

      @Semantics.businessDate.from
      cast ( afvv.spavd as ps_s4_gstrp )                                                                                as  LatestSchedldFcstdStartDate, // Latest start date(F)

      @Semantics.businessDate.to
      cast ( afvv.spedd as ps_s4_gltpp )                                                                                as  LatestSchedldFcstdEndDate, // Latest Forecast Finish Date

      @Semantics.businessDate.to
      cast ( afvv.pedd as ps_s4_co_pedd )                                                                               as  ActyConfFcstdEndDate, //Confirm. fin.-fcst


      cast ( afvv.puffr as puffr_frei )                                                                                 as  BasicDatesFreeFloat, //Free float

      cast ( afvv.pufgs as puffr_gesm )                                                                                 as  TotalFloatForBasicDates, //Total float

      cast ( afvv.pufgp as ps_s4_ppuff_gesm )                                                                           as  TotalFloatForForecastedDates, //Total float (frcst)

      cast ( afvv.puffp as ps_s4_ppuff_frei )                                                                           as  ForecastedDatesFreeFloat, // Free float (forecast)


      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'FcstdStandardDurationUnit'
      cast ( afvv.ewdan as ps_s4_ewdan )                                                                                as  ForecastedStandardDuration, //Forecast normal dur.

      @Semantics.unitOfMeasure: true
      cast ( afvv.ewdne as ps_s4_ewdne )                                                                                as  FcstdStandardDurationUnit, // Un./norm. dur. fcst

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ForecastedMinimumDurationUnit'
      cast ( afvv.ewdam as ps_s4_ewdam )                                                                                as  ForecastedMinimumDuration, //Min duration (frcst)

      @Semantics.unitOfMeasure: true
      cast ( afvv.ewdme as ps_s4_ewdme )                                                                                as  ForecastedMinimumDurationUnit, //Min. duration unit


      cast ( afvv.ewste as ps_s4_ps_reste )                                                                             as  ActyFcstEndDateConstraintType, // Constraint on finish (F)

      cast ( afvv.ewsta as ps_s4_ps_resta )                                                                             as  ActyFcstStartDteConstraintType, // Start constraint (F)

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      cast ( afvv.ofmnw as ofmnw )                                                                                      as  ForecastedWorkQty, // Forecast work

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      cast ( afvv.offstb as cp_ooffstb )                                                                                as  StartDateOffsetDuration, // Time interval start

      @Semantics.unitOfMeasure: true
      cast ( afvv.ehoffb as ps_s4_cp_oehoffb )                                                                          as  StartDateOffsetDurationUnit, // Unit

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      cast ( afvv.offste as cp_ooffste )                                                                                as  EndDateOffsetDuration, //Time interval to finish

      @Semantics.unitOfMeasure: true
      cast ( afvv.ehoffe as ps_s4_cp_oehoffe )                                                                          as  EndDateOffsetDurationUnit, //Unit

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'ActivityConfFcstdDurationUnit'
      cast ( afvv.pdau as ps_s4_pdau )                                                                                  as  ActivityConfFcstdDuration, //Fcst.duration-conf.

      @Semantics.unitOfMeasure: true
      cast ( afvv.pdae as ps_s4_pdae )                                                                                  as  ActivityConfFcstdDurationUnit, //Un. forecast duratn


      @ObjectModel.foreignKey.association: '_FunctionalArea'
      cast ( afvc.func_area as fkber )                                                                                  as  FunctionalArea, //Functional Area

      //functional area name


      // Fields added for association

      afvc.kalsm                                                                                                        as  TaxJurisdictionCalcProcedure,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      round ( cast( ( afvv.ismnw - afvv.ofmnw ) as remnw_2 ),2)                                                         as  RemainingWorkQuantity, //final confirmation awaited from Mario


      // Fields added for other views to be used - can be removed later if not used

      cast ( afvc.projn as ps_s4_pspnr preserving type )                                                                as  WBSElementInternalID,
      case when afvc.projn = '00000000'
      then
      _Project.ProjectObject
      else
      _WBSElement._Project.ProjectObject     end                                                                        as  ProjectObject,
      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.WBSElementObject      end                                                                             as  WBSElementObject,
      afvc.objnr                                                                                                        as  NetworkActivityObject,
      afvc.aufpl                                                                                                        as  ProjectNetworkInternalID,
      afvc.aplzl                                                                                                        as  NetworkActivityInternalID,
      case when afvc.projn = '00000000'
      then
      _Project.ProjectInternalID
      else
      _WBSElement.ProjectInternalID         end                                                                         as  ProjectInternalID,
      @EndUserText.label: 'Is External Activity'
      case when t430.lief = '+' then
        'X'
      else
        ''
      end                                                                                                               as  IsExternalActivity,
      @EndUserText.label: 'Activity Is Account Assigned'
      case when afvc.netzkont = '2' then
        'X'
      else
        ' '
      end                                                                                                               as  ActivityIsAccountAssigned,
      @EndUserText.label: 'Is Service Activity'
      case when
        t430.pkost = '' and t430.lief = '+'
        and t430.service = 'X'
        and   afvc.sumnr
          = '00000000'
      then
        'X'
      else
        ' '
      end                                                                                                               as  IsServiceActivity,
      @EndUserText.label: 'Is Internal Activity'
      case when
        t430.pkost = '' and t430.lief = ''
        and t430.service = ''
        and   afvc.sumnr
          = '00000000'
      then
        'X'
      else ' '
      end                                                                                                               as  IsInternalActivity,
      @EndUserText.label: 'Object Is Confirmed'
      case when
        _ActivityConfirmed.StatusIsInactive = ' '
      then
        'X'
      else ' '
      end                                                                                                               as  ObjectIsConfirmed,
      @EndUserText.label: 'Object Is Partially Confirmed'
      case when
        _ActivityPartiallyConfirmed.StatusIsInactive = ' '
      then
        'X'
      else ' '
      end                                                                                                               as  ObjectIsPartiallyConfirmed,
      afvc.ltxa2                                                                                                        as  NetworkActivityDescription2,

      afvv.ssedz                                                                                                        as  SchedldBasicLatestEndTime,
      afvv.ssavz                                                                                                        as  SchedldBasicLatestStartTime,
      afvv.spedz                                                                                                        as  SchedldFcstdLatestEndTime,
      afvv.spavz                                                                                                        as  SchedldFcstdLatestStartTime,
      afvv.fsedz                                                                                                        as  SchedldBasicEarliestEndTime,
      afvv.fsavz                                                                                                        as  SchedldBasicEarliestStartTime,
      afvv.fpedz                                                                                                        as  SchedldFcstdEarliestEndTime,
      afvv.fpavz                                                                                                        as  SchedldFcstdEarliestStartTime,
      afvv.pedz                                                                                                         as  ActyConfFcstdEndTime,
      afvv.ntenz                                                                                                        as  ConstraintTimeForBasicEndTime,
      afvv.ntanz                                                                                                        as  ConstraintTimeForBscStartTime,
      afvv.isdz                                                                                                         as  ActualExecutionStartTime,
      afvv.iedz                                                                                                         as  ActualExecutionEndTime,
      afvv.ewstz                                                                                                        as  ForecastedStartTime,
      afvv.ewenz                                                                                                        as  ForecastedEndTime,
      afvv.epenz                                                                                                        as  DispatchedEndTime,
      afvv.epend                                                                                                        as  DispatchedEndDate,
      afvv.epanz                                                                                                        as  DispatchedStartTime,
      afvv.epanf                                                                                                        as  DispatchedStartDate,

      afvu.vname                                                                                                        as  JointVenture,
      afvu.jv_jibsa                                                                                                     as  JointVentureSubClass,
      afvu.jv_jibcl                                                                                                     as  JointVentureClass,
      afvu.jv_otype                                                                                                     as  JointVentureObjectType,
      afvu.jv_oco                                                                                                       as  JntVentureOriglCostObjectType,
      afvu.usr11                                                                                                        as  FreeDefinedIndicator2,
      afvu.usr10                                                                                                        as  FreeDefinedIndicator1,
      afvu.usr09                                                                                                        as  FreeDefinedDate2,
      afvu.usr08                                                                                                        as  FreeDefinedDate1,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      afvu.usr07                                                                                                        as  FreeDefinedAmount2,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      afvu.usr06                                                                                                        as  FreeDefinedAmount1,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      afvu.usr05                                                                                                        as  FreeDefinedQuantity2,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      afvu.usr04                                                                                                        as  FreeDefinedQuantity1,
      afvu.usr03                                                                                                        as  FreeDefinedAttribute04,
      afvu.usr02                                                                                                        as  FreeDefinedAttribute03,
      afvu.usr01                                                                                                        as  FreeDefinedAttribute02,
      afvu.usr00                                                                                                        as  FreeDefinedAttribute01,
      @Semantics.currencyCode: true
      afvu.use06                                                                                                        as  FreeDefinedAmount1Currency,
      @Semantics.currencyCode: true
      afvu.use07                                                                                                        as  FreeDefinedAmount2Currency,
      @Semantics.unitOfMeasure: true
      afvu.use05                                                                                                        as  FreeDefinedQuantity2Unit,
      @Semantics.unitOfMeasure: true
      afvu.use04                                                                                                        as  FreeDefinedQuantity1Unit,

      afvc.wkurs                                                                                                        as  ExchangeRate,
      afvc.wempf                                                                                                        as  GoodsRecipientName,
      afvc.sumnr                                                                                                        as  SuperiorNtwkActivityInternalID,
      afvc.rueck                                                                                                        as  NetworkActivityConfirmation,
      afvc.rmzhl                                                                                                        as  NtwkActyConfirmationCount,
      afvc.qualf                                                                                                        as  EmployeeSuitability,
      afvc.nptxtky                                                                                                      as  ProjectTextInternalID,
      afvc.nprio                                                                                                        as  OperationImportance,
      afvc.no_disp                                                                                                      as  NtwkActyIsRelevantForMatlPlng,
      afvc.netzkont                                                                                                     as  NtwkAccountAssignmentCode,
      afvc.loart                                                                                                        as  EmployeeWageType,
      afvc.ktsch                                                                                                        as  StandardTextInternalID,
      afvc.ebelp                                                                                                        as  PurchasingDocumentItem,
      afvc.ebeln                                                                                                        as  PurchasingDocument,
      afvc.clasf                                                                                                        as  ActyIsTakenAcctForProjSmmry,
      afvc.anzzl                                                                                                        as  NumberOfCapacities,
      afvc.anzma                                                                                                        as  NumberOfEmployees,
      afvc.anfko                                                                                                        as  PartnerCostCenter,
      afvc.ablad                                                                                                        as  UnloadingPointName,
      afvc.mlstn                                                                                                        as  UsageCode,
      afvc.txtsp                                                                                                        as  Language,
      afvc.arbid                                                                                                        as  WorkCenterInternalID,
      t430.pkost                                                                                                        as  IsCostActivity,
      afvc.sortl                                                                                                        as  PurchasingInfoRecdAddlGrpgName,
      afko.dispo                                                                                                        as  MRPController,

      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.RespCostCenterControllingArea end                                                                     as  RespCostCenterControllingArea,
      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.ResponsibleCostCenter end                                                                             as  ResponsibleCostCenter,
      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.RequestingCostCenter end                                                                              as  RequestingCostCenter,
      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.ReqgCostCenterControllingArea end                                                                     as  ReqgCostCenterControllingArea,
      case when afvc.projn = '00000000'
      then
      0
      else
      _WBSElement.WBSElementHierarchyLevel end                                                                          as  WBSElementHierarchyLevel,
      case when afvc.projn = '00000000'
      then
      ''
      else
      _WBSElement.ProjectType end                                                                                       as  ProjectType,

      @EndUserText.label: 'Network Activity Category'
      case when
        (
            t430.lief = '+'
      // or  IsExternalActivity = '+'

          or  ( t430.pkost = '' and t430.lief = '+' and t430.service = 'X'
        and   afvc.sumnr
          = '00000000' )
        )
      then
        'E'
      else
        case when t430.pkost = 'X' then
          'C'
        else
          case when t430.lief = '+' then
              'W'
            else
              ''
            end
        end
      end                                                                                                               as  NetworkActivityCategory,
      afvu.slwid  as  FreeDefinedTableFieldSemantic,



      _ProjectNetwork,
      _WBSElement,
      _ProfitCenter,
      _ControlProfile,
      _WorkCenter,
      _MRPController,
      //      _CostElement,

      _MaterialGroup,
      _CompanyCode,
      _ControllingArea,
      _CostCenterActivityType,
      _TaxJurisdiction,
      _ControllingObjectClass,
      _FunctionalArea,
      _BusinessArea,
      _PurchasingGroup,
      _NetworkActivityQuantityUnit,
      _StandardDurationUnit,
      _NtwkActivityWorkQuantityUnit,
      _FcstdStandardDurationUnit,
      _ForecastedMinimumDurationUnit,
      _StartDateOffsetDurationUnit,
      _EndDateOffsetDurationUnit,
      _ActivityConfFcstdDurationUnit,
      _Supplier,
      _ActivityShortText

      // Changes for DPP

      //      @UI.hidden: true

      //      @Consumption.hidden: true

      ////    Added to use _Project Association. Don't use this field

      //      afko.pronr as OldProjectObject,


      //      @UI.hidden: true

      //      @Consumption.hidden: true

      //      _Project




      //Fields applicable to Version

      //Project Version

      //Project Version Description

      //Project Version Group



      //Days due

      //Days overdue


      //Recipient - Determine which field in CN47N

      //cast ( afvv.beaze as beaze ) as OpPlannedProcessingDurnUnit, // Edit unit - cast

      //afvv.beazp, //Processing time unit (F) - cast / gtc

      //Processing time Forecast - cast / gtc / logic - derived from bearp- use rounding

      //Processing time - cast / gtc / logic - derived from bearz - use rounding

      //Quantity received - logic

      //Order unit - cast / logic

      //Purchase ord. exists

      //Actual duration

      //Unit for actual dur.

      //Remaining duration

      //Unit for remain. dur

      //Remaining work

      //Unit for work

      //Processing %

      //Processing % of work


      //Earlier - Deprecate ??

      //Later - Deprecate ??


      /* - Unable to find
      Created by
      Created on
      Changed by
      Last Changed On
      */

};