@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_MRPController', '_ProductionSupervisor']
@Analytics.dataCategory: #DIMENSION
@Analytics.technicalName: 'IPPMFGORDBSCFLT'
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'ManufacturingOrder'
@ObjectModel.semanticKey: [ 'ManufacturingOrder']
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_ManufacturingOrder'
@Search.searchable: true
@EndUserText.label: 'Manufacturing Order'
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
// Used only for Supervisor apps
define view entity I_MfgOrderBasicFilter
// Corresponds to calculation view 'sap.hba.ecc.MfgOrder'
as select from I_LogisticsOrder as aufv
inner join I_OrderItem as afpo on afpo.OrderID = aufv.OrderID
and afpo.OrderItem = '0001'
association [1..1] to I_MfgOrderCategory as _MfgOrderCategory on $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
association [1..1] to I_MfgOrderType as _MfgOrderType on $projection.ManufacturingOrderType = _MfgOrderType.ManufacturingOrderType
association [1..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations on $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations
association [0..1] to I_Language as _LongTextLanguage on $projection.LongTextLanguageCode = _LongTextLanguage.Language
association [1..1] to I_UnitOfMeasure as _ProductionUnit on $projection.ProductionUnit = _ProductionUnit.UnitOfMeasure
association [1..1] to I_Plant as _Plant on $projection.ProductionPlant = _Plant.Plant
association [0..1] to I_Plant as _MRPPlant on $projection.MRPPlant = _MRPPlant.Plant
association [0..1] to I_MRPArea as _MRPArea on $projection.MRPArea = _MRPArea.MRPArea
association [0..1] to I_Material as _Material on $projection.Material = _Material.Material
association [0..1] to I_MaterialPlant as _MaterialPlant on $projection.ProductionPlant = _MaterialPlant.Plant
and $projection.Material = _MaterialPlant.Material
association [0..1] to I_Product as _Product on $projection.Material = _Product.Product
association [0..1] to I_Material as _BillOfOperationsMaterial on $projection.BillOfOperationsMaterial = _BillOfOperationsMaterial.Material
association [0..1] to I_SalesOrder as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SalesOrderItem as _SalesOrderItem on $projection.SalesOrder = _SalesOrderItem.SalesOrder
and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
association [0..1] to I_SalesDocument as _SalesDocument on $projection.SalesDocument = _SalesDocument.SalesDocument
association [0..1] to I_SalesDocumentItem as _SalesDocumentItem on $projection.SalesDocument = _SalesDocumentItem.SalesDocument
and $projection.SalesDocumentItem = _SalesDocumentItem.SalesDocumentItem
association [0..1] to I_WBSElementByInternalKey as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
association [0..1] to I_ChangeMaster as _ChangeNumber on $projection.ChangeNumber = _ChangeNumber.ChangeNumber
association [0..1] to I_GLAccount as _GLAccount on $projection.GLAccount = _GLAccount.GLAccount
and $projection.CompanyCode = _GLAccount.CompanyCode
association [0..1] to I_PlannedOrder as _PlannedOrder on $projection.PlannedOrder = _PlannedOrder.PlannedOrder
association [0..1] to I_MRPController as _MRPController on $projection.MRPPlant = _MRPController.Plant
and $projection.MRPController = _MRPController.MRPController
association [0..1] to I_ProductionSupervisor as _ProductionSupervisor on $projection.ProductionPlant = _ProductionSupervisor.Plant
and $projection.ProductionSupervisor = _ProductionSupervisor.ProductionSupervisor
association [0..1] to I_ProductionSchedulingProfile as _ProductionSchedulingProfile on $projection.ProductionPlant = _ProductionSchedulingProfile.Plant
and $projection.ProductionSchedulingProfile = _ProductionSchedulingProfile.ProductionSchedulingProfile
association [0..1] to I_ResponsiblePlannerGroup as _ResponsiblePlannerGroup on $projection.ProductionPlant = _ResponsiblePlannerGroup.Plant
and $projection.ResponsiblePlannerGroup = _ResponsiblePlannerGroup.ResponsiblePlannerGroup
association [0..1] to I_ProductionVersion as _ProductionVersion on $projection.Material = _ProductionVersion.Material
and $projection.ProductionPlant = _ProductionVersion.Plant
and $projection.ProductionVersion = _ProductionVersion.ProductionVersion
association [0..*] to I_MaterialBOM as _BillOfMaterial on $projection.BillOfMaterialVariantUsage = _BillOfMaterial.BillOfMaterialVariantUsage
and $projection.BillOfMaterial = _BillOfMaterial.BillOfMaterial
and $projection.BillOfMaterialVariant = _BillOfMaterial.BillOfMaterialVariant
and $projection.BillOfMaterialCategory = _BillOfMaterial.BillOfMaterialCategory
and $projection.BillOfMaterialVersion = _BillOfMaterial.BillOfMaterialVersion
association [0..*] to I_ProdnProcgFlexibilityIndTxt as _ProdnProcgFlexibilityIndTxt on $projection.ProdnProcgIsFlexible = _ProdnProcgFlexibilityIndTxt.ProdnProcgIsFlexible
{
// Key
@UI.hidden: true
@ObjectModel.text.element: [ 'ManufacturingOrderText']
@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
key cast(aufv.OrderID as manufacturingorder preserving type) as ManufacturingOrder,
// Category and Type
@ObjectModel.foreignKey.association: '_MfgOrderCategory'
@UI.hidden: true
cast(aufv.OrderCategory as manufacturingordercategory preserving type) as ManufacturingOrderCategory,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_MfgOrderType'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OrderTypeVH', element: 'OrderType' } } ]
cast(aufv.OrderType as manufacturingordertype preserving type) as ManufacturingOrderType,
// Text
@UI.hidden: true
@Semantics.text: true
cast(aufv.OrderDescription as manufacturingordertext preserving type) as ManufacturingOrderText,
// new logic: Since long text indicator does not contain X but the language code, this one is moved to
// language field and longtext indicator is determined separately
cast(case aufv.OrderHasLongText
when '' then ''
else 'X'
end as aufltext preserving type) as ManufacturingOrderHasLongText,
@ObjectModel.foreignKey.association: '_LongTextLanguage'
cast(aufv.OrderHasLongText as pph_longtextlang) as LongTextLanguageCode,
// Attributes
@UI.hidden: true
cast(aufv.PriorityCode as orderimportancecode preserving type) as ManufacturingOrderImportance,
@UI.hidden: true
aufv.ProdnProcgIsFlexible as ProdnProcgIsFlexible,
aufv.IsMarkedForDeletion as MfgOrderIsToBeDeleted,
aufv.MfgOrderHasMultipleItems,
aufv.MfgOrderIsPartOfCollvOrder,
aufv.MfgOrderHierarchyLevel,
afpo.IsCompletelyDelivered,
aufv.OrderIsNotCostedAutomatically,
aufv.OrdIsNotSchedldAutomatically,
// Admin
@UI.hidden: true
@Semantics.systemDate.createdAt: true
cast(aufv.CreationDate as ordercreationdate preserving type) as MfgOrderCreationDate,
@Semantics.systemTime.createdAt: true
@Semantics.time: true
cast(aufv.CreationTime as ordercreationtime preserving type) as MfgOrderCreationTime,
@Semantics.user.createdBy: true
@UI.hidden: true
aufv.CreatedByUser,
@UI.hidden: true
@Semantics.systemDate.lastChangedAt: true
aufv.LastChangeDate,
@Semantics.systemTime.lastChangedAt: true
aufv.LastChangeTime,
@Semantics.user.lastChangedBy: true
aufv.LastChangedByUser,
// Assignments
@UI.hidden: true
@ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
cast(aufv.OrderInternalBillOfOperations as pph_aufpl preserving type) as OrderInternalBillOfOperations,
@UI.hidden: true
-- @ObjectModel.foreignKey.association: '_ReferenceOrder'
aufv.ReferenceOrder,
-- @ObjectModel.foreignKey.association: '_LeadingOrder'
aufv.LeadingOrder,
@UI.hidden: true
-- @ObjectModel.foreignKey.association: '_SuperiorOrder'
aufv.MfgOrderSuperiorMfgOrder,
@ObjectModel.foreignKey.association: '_Currency'
aufv.Currency,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_Plant'
cast(aufv.Plant as pwwrk preserving type) as ProductionPlant,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
@ObjectModel.foreignKey.association: '_Material'
afpo.Material,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_MRPPlant'
afpo.MRPPlant,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_MRPArea'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MRPAreaVH', element: 'MRPArea' } } ]
afpo.MRPArea,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_MRPController'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MRPControllerVH', element: 'MRPController' } } ]
cast(aufv.MRPController as pph_dispo preserving type) as MRPController,
@ObjectModel.foreignKey.association: '_ProductionSupervisor'
@UI.hidden : true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProdProductionSupervisorVH', element: 'ProductionSupervisor' } } ]
cast(aufv.ProductionSupervisor as pph_fevor preserving type) as ProductionSupervisor,
@ObjectModel.foreignKey.association: '_ProductionSchedulingProfile'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionSchedgProfileVH', element: 'ProductionSchedulingProfile' } } ]
cast(aufv.ProductionSchedulingProfile as pph_prodprf preserving type) as ProductionSchedulingProfile,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
aufv.ResponsiblePlannerGroup,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionVersionStdVH', element: 'ProductionVersion' } } ]
@ObjectModel.foreignKey.association: '_ProductionVersion'
afpo.ProductionVersion,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlannedOrderStdVH', element: 'PlannedOrder' } } ]
@ObjectModel.foreignKey.association: '_PlannedOrder'
afpo.PlannedOrder,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
@ObjectModel.foreignKey.association: '_SalesOrder'
afpo.SalesOrder,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderItemStdVH', element: 'SalesOrderItem' } } ]
@ObjectModel.foreignKey.association: '_SalesOrderItem'
afpo.SalesOrderItem,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesDocumentStdVH', element: 'SalesDocument' } } ]
@ObjectModel.foreignKey.association: '_SalesDocument'
cast(afpo.SalesOrder as vdm_vbeln preserving type) as SalesDocument,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesDocumentItemStdVH', element: 'SalesDocumentItem' } } ]
@ObjectModel.foreignKey.association: '_SalesDocumentItem'
cast(afpo.SalesOrderItem as vdm_posnr preserving type) as SalesDocumentItem,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElmntByIntKeyStdVH', element: 'WBSElementInternalID' } } ]
@ObjectModel.foreignKey.association: '_WBSElement'
cast(afpo.WBSElementInternalID as ps_s4_pspnr preserving type ) as WBSElementInternalID,
@ObjectModel.foreignKey.association: '_Reservation'
aufv.Reservation,
@ObjectModel.foreignKey.association: '_SettlementReservation'
cast(aufv.SettlementReservation as settlmntres preserving type) as SettlementReservation,
@ObjectModel.foreignKey.association: '_ConfirmationGroup'
aufv.MfgOrderConfirmation,
@EndUserText:{label: 'Confirmation Counter', quickInfo: 'Confirmation Counter'}
aufv.MfgOrderConfirmationCount,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CapacityRequirementStdVH', element: 'CapacityRequirement' } } ]
@ObjectModel.foreignKey.association: '_CapacityRequirement'
aufv.CapacityRequirement,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_InspectionLotStdVH', element: 'InspectionLot' } } ]
@ObjectModel.foreignKey.association: '_InspectionLot'
aufv.InspectionLot,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ChangeMasterStdVH', element: 'ChangeNumber' } } ]
@ObjectModel.foreignKey.association: '_ChangeNumber'
aufv.ChangeNumber,
@ObjectModel.foreignKey.association: '_BasicSchedulingType'
@UI.hidden: true
cast(aufv.BasicSchedulingType as basicschedtype preserving type) as BasicSchedulingType,
@ObjectModel.foreignKey.association: '_ForecastSchedulingType'
cast(aufv.ForecastSchedulingType as forecastschedtype preserving type) as ForecastSchedulingType,
cast(aufv.ObjectInternalID as pph_objnr preserving type) as ManufacturingObject,
cast(afpo.ProductConfiguration as product_configuration preserving type) as ProductConfiguration,
afpo.EffectivityParameterVariant,
@UI.hidden : true
afpo.SerialNumberAssgmtProfile,
aufv.ConditionApplication,
aufv.CapacityActiveVersion,
aufv.CapacityRqmtHasNotToBeCreated,
aufv.OrderSequenceNumber,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BatchStdVH', element: 'Batch' } } ]
afpo.Batch,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_StorageLocationStdVH', element: 'StorageLocation' } } ]
afpo.StorageLocation,
// Assignments BOO
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
@ObjectModel.foreignKey.association: '_BillOfOperationsMaterial'
aufv.Material as BillOfOperationsMaterial,
@ObjectModel.foreignKey.association: '_BillOfOperationsType'
aufv.BillOfOperationsType,
@ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
@VDM.lifecycle.status: #DEPRECATED // default data element change -> deprecated to avoid RTT2 error in ATC
@VDM.lifecycle.successor: 'BillOfOperationsGroup2'
aufv.BillOfOperations,
@ObjectModel.foreignKey.association: '_BillOfOperationsGroup2'
aufv.BillOfOperationsGroup,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
@ObjectModel.foreignKey.association: '_BillOfOperations'
aufv.BillOfOperationsVariant,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BOOChgStateStdVH', element: 'BOOInternalVersionCounter' } } ]
@ObjectModel.foreignKey.association: '_BillOfOperationsChangeState'
@EndUserText:{label: 'Routing Version Counter', quickInfo: 'Routing Version Counter'}
aufv.BOOInternalVersionCounter,
@ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
aufv.BillOfOperationsUsage,
aufv.BillOfOperationsVersion,
aufv.BOOExplosionDate,
@EndUserText:{label: 'Routing Valid-From Date', quickInfo: 'Routing Valid-From Date'}
aufv.BOOValidityStartDate,
// Assignments BOM
aufv.BillOfMaterialCategory,
cast(aufv.BillOfMaterial as pph_stnum preserving type ) as BillOfMaterial,
aufv.BillOfMaterialVariant,
aufv.BillOfMaterialVariantUsage,
aufv.BillOfMaterialVersion,
aufv.BOMExplosionDate,
@EndUserText:{label: 'BOM Valid-From Date', quickInfo: 'BOM Valid-From Date'}
aufv.BOMValidityStartDate,
// Assignments FI/CO
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
@ObjectModel.foreignKey.association: '_BusinessArea'
aufv.BusinessArea,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
@ObjectModel.foreignKey.association: '_CompanyCode'
aufv.CompanyCode,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_ControllingArea'
aufv.ControllingArea,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' } } ]
aufv.ProfitCenter,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
aufv.CostCenter,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
aufv.ResponsibleCostCenter,
aufv.CostElement,
aufv.CostingSheet,
@UI.hidden: true
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_GLAccountStdVH', element: 'GLAccount' } } ]
@ObjectModel.foreignKey.association: '_GLAccount'
aufv.GLAccount,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductCostCtrlgOrderStdVH', element: 'OrderID' } } ]
@ObjectModel.foreignKey.association: '_ProductCostCollector'
aufv.ProductCostCollector,
aufv.ActualCostsCostingVariant,
aufv.PlannedCostsCostingVariant,
@ObjectModel.foreignKey.association: '_ControllingObjectClass'
aufv.ControllingObjectClass,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_FunctionalArea'
aufv.FunctionalArea,
// Dates and Times
cast(aufv.PlannedStartDate as mfgorderplannedstartdate preserving type) as MfgOrderPlannedStartDate,
cast(aufv.PlannedStartTime as mfgorderplannedstarttime preserving type) as MfgOrderPlannedStartTime,
cast(aufv.PlannedEndDate as mfgorderplannedenddate preserving type) as MfgOrderPlannedEndDate,
cast(aufv.PlannedEndTime as mfgorderplannedendtime preserving type) as MfgOrderPlannedEndTime,
@UI.hidden: true
cast(aufv.PlannedReleaseDate as mfgorderplannedreleasedate preserving type) as MfgOrderPlannedReleaseDate,
cast(aufv.ScheduledBasicStartDate as mfgorderscheduledstartdate preserving type) as MfgOrderScheduledStartDate,
cast(aufv.ScheduledBasicStartTime as mfgorderscheduledstarttime preserving type) as MfgOrderScheduledStartTime,
cast(aufv.ScheduledBasicEndDate as mfgorderscheduledenddate preserving type) as MfgOrderScheduledEndDate,
cast(aufv.ScheduledBasicEndTime as mfgorderscheduledendtime preserving type) as MfgOrderScheduledEndTime,
@UI.hidden: true
cast(aufv.ScheduledReleaseDate as mfgorderscheduledreleasedate preserving type) as MfgOrderScheduledReleaseDate,
cast(aufv.ActualStartDate as mfgorderactualstartdate preserving type) as MfgOrderActualStartDate,
cast(aufv.ActualStartTime as mfgorderactualstarttime preserving type) as MfgOrderActualStartTime,
cast(aufv.ActualEndDate as mfgorderactualenddate preserving type) as MfgOrderActualEndDate,
@UI.hidden: true
cast(aufv.ActualReleasedDate as mfgorderactualreleasedate preserving type) as MfgOrderActualReleaseDate,
cast(aufv.ConfirmedEndDate as mfgorderconfirmedenddate preserving type) as MfgOrderConfirmedEndDate,
cast(aufv.ConfirmedEndTime as mfgorderconfirmedendtime preserving type) as MfgOrderConfirmedEndTime,
@UI.hidden: true
aufv.TotalCommitmentDate as MfgOrderTotalCommitmentDate,
afpo.ActualDeliveryDate as MfgOrderItemActualDeliveryDate,
// Quantities and UoM
@UI.hidden: true
cast(aufv.BaseUnit as productionunit preserving type) as ProductionUnit,
@UI.hidden: true
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
cast(aufv.OrderPlannedTotalQty as mfgorderplannedtotalqty preserving type) as MfgOrderPlannedTotalQty,
@UI.hidden: true
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
cast(aufv.OrderPlannedScrapQty as mfgorderplannedscrapqty preserving type) as MfgOrderPlannedScrapQty,
@UI.hidden: true
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
cast(aufv.OrderConfirmedYieldQty as co_igmng preserving type) as MfgOrderConfirmedYieldQty,
@UI.hidden: true
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
cast(aufv.OrderConfirmedScrapQty as co_iasmg preserving type) as MfgOrderConfirmedScrapQty,
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
@UI.hidden: true
aufv.MfgOrderConfirmedReworkQty,
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
cast(afpo.MfgOrderItemActualDeviationQty as co_mimez preserving type) as ExpectedDeviationQuantity,
@UI.hidden: true
@Semantics.quantity.unitOfMeasure: 'ProductionUnit'
// @DefaultAggregation: #NONE
afpo.MfgOrderItemGoodsReceiptQty as ActualDeliveredQuantity,
// Associations
_MfgOrderCategory,
_MfgOrderType,
aufv._OrderTypeDetails,
//_CreatedByUser,
aufv._LastChangedByUser,
_LongTextLanguage,
_ProductionUnit,
aufv._Currency,
_OrdInternalBillOfOperations,
_BillOfMaterial,
_BillOfOperationsMaterial,
aufv._BillOfOperationsType,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: '_BillOfOperationsGroup2'
aufv._BillOfOperationsGroup,
aufv._BillOfOperationsGroup2,
aufv._BillOfOperations,
aufv._BillOfOperationsChangeState,
aufv._BillOfOperationsUsage,
aufv._ConfirmationGroup,
aufv._Reservation,
aufv._SettlementReservation,
_Plant,
_Material,
_MaterialPlant,
_Product,
_MRPArea,
_MRPPlant,
_MRPController,
_ProductionSupervisor,
_ProductionSchedulingProfile,
_ResponsiblePlannerGroup,
_ProductionVersion,
aufv._CapacityRequirement,
_ChangeNumber,
aufv._InspectionLot,
_PlannedOrder,
_SalesOrder,
_SalesOrderItem,
_SalesDocument,
_SalesDocumentItem,
_WBSElement,
aufv._BusinessArea,
aufv._ProfitCenter,
aufv._CostCenter,
aufv._ResponsibleCostCenter,
aufv._CompanyCode,
aufv._ControllingArea,
aufv._ControllingObjectClass,
aufv._FunctionalArea,
_GLAccount,
aufv._ProductCostCollector,
aufv._BasicSchedulingType,
aufv._ForecastSchedulingType,
_ProdnProcgFlexibilityIndTxt
}
where ( aufv.OrderCategory = '10'); //Manufacturing orders only
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDER",
"I_ORDERITEM"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_BILLOFOPERATIONSUSAGE",
"I_BUSINESSAREA",
"I_CAPACITYREQUIREMENT",
"I_CHANGEMASTER",
"I_COMPANYCODE",
"I_CONFIRMATIONGROUP",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_CURRENCY",
"I_FUNCTIONALAREA",
"I_GLACCOUNT",
"I_INSPECTIONLOT",
"I_LANGUAGE",
"I_MATERIAL",
"I_MATERIALBOM",
"I_MATERIALPLANT",
"I_MFGORDERCATEGORY",
"I_MFGORDERTYPE",
"I_MRPAREA",
"I_MRPCONTROLLER",
"I_ORDERTYPEDETAILS",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANNEDORDER",
"I_PLANT",
"I_PRODNPROCGFLEXIBILITYINDTXT",
"I_PRODUCT",
"I_PRODUCTCOSTCTRLGORDER",
"I_PRODUCTIONSCHEDULINGPROFILE",
"I_PRODUCTIONSUPERVISOR",
"I_PRODUCTIONVERSION",
"I_PROFITCENTER",
"I_RESERVATIONDOCUMENTHEADER",
"I_RESPONSIBLEPLANNERGROUP",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SCHEDULINGTYPE",
"I_UNITOFMEASURE",
"I_USER",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[
"I_LOGISTICSORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/