I_MaintOrderComponentDEX

@EndUserText.label: 'Maintenance Order Component Data'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@ObjectModel.supportedCapabilities:[ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.sapObjectNodeType.name: 'MaintenanceOrder'
@Analytics: {
  dataCategory: #FACT,
  dataExtraction: {
    enabled: true,
        delta.changeDataCapture: {
            mapping:[
                      {
                        table: 'RESB', role: #MAIN,
                        viewElement: ['Reservation','ReservationItem','ReservationType'],
                        tableElement: ['RSNUM', 'RSPOS', 'RSART']
                      },
                      {
                        table: 'AUFK', role: #LEFT_OUTER_TO_ONE_JOIN,
                        viewElement: ['MaintenanceOrder'],
                        tableElement: ['AUFNR']
                      },
                      {
                        table: 'rsdb', role: #LEFT_OUTER_TO_ONE_JOIN,
                        viewElement: ['Reservation','ReservationItem','ReservationType','ResvnPurchasingDocumentNumber'],
                        tableElement: ['RSNUM', 'RSPOS', 'RSART', 'RSINZ']
                      },
                      {
                        table: 'rsadd', role:  #LEFT_OUTER_TO_ONE_JOIN,
                        viewElement: ['Reservation','ReservationItem','ReservationType'],
                        tableElement: ['RSNUM', 'RSPOS', 'RSART']
                      }
                    ]
                 }
              }
          }
@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'ORI',
  dataSources: ['_MaintenanceOrderExtension'],
  quota: {
    maximumFields: 250,
    maximumBytes: 5000
  }
}


define view entity I_MaintOrderComponentDEX
  as select from I_MaintenanceOrderComponent_2 as _MaintenanceOrderComponent
  association [0..1] to I_MaintenanceOrderDEX as _MaintenanceOrderDEX       on _MaintenanceOrderComponent.MaintenanceOrder = _MaintenanceOrderDEX.MaintenanceOrder
  -- Extensions, do not expose as association:
  association [0..1] to E_MaintenanceOrder    as _MaintenanceOrderExtension on _MaintenanceOrderComponent.MaintenanceOrder = _MaintenanceOrderExtension.MaintenanceOrder
{
      //keys as underlying main table resb

  key Reservation,
  key ReservationItem,
  key ReservationType,

      //exposing additional keys

      MaintenanceOrder,
      MaintenanceOrderOperation,
      MaintenanceOrderSubOperation,
      MaintOrderComponentInternalID,

      MaintenanceOrderComponent,
      @Consumption.hidden: true
      ResvnPurchasingDocumentNumber,

      // Order Header:

      _MaintenanceOrderDEX.FunctionalLocation                                           as FunctionalLocation,
      _MaintenanceOrderDEX.Equipment                                                    as Equipment,
      _MaintenanceOrderDEX.Assembly                                                     as Assembly,
      _MaintenanceOrderDEX.MaintenanceActivityType                                      as MaintenanceActivityType,
      _MaintenanceOrderDEX.MaintenancePlannerGroup                                      as MaintenancePlannerGroup,
      _MaintenanceOrderDEX.MaintenancePlanningPlant                                     as MaintenancePlanningPlant,
      _MaintenanceOrderDEX.MaintenanceOrderType                                         as MaintenanceOrderType,
      _MaintenanceOrderDEX.MaintenancePlant                                             as MaintenancePlant,
      _MaintenanceOrderDEX.MaintObjectLocAcctAssgmtNmbr                                 as MaintObjectLocAcctAssgmtNmbr,

      @Semantics.systemDate.createdAt: true
      _MaintenanceOrder._Order.CreationDate,
      @Semantics.systemDateTime.lastChangedAt: true
      _MaintenanceOrderDEX.LastChangeDateTime,

      _MaintenanceOrderDEX.MaintOrdProcessPhaseCode                                        as MaintOrdProcessPhaseCode,
      _MaintenanceOrderDEX.MaintOrdProcessSubPhaseCode                                     as MaintOrdProcessSubPhaseCode,
      _MaintenanceOrderDEX.LatestAcceptableCompletionDate                                  as LatestAcceptableCompletionDate,
      _MaintenanceOrder.PrevLtstAccptblCompletionDate                                   as PrevLtstAccptblCompletionDate,
      _MaintenanceOrderDEX.MaintOrderProcessingContext                                     as MaintOrderProcessingContext,

      //Reservation and other

      ReservationIsFinallyIssued,
      Plant,
      StorageLocation,
      Material,
      ComponentDescription,
      MaintComponentItemCategory,
      MaintOrdOpCompRequisitioner,
      MaterialGroup,
      Supplier,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      RequirementQuantityInBaseUnit,
      BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'UnitOfEntry'
      QuantityInUnitOfEntry,
      UnitOfEntry,
      MaintOrderCompDebitCreditCode,
      @Semantics.booleanIndicator: true
      PurReqnOrResvnGeneration,
      MaterialCompIsProcuredDirectly,
      RequirementDate,
      RequirementTime,
      ProductTypeCode,
      ServicePerformer,
      PerformancePeriodStartDate,
      PerformancePeriodEndDate,
      PerformancePeriodStartTime,
      PerformancePeriodEndTime,
      @Semantics.quantity.unitOfMeasure: 'LeanServiceDurationUnit'
      LeanServiceDuration,
      LeanServiceDurationUnit,
      DistributionFunction,
      MaintOrdCompDeliveryDateAdjmt,
      SrvcSchedgIsAlignedWthOpWrkCtr,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      MaintOrderRoutingNumber,
      MaintOrderOperationCounter,
      GoodsMovementType,
      GoodsMovementIsAllowed,

      MaintenanceOrderComponentBatch,
      MaintOrdOpComponentGLAccount,
      MaintOrdOpCompCostingRelevancy,
      MaintCompAltvProdUsgeRateInPct,
      MaintOrderOpComponentSortText,
      MaintOrdOpCompIsBulkProduct,
      MaterialProvisionType,
      MaintOrdOpCompAssgdWBSElmntInt,
      cast ( _MaintenanceOrder._WBSElement.WBSElement as vdm_ps_posid preserving type ) as WBSElement,

      @Semantics.amount.currencyCode: 'MaintOrdOpComponentCurrency'
      MaintOrderOpComponentPrice,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MaintOrdOpCompPriceUnitQty,
      MatlCompIsMarkedForBackflush,
      PurchasingGroup,
      DeliveryTimeInDays,
      MaintOrdOpCompGdsRecipientName,
      MaintOrdOpCompUnloadingPtTxt,
      GoodsReceiptDurationInWorkDays,
      PurchasingInfoRecord,
      OperationLeadTimeOffset,
      OpsLeadTimeOffsetUnit,
      ResponsiblePurchaseOrg,

      MaintOrdCompPurOutlineAgrmtItm,
      IsDeleted,
      _MaintenanceOrderDEX.ControllingArea,
      _MaintenanceOrderDEX.ResponsibleCostCenter,

      @Semantics.amount.currencyCode: 'MaintOrdOpComponentCurrency'
      OverallLimitAmount,
      @Semantics.amount.currencyCode: 'MaintOrdOpComponentCurrency'
      ExpectedOverallLimitAmount,

      QuantityIsFixed,
      MaintOrdOpComponentCurrency,
      MaintOrdOpCompProcmtTrckgNmbr,
      MaintOrdOpCompSpecialStockType,

      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      VariableSizeDimension1,
      VariableSizeDimensionUnit,
      VariableSizeCompFormulaKey,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      VariableSizeDimension2,
      NumberOfVariableSizeItem,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      VariableSizeDimension3,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      VariableSizeItemQuantity,
      VariableSizeComponentUnit,

      RqmtDateIsEnteredManually,
      SupplierProduct,
      MaintOrdCompCmtdQtyIsKept,
      MaintOrdOpCompPurOutlineAgrmt,
      MaintOrdOpCompProcmtCatalog,
      MaintOrdOpCompProcmtCatalogItm,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      QuantityWithdrawnInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      ConfirmedAvailableQuantity,
      _ReservationItem.RecipientLocationCode,

      // For DCL:

      _MaintenanceOrderDEX

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDER",
"I_MAINTENANCEORDER",
"I_MAINTENANCEORDERCOMPONENT_2",
"I_MAINTENANCEORDERDEX",
"I_RESERVATIONDOCUMENTITEM",
"I_WBSELEMENTBYINTERNALKEY"
],
"ASSOCIATED":
[
"I_MAINTENANCEORDERDEX"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/