I_MaterialShortageDefinition

DDL: I_MATERIALSHORTAGEDEFINITION SQL: IMATSHORTDEF Type: view BASIC

MRP Material Shortage Definition

I_MaterialShortageDefinition is a Basic CDS View that provides data about "MRP Material Shortage Definition" in SAP S/4HANA. It reads from 1 data source (sdm_msh_prof01) and exposes 7 fields with key fields MaterialShortageProfile, MaterialShortageProfileCount. It has 3 associations to related views.

1 data source(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
sdm_msh_prof01 sdm_msh_prof01 from

Associations (3)

CardinalityTargetAliasCondition
[0..1] sdm_aor_profile _ProfileUser _ProfileUser.uname = $session.user and _ProfileUser.sdm_profile = $projection.MaterialShortageProfile
[0..1] sdm_aor_profile _ProfileStar _ProfileStar.uname = '*' and _ProfileStar.sdm_profile = $projection.MaterialShortageProfile
[0..*] sdm_msh_prof01_t _MaterialShortageDefText $projection.MaterialShortageProfile = _MaterialShortageDefText.materialshortageprofile and $projection.MaterialShortageProfileCount = _MaterialShortageDefText.materialshortageprof_cnt

Annotations (9)

NameValueLevelField
AbapCatalog.sqlViewName IMATSHORTDEF view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label MRP Material Shortage Definition view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
VDM.viewType #BASIC view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY MaterialShortageProfile sdm_msh_prof01 materialshortageprofile
KEY MaterialShortageProfileCount
DemandCategoryGroup sdm_msh_prof01 demandcategorygroup
ReceiptCategoryGroup sdm_msh_prof01 receiptcategorygroup
EvaluationHorizonInDays sdm_msh_prof01 sdivevaluationhorizonindays
MaterialShortageDefinitionName
HasMfgOrderComponentCheckRule sdm_msh_prof01 mfgordercomponentcheckrule 
@AbapCatalog.sqlViewName: 'IMATSHORTDEF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'MRP Material Shortage Definition'

@ClientHandling.algorithm: #SESSION_VARIABLE


@ObjectModel: {
    usageType: {serviceQuality: #B, sizeCategory: #M, dataClass: #CUSTOMIZING }
}

@VDM.viewType: #BASIC

define view I_MaterialShortageDefinition
  as select from sdm_msh_prof01

  association [0..1] to sdm_aor_profile  as _ProfileUser             on  _ProfileUser.uname = $session.user   and _ProfileUser.sdm_profile =  $projection.MaterialShortageProfile
  association [0..1] to sdm_aor_profile  as _ProfileStar             on  _ProfileStar.uname = '*'             and _ProfileStar.sdm_profile =  $projection.MaterialShortageProfile
  association [0..*] to sdm_msh_prof01_t as _MaterialShortageDefText on  $projection.MaterialShortageProfile      = _MaterialShortageDefText.materialshortageprofile
                                                                     and $projection.MaterialShortageProfileCount = _MaterialShortageDefText.materialshortageprof_cnt
{
  key sdm_msh_prof01.materialshortageprofile                                                                as MaterialShortageProfile,
  key cast (sdm_msh_prof01.materialshortageprof_cnt as materialshortageprofilecount preserving type)        as MaterialShortageProfileCount,
      sdm_msh_prof01.demandcategorygroup                                                                    as DemandCategoryGroup,
      sdm_msh_prof01.receiptcategorygroup                                                                   as ReceiptCategoryGroup,
      sdm_msh_prof01.sdivevaluationhorizonindays                                                            as EvaluationHorizonInDays,
      _MaterialShortageDefText[ 1: spras = $session.system_language ].materialshortagedefinitionname        as MaterialShortageDefinitionName,
      sdm_msh_prof01.mfgordercomponentcheckrule                                                             as HasMfgOrderComponentCheckRule
}
where
     _ProfileUser.sdm_profile               = sdm_msh_prof01.materialshortageprofile
  or _ProfileStar.sdm_profile               = sdm_msh_prof01.materialshortageprofile
  or sdm_msh_prof01.materialshortageprofile = 'SAP000000001'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SDM_AOR_PROFILE",
"SDM_MSH_PROF01",
"SDM_MSH_PROF01_T"
],
"ASSOCIATED":
[
"SDM_AOR_PROFILE",
"SDM_MSH_PROF01_T"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More