I_MaintPlanningBucketTP

@AbapCatalog.sqlViewName: 'IMAINTPLNGBKTTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Planning Bucket TP'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  entityChangeStateId:            'LastChangeDateTime',
  draftEnabled:                   true,
  lifecycle.draft.expiryBehavior : #RELATIVE_TO_PROCESSING_START,
  lifecycle.draft.expiryInterval: 'P1D',
  createEnabled:                  true,
  updateEnabled:                  true,
  deleteEnabled:                  true,
  writeDraftPersistence:          'EAM_PLNGBKT_D',
  writeActivePersistence:         'EAM_PLNGBKT',
  compositionRoot:                true,
   transactionalProcessingEnabled: true,
  modelCategory:                  #BUSINESS_OBJECT,
  representativeKey:              'MaintPlanningBucketUUID',
  semanticKey:                    ['MaintPlanningBucketUUID'],
  usageType: {
    serviceQuality: #C,
    dataClass:      #TRANSACTIONAL,
    sizeCategory:   #L
  }
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'MaintenancePlanningBucket'
@Metadata.allowExtensions

define view I_MaintPlanningBucketTP
  as select from I_MaintPlngBucketWithRespyData

  association [0..*] to I_MaintPlanningBucketScopeTP as _MaintPlanningBucketScope on  _MaintPlanningBucketScope.MaintPlanningBucketUUID = $projection.MaintPlanningBucketUUID

  association [0..1] to I_MaintPlanningBucketTP      as _RefMaintPlanningBucket   on  _RefMaintPlanningBucket.MaintPlanningBucketUUID = $projection.RefMaintPlanningBucket

  association [0..1] to I_MaintenancePlanPlant       as _MaintenancePlanningPlant on  _MaintenancePlanningPlant.MaintenancePlanningPlant = $projection.MaintenancePlanningPlant

  association [0..1] to I_MaintPlngBucketRcrrcType   as _RecurrenceType           on  _RecurrenceType.MaintPlngBucketRecurrenceType = $projection.MaintPlngBucketRecurrenceType

  association [0..1] to I_UnitOfMeasure              as _UnitOfMeasure            on  _UnitOfMeasure.UnitOfMeasureISOCode = 'WEE'


{
       //EAM_PLNGBKT

       @ObjectModel.text.element: ['MaintPlanningBucketDescription']
       @UI.hidden
  key  MaintPlanningBucketUUID,

       @ObjectModel.mandatory
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlanningBucketType,

       @ObjectModel.mandatory
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       @Consumption.valueHelpDefinition: [{ entity: { name: 'C_MaintenancePlanPlantVH', element: 'MaintenancePlanningPlant' } }]
       MaintenancePlanningPlant,

       @ObjectModel.text.element: ['MaintPlanningBucketDescription']
       @ObjectModel.mandatory
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBucketLabel,

       @Semantics.text: true
       MaintPlanningBucketDescription,

       RefMaintPlanningBucket,

       '                                                                                                                        ' as MaintPlngBcktLabelPatternDesc,
       @ObjectModel.readOnly: true
       @UI.hidden
       cast('        ' as abap.dats)                                                                                              as MaintPlngBcktNextGnrtnDate,
       @ObjectModel.readOnly: true
       MaintPlngBucketLabelPattern,
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBucketRecurrenceType,
       NrOfMaintPlngBucketsInAdvance,
       MaintPlanningBucketPersonResp                                                                                              as PersonResponsible,
       //       PersonResponsible,

       @ObjectModel.mandatory
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBucketStartDateTime,
       @ObjectModel.mandatory
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBucketEndDateTime,

       @Semantics.systemDateTime.lastChangedAt
       LastChangeDateTime,

       MaintPlngBucketGenerationDate,
       MaintPlngBucketSortUUID                                                                                                    as MaintPlngBucketSortField,
       //       MaintPlngBucketSortField,

       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBucketDuration,
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBucketDurationUnit,
       @ObjectModel.readOnly: #('EXTERNAL_CALCULATION')
       MaintPlngBcktRcrrcInterval,

       @ObjectModel.readOnly: true
       MaintenanceEvent,

       '        '                                                                                                                 as MaintenanceRevision,

       '  '                                                                                                                       as MaintenanceEventType,
       ' '                                                                                                                        as OperationSystemCondition,
       MaintOrderForAdministration,

       @ObjectModel.readOnly: true
       cast( case when MaintPlngBucketRecurrenceType = 'DAILY' then 'TAG'
                  when MaintPlngBucketRecurrenceType = 'WEEKLY' then _UnitOfMeasure.UnitOfMeasure_E
                  else '' end as meins )                                                                                          as MaintPlngBcktRcrrcIntervalUnit,

       cast( '' as xfeld )                                                                                                        as MaintEventHasOrderAssigned,
       cast( '00' as maintordselfordateadjmt )                                                                                    as MaintOrdSelForDateAdjmt,

       @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
       _MaintPlanningBucketScope,
       _RefMaintPlanningBucket,
       _MaintenancePlanningPlant,
       _RecurrenceType,
       _PersonWorkAgreement,
       _MaintPlanningBucketType,
       _UnitOfMeasure
       //       _EquipmentData

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTPLNGBUCKETWITHRESPYDATA",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"I_MAINTENANCEPLANPLANT",
"I_MAINTPLANNINGBUCKETSCOPETP",
"I_MAINTPLANNINGBUCKETTYPE",
"I_MAINTPLNGBUCKETRCRRCTYPE",
"I_PERSONWORKAGREEMENT_1",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MAINTPLNGBUCKETWITHRESPYDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/