I_MaterialSelectionVH

DDL: I_MATERIALSELECTIONVH Type: view_entity COMPOSITE

Material Selection ID

I_MaterialSelectionVH is a Composite CDS View that provides data about "Material Selection ID" in SAP S/4HANA. It reads from 1 data source (I_MaterialShortageDefinition) and exposes 6 fields with key fields MRPPlant, Material, MRPArea, MRPPlanningSegmentType, MRPPlanningSegmentExternalCode.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
I_MaterialShortageDefinition _MaterialShortageProf inner

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Material Selection ID view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey MaterialSelectionIdentifier view
Search.searchable true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY MRPPlant MRPPlanningSegment MRPPlant
KEY Material MRPPlanningSegment Material
KEY MRPArea MRPPlanningSegment MRPArea
KEY MRPPlanningSegmentType
KEY MRPPlanningSegmentExternalCode MRPPlanningSegment MRPPlanningSegmentExternalCode
KEY MaterialShortageProfile MRPPlanningSegment MaterialShortageProfile 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Material Selection ID'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@ObjectModel: {
                dataCategory: #VALUE_HELP,
                representativeKey: 'MaterialSelectionIdentifier',
                supportedCapabilities: [#VALUE_HELP_PROVIDER]
              } 
@Search.searchable: true              
define view entity I_MaterialSelectionVH as select  distinct from I_MRPPlanningSegment  as MRPPlanningSegment 
inner join  I_MaterialShortageDefinition as _MaterialShortageProf on  _MaterialShortageProf.MaterialShortageProfile = MRPPlanningSegment.MaterialShortageProfile 
and _MaterialShortageProf.MaterialShortageProfileCount = '001' 
{ 
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #MEDIUM   
  @UI: {lineItem: [ { position:20 } ]} 
  key MRPPlanningSegment.MRPPlant,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #HIGH  
  @UI: {lineItem: [ { position:10 } ]}
  key MRPPlanningSegment.Material,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #MEDIUM  
  @UI: {lineItem: [ { position:30 } ]}
  key MRPPlanningSegment.MRPArea,
  @UI.hidden: true
  @UI.selectionField: [{exclude: true}]
  key cast (MRPPlanningSegment.MRPPlanningSegmentType as abap.numc(2) ) as MRPPlanningSegmentType,
  @Search.fuzzinessThreshold: 0.8
  @Search.defaultSearchElement: true
  @Search.ranking: #MEDIUM   
  @EndUserText:{label: 'Individual Segment',quickInfo: 'Individual Segment'}
  @UI: {lineItem: [ { position:50 } ]}
  key MRPPlanningSegment.MRPPlanningSegmentExternalCode,
  @EndUserText.label: 'Material Selection ID'
  @UI: {lineItem: [ { position:40 } ]}
  key concat(MRPPlanningSegment.Material,concat(MRPPlanningSegment.MRPPlant,
  concat(MRPPlanningSegment.MRPArea,concat(MRPPlanningSegment.MRPPlanningSegmentType,MRPPlanningSegment.MRPPlanningSegmentExternalCode))))        as MaterialSelectionIdentifier,
  @UI.hidden: true
  @UI: { selectionField:[ { exclude: true }]}
  key MRPPlanningSegment.MaterialShortageProfile
}

where
  (
       MRPPlanningSegment.MRPPlanningSegmentType = '02'
    or MRPPlanningSegment.MRPPlanningSegmentType = '00'
    or MRPPlanningSegment.MRPPlanningSegmentType = '20'
    or MRPPlanningSegment.MRPPlanningSegmentType = '22'
    or MRPPlanningSegment.MRPPlanningSegmentType = '24'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALSHORTAGEDEFINITION",
"I_MRPPLANNINGSEGMENT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More