I_ProductionSchedulingProfile

@AbapCatalog.sqlViewName: 'IPRODNSCHEDGPROF'
@AbapCatalog.buffering: {status: #ACTIVE, type: #FULL, numberOfKeyFields: 000}
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities:  [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'ProductionSchedulingProfile'
@ObjectModel.semanticKey: ['ProductionSchedulingProfile']
@ObjectModel.sapObjectNodeType.name: 'ProductionSchedulingProfile'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@Search.searchable: true
@EndUserText.label: 'Production Scheduling Profile'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_ProductionSchedulingProfile
  as select from tco43 as tco43
  association [1..1] to I_Plant         as _Plant              on  $projection.Plant = _Plant.Plant
  association [0..1] to I_OrderCategory as _OrderCategory      on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [0..*] to I_ProductionSchedgProfileText as _Text on  $projection.Plant                       = _Text.Plant 
                                                               and $projection.ProductionSchedulingProfile = _Text.ProductionSchedulingProfile
{
      // Key

      @ObjectModel.text.association: '_Text'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key cast(tco43.co_prodprf as pph_prodprf preserving type) as ProductionSchedulingProfile,
      @ObjectModel.foreignKey.association: '_Plant'
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
  key tco43.werks as Plant,

      // Assignments

      @ObjectModel.foreignKey.association: '_OrderCategory'
      cast(tco43.autyp as pph_autyp preserving type) as OrderCategory,

      // Control parameters

      tco43.autwe                                    as GRIsPostedAutomatically,
      tco43.sync_gm_for_ewm                          as MfgOrderEWMSynchronousPosting,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text,
      _Plant,
      _OrderCategory
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TCO43"
],
"ASSOCIATED":
[
"I_ORDERCATEGORY",
"I_PLANT",
"I_PRODUCTIONSCHEDGPROFILETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/