C_MaintOrderQuickVw

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CMTORDQV'
@ClientHandling.algorithm: #SESSION_VARIABLE

-- QuickViews are currently read via association
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'MaintenanceOrder'

@UI.headerInfo : {
  typeName: 'Maintenance Order',
  typeNamePlural: 'Maintenance Orders',
  imageUrl: 'MaintenanceOrderThumbnailURL'
}

define view C_MaintOrderQuickVw
  as select from I_MaintOrderTechObj
{
      @UI.facet: [{
        purpose: #QUICK_VIEW,
        type: #FIELDGROUP_REFERENCE,
        targetQualifier: 'MaintenanceOrderQuickView'
      }]
      // Maintanence Order

      //    @UI: {

      //            fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 10}]

      //            }

      //    @EndUserText.label: 'Maintenance Order'


  key MaintenanceOrder,

      // Maintanence Order Description

      //    @UI: {

      //            fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 20}]

      //            }

      //    @EndUserText.label: 'Description'

      //

      MaintenanceOrderDesc,

      // Maintanence Order Long Text


      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_ORDER_LTXT_EXIT'
      @UI.fieldGroup: [{ qualifier: 'MaintenanceOrderQuickView', position: 30 }]
      @UI.multiLineText: true
      @EndUserText.label: 'Long Text'
      cast( '' as abap.sstring( 1333 ) )                                           as MaintenanceOrderLongText,

      // Maintanence Order Type

      @UI: {
              fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 40}]
              }
      @EndUserText.label: 'Order Type'
      @ObjectModel.text.element: [ 'MaintenanceOrderTypeName' ]
      @UI.textArrangement: #TEXT_FIRST
      MaintenanceOrderType,

      // Maintanence Order Type Text

      @EndUserText.label: 'Order Type Text'
      _Order._OrderType._Text[1:Language = $session.system_language].OrderTypeName as MaintenanceOrderTypeName,

      // Maintanence Order Priority

      @UI: {
              fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 50}]
              }
      @EndUserText.label: 'Priority'
      @ObjectModel.text.element: [ 'MaintPriorityDesc' ]
      @UI.textArrangement: #TEXT_FIRST
      MaintPriority,

      // IME: 2002 LACD

      @UI: {
             fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 60}]
             }
      LatestAcceptableCompletionDate,
      // IME: 2002 LACD

      // Maintanence Priority Text


      @EndUserText.label: 'Priority Text'
      _MaintenancePriority._Text[1:Language = $session.system_language].MaintPriorityDesc,

      // Maintanence Order Required Start Date

      @UI: {
              fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 70}]
              }
      @EndUserText.label: 'Required Start'

      MaintOrdBasicStartDate,

      // Maintanence Order Required End Date

      @UI: {
              fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 80}]
              }
      @EndUserText.label: 'Required End'

      MaintOrdBasicEndDate,

      // Maintanence Order Person Responsible

      @UI: { fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 90}] }
      @EndUserText.label: 'Person Responsible'
      @ObjectModel.text.element: [ 'PersonResponsibleName' ]
      @UI.textArrangement: #TEXT_FIRST
      MaintOrdPersonResponsible,

      // Maintenance Order Person Resposible Name

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_OBJPG_MNTORD_PART_EXIT'
      @EndUserText.label: 'Person Responsible Name'
      cast('' as eams_person_responsible_name)                                     as PersonResponsibleName,

      @UI.hidden: true
      cast (_MaintOrderTypeControlParam.MaintOrderRespPartnerFunction as char2)    as MaintOrderRespPartnerFunction,

      // Maintanence Order System Satus

      @UI: {
              fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 100}]
              }
      @EndUserText.label: 'System Status'
      @ObjectModel: {
             virtualElement: true,
             virtualElementCalculatedBy: 'ABAP:CL_EAM_MNTORD_STS_EXIT'
           }

      cast ('' as vdm_j_system_status_concat_t)                                    as ConcatenatedActiveSystStsName,


      // Maintanence Order User Status

      @UI: {
              fieldGroup:     [{ qualifier:'MaintenanceOrderQuickView', position: 110}]
              }
      @EndUserText.label: 'User Status'
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_EAM_MNTORD_STS_EXIT'
      }
      cast ('' as vdm_j_user_status_concat_t)                                      as ConcatenatedActiveUserStsName,

      @Semantics.imageUrl: true
      @Consumption.filter.hidden: true
      //    concat(  '/sap/opu/odata/sap/EAM_OBJPG_MAINTORDANDOPER_SRV/' , concat( concat( 'MaintenanceOrderThumbnail(MaintenanceOrder=''', MaintenanceOrder ), ''')/$value')  )                                                                                                                                                                                                                                                                    as  MaintenanceOrderThumbnailURL,

      'sap-icon://Fiori2/F0246'                                                    as MaintenanceOrderThumbnailURL,


      MaintOrderRoutingNumber,
      MaintenanceOrderInternalID,
      OrderHasLongText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDER",
"I_MAINTORDERTECHOBJ",
"I_MAINTORDERTYPECONTROLPARAM",
"I_ORDERTYPE",
"I_ORDERTYPETEXT",
"I_PMNOTIFICATIONPRIORITY",
"I_PMNOTIFICATIONPRIORITYTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/