I_MfgOrderOperationBySemKey

@AbapCatalog.sqlViewName: 'IMFGORDOPBYSEMK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'ManufacturingOrderOperation'
@ObjectModel.semanticKey: ['ManufacturingOrder', 'ManufacturingOrderSequence', 'ManufacturingOrderOperation']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Operation By Semantic Key'
// To be used mainly for foreign key purposes using the semantic key of order operations

// Successor view of I_MfgOrderOperationBySemanKey using representative key w/o conversion exit


/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_MfgOrderOperationBySemKey
  as select from I_MfgOrderOperationBasic as afvc

  association [1..1] to I_ManufacturingOrder         as _MfgOrder          on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_ManufacturingOrderSequence as _MfgOrderSequence  on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                           and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [1..1] to I_Plant                      as _ProductionPlant   on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [1..1] to I_OrderInternalID            as _OrderInternalID   on  $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [0..1] to I_Language                   as _LongTextLanguage  on  $projection.LongTextLanguage = _LongTextLanguage.Language
{
      // Key

      @ObjectModel.foreignKey.association: '_MfgOrder'
  key afvc.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
  key afvc.ManufacturingOrderSequence,
      @ObjectModel.text.element: ['MfgOrderOperationText']
  key afvc.ManufacturingOrderOperation_2 as ManufacturingOrderOperation,

      // SubOp/Phase

      @Semantics.booleanIndicator
      afvc.OperationIsSubOperation,
      afvc.MfgOrderOperationIsPhase,
 
      // Order header data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      afvc.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      afvc.ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      afvc.ProductionPlant,

      // Text

      @Semantics.text: true
      cast(afvc.MfgOrderOperationText as mfgorderoperationtext preserving type) as MfgOrderOperationText,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      afvc.Language                                                             as LongTextLanguage,
      cast(case 
             when afvc.Language <> '' then 'X'
             else afvc.Language
      end as aufltext preserving type) as OperationHasLongText,

      // Technical Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
      afvc.OrderInternalBillOfOperations as OrderInternalID,
      afvc.OrderIntBillOfOperationsItem  as OrderOperationInternalID,
      
      // Confirmation

      @ObjectModel.foreignKey.association: '_ConfirmationGroup'      
      afvc.OperationConfirmation,
      afvc.NumberOfOperationConfirmations,
      
      // Associations

      _MfgOrder,
      _MfgOrderSequence,
      _MfgOrderCategory,
      _MfgOrderType,
      _ProductionPlant,
      _OrderInternalID,
      _ConfirmationGroup,
      _LongTextLanguage
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDEROPERATIONBASIC"
],
"ASSOCIATED":
[
"I_CONFIRMATIONGROUP",
"I_LANGUAGE",
"I_MANUFACTURINGORDER",
"I_MANUFACTURINGORDERSEQUENCE",
"I_MFGORDERCATEGORY",
"I_MFGORDERTYPE",
"I_ORDERINTERNALID",
"I_PLANT"
],
"BASE":
[
"I_MFGORDEROPERATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/