I_MaintenanceOrderDEX

@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@ObjectModel.supportedCapabilities:[ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.sapObjectNodeType.name: 'MaintenanceOrder'
@Analytics: {
  dataCategory: #FACT,
  dataExtraction: {
    enabled: true,
        delta.changeDataCapture: {
            mapping:[
                      {
                        table: 'AFIH', role: #MAIN,
                        viewElement: ['MaintenanceOrder'],
                        tableElement: ['AUFNR']
                      },
                      {
                        table: 'AUFK', role:  #LEFT_OUTER_TO_ONE_JOIN,
                        viewElement: ['MaintenanceOrder'],
                        tableElement: ['AUFNR']
                      },
                      {
                        table: 'AFKO', role:  #LEFT_OUTER_TO_ONE_JOIN,
                        viewElement: ['MaintenanceOrder'],
                        tableElement: ['AUFNR']
                      }
                    ]
                 }
              }
          }
@EndUserText.label: 'Maintenance Order Data'
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'ORI',
  dataSources: ['_MaintenanceOrderExtension'],
  quota: {
    maximumFields: 250,
    maximumBytes: 5000
  }
}
define view entity I_MaintenanceOrderDEX
  as select from I_MaintenanceOrder as MaintenanceOrder

  association [0..1] to I_FunctionalLocationData as _FunctionalLocation        on $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation
  association [0..1] to E_MaintenanceOrder       as _MaintenanceOrderExtension on $projection.MaintenanceOrder = _MaintenanceOrderExtension.MaintenanceOrder
{
  key  MaintenanceOrder,
       MaintOrderRoutingNumber,
       MaintenanceOrderType,
       MaintenanceOrderDesc,
       MaintOrdBasicStartDate,
       MaintOrdBasicStartTime,
       MaintOrdBasicEndDate,
       MaintOrdBasicEndTime,
       ScheduledBasicStartDate,
       ScheduledBasicStartTime,
       ScheduledBasicEndDate,
       ScheduledBasicEndTime,
       MaintOrderReferenceDate,
       MaintOrderReferenceTime,
       MainWorkCompletedDateTime,
       MaintenanceNotification,
       @Semantics.booleanIndicator: true
       OrdIsNotSchedldAutomatically,

       ControllingArea,
       WorkCenterInternalID                                                                    as MainWorkCenterInternalID,
       WorkCenterTypeCode                                                                      as MainWorkCenterTypeCode,
       MainWorkCenter,
       MainWorkCenterPlant,

       _LocationAccountAssignment.WorkCenterInternalID,
       _LocationAccountAssignment.WorkCenterTypeCode,

       _LocationAccountAssignment._WorkCenter.WorkCenter,
       MaintenancePlanningPlant,
       MaintenancePlant,

       Assembly,

       MaintOrdProcessPhaseCode,
       MaintOrdProcessSubPhaseCode,

       BusinessArea,
       CompanyCode,
       _LocationAccountAssignment.CostCenter,
       CostingSheet,
       ReferenceElement,
       FunctionalArea,
       AdditionalDeviceData,
       Equipment,
       _Equipment._EquipmentText[1:Language=$session.system_language].EquipmentName,
       cast ( _LocationAccountAssignment.FunctionalLocation as vdm_eam_tplnr )                 as FunctionalLocation,
       MaintenanceOrderPlanningCode,
       MaintenancePlannerGroup,
       MaintenanceActivityType,
       MaintPriority,
       MaintPriorityType,
       OrderProcessingGroup,
       ProfitCenter,
       ResponsibleCostCenter,
       Currency,
       MaintenanceRevision,
       SerialNumber,
       Material                                                                                as Product,
       SuperiorProjectNetwork,
       OperationSystemCondition,
       _WBSElement.WBSElementExternalID                                                        as WBSElement,
       WBSElementInternalID,
       cast( ProjectInternalID as ps_s4_proj_pspnr )                                           as ProjectInternalID,
       ControllingObjectClass,
       MaintenanceOrderInternalID,
       MaintenanceItemObjectList                                                               as MaintenanceObjectList,
       MaintObjectLocAcctAssgmtNmbr,
       _LocationAccountAssignment.AssetLocation,
       _LocationAccountAssignment.AssetRoom,
       _LocationAccountAssignment.PlantSection,
       _LocationAccountAssignment.ABCIndicator,
       _LocationAccountAssignment.MaintObjectFreeDefinedAttrib,
       BasicSchedulingType,
       LatestAcceptableCompletionDate,
       MaintOrdPersonResponsible,
       LastChangeByUser,
       @Semantics.systemDateTime.lastChangedAt: true
       cast( LastChangeDateTime as rslastchangedat preserving type )                           as LastChangeDateTime,
       CreatedByUser,
       OrderHasLongText,
       MaintenanceOrderOverheadCode,
       PlannedCostsCostingVariant,
       ActualCostsCostingVariant,
       MaintenancePlan,
       MaintenanceCall,
       MaintenanceItem,
       LeadingOrder,
       TaskListType,
       TaskListGroup,
       TaskListGroupCounter,
       _LocationAccountAssignment._WBSElementBasicData.WBSElementExternalID                    as LocAcctAssgmtWBSElement,
       cast ( _LocationAccountAssignment.WBSElementInternalID as ps_s4_pspnr preserving type ) as LocAcctAssgmtWBSElmntIntID,
       _CtrlgObjectSettlementRule.ControllingSettlementProfile,
       _LocationAccountAssignment.BusinessArea                                                 as LocAcctAssgmtBusinessArea,
       _LocationAccountAssignment.ControllingArea                                              as LocAcctAssgmtControllingArea,
       _LocationAccountAssignment.CompanyCode                                                  as LocAcctAssgmtCompanyCode,
       MaintOrderProcessingContext,

       _Equipment,
       _FunctionalLocation

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CTRLGOBJECTSETTLEMENTRULE",
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEORDER",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYINTERNALKEY",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_FUNCTIONALLOCATIONDATA"
],
"BASE":
[
"I_MAINTENANCEORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/