I_MaintOrderTechObj

@EndUserText.label: 'Maintenance Order w/ Technical Object'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AbapCatalog.sqlViewName: 'IMAINTORDTECOBJ'
@AbapCatalog.preserveKey: true

@ObjectModel.representativeKey: 'MaintenanceOrder'
@ObjectModel.semanticKey:  [ 'MaintenanceOrder' ]

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL

// #BASIC View which also incorporates I_TechnicalObject (used for generating BOPF infrastructure)


define view I_MaintOrderTechObj
  as select from I_MaintenanceOrder

  association [0..*] to I_MaintOrderOperTechObj      as _MaintenanceOrderOperation    on  _MaintenanceOrderOperation.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..1] to I_TechnicalObject            as _TechnicalObject              on  _TechnicalObject.TechnicalObject           = $projection.TechnicalObject
                                                                                      and _TechnicalObject.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
  association [0..1] to I_TechObjIsEquipOrFuncnlLoc  as _TechObjIsEquipOrFuncnlLoc    on  _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
  association [0..1] to P_MaintOrdResponsiblePartner as _MaintOrdResponsiblePartner   on  _MaintOrdResponsiblePartner.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..1] to I_Indicator                  as _MaintOrderIsFinallyConfirmed on  _MaintOrderIsFinallyConfirmed.IndicatorValue = $projection.MaintOrderIsFinallyConfirmed
  association [0..1] to I_WorkCenterBySemanticKey    as _MaintOrdMainWorkCenter       on  _MaintOrdMainWorkCenter.WorkCenter = $projection.MaintOrdMainWorkCenter
                                                                                      and _MaintOrdMainWorkCenter.Plant = $projection.MaintOrdMainWorkCenterPlant
  association [0..1] to I_Plant                      as _MaintOrdMainWorkCenterPlant  on  _MaintOrdMainWorkCenterPlant.Plant = $projection.MaintOrdMainWorkCenterPlant
  association [0..*] to I_StatusObjectStatusBasic    as _StatusObjectStatusBasic      on  _StatusObjectStatusBasic.StatusObject = $projection.MaintenanceOrderInternalID
  association [0..1] to I_PersonWorkAgreement_1      as _MaintOrdPersonResponsible    on  _MaintOrdPersonResponsible.PersonWorkAgreement = $projection.MaintOrdPersonResponsible
  association [0..1] to I_MaintOrderProcessingContext  as _MaintOrderProcessingContext   on  _MaintOrderProcessingContext.MaintOrderProcessingContext = $projection.MaintOrderProcessingContext
  association [0..1] to C_MaintOrdProcessingContextVH  as _MaintOrdProcessingContextVH   on  _MaintOrdProcessingContextVH.MaintOrderProcessingContext = $projection.MaintOrderProcessingContext

{

      @ObjectModel.text.element:  [ 'MaintenanceOrderDesc' ]
  key I_MaintenanceOrder.MaintenanceOrder,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_TechnicalObjectStdVH',
                     element: 'TechnicalObject' },
          additionalBinding: [{ localElement: 'TechObjIsEquipOrFuncnlLoc',
                                element: 'TechObjIsEquipOrFuncnlLoc' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_TechnicalObject'
      case when Equipment = '' then
                  cast( _LocationAccountAssignment.FunctionalLocation as eams_tec_obj )
           else cast( Equipment as eams_tec_obj ) end                                         as TechnicalObject,

      @ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
      @UI.textArrangement: #TEXT_ONLY
      cast( case when Equipment = '' and _LocationAccountAssignment.FunctionalLocation = '' then ''
            else case when Equipment = '' then 'EAMS_FL'
            else 'EAMS_EQUI' end end as eams_tec_obj_type_value )                             as TechObjIsEquipOrFuncnlLoc,

      /* Fields */
      I_MaintenanceOrder.MaintPriorityType,
      I_MaintenanceOrder.MaintPriority,
      I_MaintenanceOrder.MaintenanceProcessingPhase,
      I_MaintenanceOrder.MaintObjectLocAcctAssgmtNmbr,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintNotifStdVH',
                     element: 'MaintenanceNotification' }
        }]
      // ]--GENERATED

      I_MaintenanceOrder.MaintenanceNotification,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EquipmentStdVH',
                     element: 'Equipment' }
        }]
      // ]--GENERATED

      I_MaintenanceOrder.Equipment,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceItemStdVH',
                     element: 'MaintenanceItem' }
        }]
      // ]--GENERATED

      I_MaintenanceOrder.MaintenanceItem,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      // ]--GENERATED

      I_MaintenanceOrder.Assembly,
      I_MaintenanceOrder.SerialNumber,
      I_MaintenanceOrder.MaintenancePlanningPlant,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintPlnrGrpStdVH',
                     element: 'MaintenancePlannerGroup' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED

      I_MaintenanceOrder.MaintenancePlannerGroup,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceRevisionStdVH',
                     element: 'MaintenanceRevision' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED

      I_MaintenanceOrder.MaintenanceRevision,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenancePlanStdVH',
                     element: 'MaintenancePlan' }
        }]
      // ]--GENERATED

      I_MaintenanceOrder.MaintenancePlan,
      I_MaintenanceOrder.MaintOrderRoutingNumber,
      I_MaintenanceOrder.MaintenanceOrderType,
      I_MaintenanceOrder.MaintenanceOrderCategory,
      I_MaintenanceOrder.MaintenanceOrderDesc,
      BasicSchedulingType,
      OrdIsNotSchedldAutomatically,
      I_MaintenanceOrder.MaintOrdBasicStartDate,
      I_MaintenanceOrder.MaintOrdBasicStartTime,
      I_MaintenanceOrder.MaintOrdBasicEndDate,
      I_MaintenanceOrder.MaintOrdBasicEndTime,
      I_MaintenanceOrder.MaintenanceOrderInternalID,
      I_MaintenanceOrder.WorkCenterInternalID,
      I_MaintenanceOrder.WorkCenterTypeCode,
      I_MaintenanceOrder.BusinessArea,
      I_MaintenanceOrder.FunctionalArea,
      I_MaintenanceOrder.MainWorkCenter,
      @ObjectModel.foreignKey.association: '_MaintOrdMainWorkCenter'
      I_MaintenanceOrder.MainWorkCenter as MaintOrdMainWorkCenter,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_PlantStdVH',
                     element: 'Plant' }
        }]
      @ObjectModel.foreignKey.association: '_MaintOrdMainWorkCenterPlant'
      I_MaintenanceOrder.MainWorkCenterPlant as MaintOrdMainWorkCenterPlant,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_PersWrkAgrmtSrchHelp',
                     element: 'PersonWorkAgreement' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintOrdPersonResponsible'
      I_MaintenanceOrder.MaintOrdPersonResponsible,

      I_MaintenanceOrder.MaintOrderReferenceDate,
      I_MaintenanceOrder.MaintOrderReferenceTime,
      I_MaintenanceOrder.MaintenanceOrderPlanningCode,
      I_MaintenanceOrder.OperationSystemCondition,
      I_MaintenanceOrder.ReferenceElement,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintActyTypeStdVH',
                     element: 'MaintenanceActivityType' }
        }]
      // ]--GENERATED

      I_MaintenanceOrder.MaintenanceActivityType,

      I_MaintenanceOrder.CreationDate,
      I_MaintenanceOrder.CreationTime,
      I_MaintenanceOrder.LastChangeDateTime,
      I_MaintenanceOrder.OrderHasLongText,
      I_MaintenanceOrder.CreatedByUser,

      I_MaintenanceOrder.TaskListType,
      I_MaintenanceOrder.TaskListGroup,
      I_MaintenanceOrder.TaskListGroupCounter,

      I_MaintenanceOrder.Currency,
      I_MaintenanceOrder.LatestAcceptableCompletionDate,
      I_MaintenanceOrder.Material,
      ScheduledBasicStartDate,
      ScheduledBasicStartTime,
      ScheduledBasicEndDate,
      ScheduledBasicEndTime,

      _LocationAccountAssignment.FunctionalLocation,
      _LocationAccountAssignment.PlantSection,

      @ObjectModel.foreignKey: {
          association: '_MaintOrderIsFinallyConfirmed'
      }
      cast( case when _StatusObjectStatusBasic[1: StatusCode = 'I0009' and StatusIsInactive = '' ].StatusCode != ''
      then 'X'
      else '' end as xfeld )                                                                  as MaintOrderIsFinallyConfirmed,

      MaintOrdProcessPhaseCode,
      MaintOrdProcessSubPhaseCode,
      @ObjectModel.foreignKey.association: '_MaintOrdProcessingContextVH'
      MaintOrderProcessingContext,

      cast( _LocationAccountAssignment.WBSElementInternalID as ps_s4_pspnr preserving type  ) as LocAcctAssgmtWBSElmntIntID,
      _LocationAccountAssignment.CostCenter                                                   as LocAcctAssgmtCostCenter,
      
      I_MaintenanceOrder.AdditionalDeviceData,

      //      /* Fields required by DCL (authorization) */

      I_MaintenanceOrder.ControllingArea,
      I_MaintenanceOrder.CompanyCode,
      I_MaintenanceOrder.ResponsibleCostCenter,
      ControllingObjectClass,
      ProfitCenter,
      WBSElementInternalID,
      ProjectInternalID,
      OrderProcessingGroup,
      _LocationAccountAssignment.MaintenancePlant,
      _LocationAccountAssignment._FunctionalLocation,

      /* Associations */
      I_MaintenanceOrder._Equipment,
      I_MaintenanceOrder._LocationAccountAssignment,
      I_MaintenanceOrder._MaintenanceNotification,
      I_MaintenanceOrder._MaintenanceOrderCategory,
      I_MaintenanceOrder._MaintenanceOrderType,
      I_MaintenanceOrder._MaintenanceOrderComponent,
      I_MaintenanceOrder._MaintenanceOrderPhase,
      I_MaintenanceOrder._MaintenancePlan,
      I_MaintenanceOrder._MaintenanceItem,
      I_MaintenanceOrder._OrderItem,
      I_MaintenanceOrder._MaintenanceTaskList,
      I_MaintenanceOrder._MaintenancePriority,
      I_MaintenanceOrder._MaintenancePriorityType,
      I_MaintenanceOrder._Order,
      I_MaintenanceOrder._CompanyCode,
      _ControllingObjectClass,
      _ProfitCenter,
      _OrderProcessingGroup,
      _BasicSchedulingType,
      _WBSElement,
      _Project,
      I_MaintenanceOrder._ControllingArea,
      I_MaintenanceOrder._ResponsibleCostCenter,
      I_MaintenanceOrder._StatusObject,
      I_MaintenanceOrder._BusinessArea,
      I_MaintenanceOrder._StatusObjectStatus,
      I_MaintenanceOrder._MaintenancePlannerGroup,
      I_MaintenanceOrder._MaintenancePlanningPlant,
      I_MaintenanceOrder._MaintenanceActivityType,
      I_MaintenanceOrder._Assembly,
      I_MaintenanceOrder._OperationSystemCondition,
      I_MaintenanceOrder._OrderHasLongText,
      I_MaintenanceOrder._MainWorkCenter,
      _MaintOrdMainWorkCenter,
      _MaintOrdMainWorkCenterPlant,
      I_MaintenanceOrder._MaintOrdPlngDegreeCode,
      I_MaintenanceOrder._MaintenanceRevision,
      I_MaintenanceOrder._CreatedByUser,
      MaintenanceOrderObjectList,     

      //@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      _MaintenanceOrderOperation,
      _TechnicalObject,
      _TechObjIsEquipOrFuncnlLoc,
      _MaintOrderTypeControlParam,
      _StatusObjectActiveStatus,
      --_StsObjConcatActiveStsILL,
      _MaintOrderIsFinallyConfirmed,
      _MaintOrdPersonResponsible,
      I_MaintenanceOrder._MaintOrderHasOpenMainWork,
      _MaintenancePlanPlant,
      _EAMProcessPhase,
      _EAMProcessSubPhase,
      _ResponsibleCostCenterText,
      _MaintOrderProcessingContext,
      _MaintOrdProcessingContextVH,
      _WrkPmtMaintOrderRelevance

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEORDER",
"I_STATUSOBJECTSTATUSBASIC"
],
"ASSOCIATED":
[
"C_MAINTORDPROCESSINGCONTEXTVH",
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_COSTCENTERTEXT",
"I_EAMPROCESSPHASE",
"I_EAMPROCESSSUBPHASE",
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_INDICATOR",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_LOGISTICSORDER",
"I_MAINTENANCEACTIVITYTYPE",
"I_MAINTENANCEITEM",
"I_MAINTENANCENOTIFICATION",
"I_MAINTENANCEORDERCOMPONENT_2",
"I_MAINTENANCEORDERPHASE",
"I_MAINTENANCEPLANBASIC",
"I_MAINTENANCEPLANNERGROUP",
"I_MAINTENANCEPLANPLANT",
"I_MAINTENANCEREVISION",
"I_MAINTENANCETASKLIST",
"I_MAINTOPERATIONSYSTCONDITION",
"I_MAINTORDERHASOPENMAINWORK",
"I_MAINTORDEROPERTECHOBJ",
"I_MAINTORDERPROCESSINGCONTEXT",
"I_MAINTORDERTYPECONTROLPARAM",
"I_MAINTORDPLNGDEGREECODE",
"I_MATERIAL",
"I_ORDERCATEGORY",
"I_ORDERITEM",
"I_ORDERPROCESSINGGROUP",
"I_ORDERTYPE",
"I_PERSONWORKAGREEMENT_1",
"I_PLANT",
"I_PMNOTIFICATIONPRIORITY",
"I_PMNOTIFICATIONPRIORITYTYPE",
"I_PROFITCENTER",
"I_PROJECTBYINTERNALKEY",
"I_SCHEDULINGTYPE",
"I_STATUSOBJECT",
"I_STATUSOBJECTACTIVESTATUS",
"I_STATUSOBJECTSTATUS",
"I_STATUSOBJECTSTATUSBASIC",
"I_TECHNICALOBJECT",
"I_TECHOBJISEQUIPORFUNCNLLOC",
"I_USER",
"I_WBSELEMENTBYINTERNALKEY",
"I_WORKCENTER",
"I_WORKCENTERBYSEMANTICKEY",
"I_WRKPMTMAINTORDERRELEVANCE",
"P_MAINTORDRESPONSIBLEPARTNER"
],
"BASE":
[
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/